From 81dc912f4e024ded119078a9a67b0696ec3710c2 Mon Sep 17 00:00:00 2001
From: Conrad Kostecki <conikost@gentoo.org>
Date: Tue, 20 Jul 2021 23:07:02 +0200
Subject: dev-ros/roslaunch: migrate to GLEP 81

Bug: https://bugs.gentoo.org/781296
Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Conrad Kostecki <conikost@gentoo.org>
---
 dev-ros/roslaunch/roslaunch-1.15.10-r1.ebuild | 62 +++++++++++++++++++++++++++
 dev-ros/roslaunch/roslaunch-9999.ebuild       | 21 ++++-----
 2 files changed, 73 insertions(+), 10 deletions(-)
 create mode 100644 dev-ros/roslaunch/roslaunch-1.15.10-r1.ebuild

(limited to 'dev-ros/roslaunch')

diff --git a/dev-ros/roslaunch/roslaunch-1.15.10-r1.ebuild b/dev-ros/roslaunch/roslaunch-1.15.10-r1.ebuild
new file mode 100644
index 000000000000..2cc8912dd83a
--- /dev/null
+++ b/dev-ros/roslaunch/roslaunch-1.15.10-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ROS_REPO_URI="https://github.com/ros/ros_comm"
+KEYWORDS="~amd64 ~arm"
+ROS_SUBDIR=tools/${PN}
+
+inherit ros-catkin
+
+DESCRIPTION="Tool for easily launching multiple ROS nodes"
+LICENSE="BSD"
+SLOT="0"
+
+CDEPEND="
+	dev-ros/roslib[${PYTHON_SINGLE_USEDEP}]
+	$(python_gen_cond_dep "dev-python/rospkg[\${PYTHON_USEDEP}]")
+	dev-ros/rosclean[${PYTHON_SINGLE_USEDEP}]
+	$(python_gen_cond_dep "dev-python/pyyaml[\${PYTHON_USEDEP}]")
+	dev-ros/rosgraph_msgs[${CATKIN_MESSAGES_PYTHON_USEDEP}]
+	dev-ros/rosparam[${PYTHON_SINGLE_USEDEP}]
+	dev-ros/rosmaster[${PYTHON_SINGLE_USEDEP}]
+	dev-ros/rosout
+"
+
+RDEPEND="
+	${CDEPEND}
+	acct-group/ros
+	acct-user/ros
+"
+DEPEND="
+	${CDEPEND}
+	test? (
+		$(python_gen_cond_dep "dev-util/rosdep[\${PYTHON_USEDEP}]")
+		$(python_gen_cond_dep "dev-python/nose[\${PYTHON_USEDEP}]")
+		dev-ros/test_rosmaster
+	)"
+
+src_test() {
+	export ROS_PACKAGE_PATH="${S}:${S}/../rosmaster/:${EPREFIX}/usr/share/ros_packages/rosparam:${EPREFIX}/usr/share/ros_packages/roslib:${EPREFIX}/usr/share/ros_packages/rosout"
+	ros-catkin_src_test
+}
+
+src_install() {
+	ros-catkin_src_install
+
+	dodir /etc/ros
+	sed -e "s/@PKG_VERSION@/${PV}/" "${FILESDIR}/roscore.xml.in" > "${ED}/etc/ros/roscore.xml" || die
+
+	newinitd "${FILESDIR}/roscore.initd" roscore
+	newconfd "${FILESDIR}/roscore.confd" roscore
+
+	newinitd "${FILESDIR}/roslaunch.initd" roslaunch
+	newconfd "${FILESDIR}/roslaunch.confd" roslaunch
+
+	doenvd "${FILESDIR}/40roslaunch"
+
+	# Needed by test_roslaunch
+	insinto /usr/share/${PN}
+	doins test/xml/noop.launch
+}
diff --git a/dev-ros/roslaunch/roslaunch-9999.ebuild b/dev-ros/roslaunch/roslaunch-9999.ebuild
index b0c3d9412aae..2cc8912dd83a 100644
--- a/dev-ros/roslaunch/roslaunch-9999.ebuild
+++ b/dev-ros/roslaunch/roslaunch-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -7,14 +7,13 @@ ROS_REPO_URI="https://github.com/ros/ros_comm"
 KEYWORDS="~amd64 ~arm"
 ROS_SUBDIR=tools/${PN}
 
-inherit ros-catkin user
+inherit ros-catkin
 
 DESCRIPTION="Tool for easily launching multiple ROS nodes"
 LICENSE="BSD"
 SLOT="0"
-IUSE=""
 
-RDEPEND="
+CDEPEND="
 	dev-ros/roslib[${PYTHON_SINGLE_USEDEP}]
 	$(python_gen_cond_dep "dev-python/rospkg[\${PYTHON_USEDEP}]")
 	dev-ros/rosclean[${PYTHON_SINGLE_USEDEP}]
@@ -24,7 +23,14 @@ RDEPEND="
 	dev-ros/rosmaster[${PYTHON_SINGLE_USEDEP}]
 	dev-ros/rosout
 "
-DEPEND="${RDEPEND}
+
+RDEPEND="
+	${CDEPEND}
+	acct-group/ros
+	acct-user/ros
+"
+DEPEND="
+	${CDEPEND}
 	test? (
 		$(python_gen_cond_dep "dev-util/rosdep[\${PYTHON_USEDEP}]")
 		$(python_gen_cond_dep "dev-python/nose[\${PYTHON_USEDEP}]")
@@ -54,8 +60,3 @@ src_install() {
 	insinto /usr/share/${PN}
 	doins test/xml/noop.launch
 }
-
-pkg_preinst() {
-	enewgroup ros
-	enewuser ros -1 -1 /home/ros ros
-}
-- 
cgit v1.2.3-65-gdbad