From d17d7d26ac89d321a89a6cb81fe3aca376fc1395 Mon Sep 17 00:00:00 2001
From: Guilherme Amadio <amadio@gentoo.org>
Date: Fri, 11 Mar 2022 09:16:34 +0100
Subject: dev-util/hermes: version bump to 2.9

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Guilherme Amadio <amadio@gentoo.org>
---
 dev-util/hermes/hermes-2.9.ebuild | 59 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 dev-util/hermes/hermes-2.9.ebuild

(limited to 'dev-util/hermes/hermes-2.9.ebuild')

diff --git a/dev-util/hermes/hermes-2.9.ebuild b/dev-util/hermes/hermes-2.9.ebuild
new file mode 100644
index 000000000000..672828c5e1b2
--- /dev/null
+++ b/dev-util/hermes/hermes-2.9.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..3} )
+inherit lua-single prefix
+
+DESCRIPTION="Lua based testing manager"
+HOMEPAGE="https://github.com/TACC/Hermes"
+if [[ "${PV}" == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/TACC/Hermes"
+else
+	SRC_URI="https://github.com/TACC/Hermes/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${P^}"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="test"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="${LUA_DEPS}
+	$(lua_gen_cond_dep '
+		dev-lua/luafilesystem[${LUA_USEDEP}]
+		dev-lua/luaposix[${LUA_USEDEP}]
+	')
+"
+DEPEND="test? ( ${RDEPEND} )"
+
+PATCHES=( "${FILESDIR}"/${PN}-2.8-lua-shebang.patch )
+
+src_prepare() {
+	default
+	hprefixify -w '/#\!\/bin\/bash/' tm/Tst.lua || die
+}
+
+src_compile() {
+	sed -e "s|@LUA@|${LUA}|g" \
+		-i lib/tool.lua \
+		-i bin/lua_cmd || die
+}
+
+src_test() {
+	local -x PATH="bin:${PATH}"
+	tm -vvv || die
+	testcleanup || die
+}
+
+src_install() {
+	dodir /opt/hermes
+	cp -r "${S}"/. "${ED}"/opt/hermes/ || die
+
+	doenvd "${FILESDIR}"/99hermes
+}
-- 
cgit v1.2.3-65-gdbad