From 57b66364e70aa8c1937b05ef4d42b9f0752c9200 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Sun, 12 Apr 2020 09:40:33 +0200
Subject: dev-python/gitdb: Bump to 4.0.4
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/gitdb/Manifest           |  1 +
 dev-python/gitdb/gitdb-4.0.4.ebuild | 55 +++++++++++++++++++++++++++++++++++++
 2 files changed, 56 insertions(+)
 create mode 100644 dev-python/gitdb/gitdb-4.0.4.ebuild

(limited to 'dev-python/gitdb')

diff --git a/dev-python/gitdb/Manifest b/dev-python/gitdb/Manifest
index 3f985c1d849c..537b4ce855cc 100644
--- a/dev-python/gitdb/Manifest
+++ b/dev-python/gitdb/Manifest
@@ -1 +1,2 @@
 DIST gitdb-4.0.2.tar.gz 395032 BLAKE2B 0a9cff81fe1e7e8273938545c297096be181dab4ef8e771260f78c2921bcdbf929deb453d7fc893050eb93aba54a8d8a6dabf2e553892d7a9544dbb3e35b44b7 SHA512 9375710ede3f3df7c4d2b0f144d7843cec436b7128c1093c9575ceb62ee03c9f6a12941c97f8642cd8d1b8a429258ac612a78be402bf40decd4b4b5ae2e0d2a9
+DIST gitdb-4.0.4.tar.gz 392964 BLAKE2B ffbf9d78efc1a12e63ce639018a9c5fde366ae14a85b0ec7ba2866678dbeba2c31ff18cac9b5c4caa2b7e150d3aa5d55434352c38a5155477e053c5ab5eae707 SHA512 a0b2aef8b8b3487c22faeba5d6a60ff2b1a97e3ef075f28bc27140c973242b096463839516ec233065710b7450cb4d885904a7a253e2b518379283edd40cc489
diff --git a/dev-python/gitdb/gitdb-4.0.4.ebuild b/dev-python/gitdb/gitdb-4.0.4.ebuild
new file mode 100644
index 000000000000..16cea188ec73
--- /dev/null
+++ b/dev-python/gitdb/gitdb-4.0.4.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit distutils-r1
+
+DESCRIPTION="GitDB is a pure-Python git object database"
+HOMEPAGE="
+	https://github.com/gitpython-developers/gitdb
+	https://pypi.org/project/gitdb/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/smmap-3.0.1[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		dev-vcs/git
+	)"
+
+distutils_enable_tests nose
+
+src_test() {
+	local i
+
+	mkdir "${T}"/repo || die
+	cd "${T}"/repo || die
+
+	for (( i = 0; i < 2500; ++i )); do
+		echo "${i}" > file"${i}" || die
+	done
+
+	git init || die
+	git config user.email "you@example.com" || die
+	git config user.name "Your Name" || die
+	git add -A || die
+	git commit -q -m ".." || die
+	git clone --bare "${T}"/repo "${T}"/repo.git || die
+	cd "${S}" || die
+
+	distutils-r1_src_test
+}
+
+python_test() {
+	#TRAVIS=1 disables performance tests which rely on the gitdb repo
+	local -x TRAVIS=1
+	local -x GITDB_TEST_GIT_REPO_BASE="${T}"/repo.git
+	nosetests -v || die "Tests fail with ${EPYTHON}"
+}
-- 
cgit v1.2.3-65-gdbad