From 4e7cf7c4d7b071bf9f7cb1203d17161b46b5e1ac Mon Sep 17 00:00:00 2001
From: Marek Szuba <marecki@gentoo.org>
Date: Thu, 11 May 2023 12:35:41 +0100
Subject: dev-vcs/git-machete: add 3.17.3

Signed-off-by: Marek Szuba <marecki@gentoo.org>
---
 dev-vcs/git-machete/git-machete-3.17.3.ebuild | 41 +++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)
 create mode 100644 dev-vcs/git-machete/git-machete-3.17.3.ebuild

(limited to 'dev-vcs/git-machete/git-machete-3.17.3.ebuild')

diff --git a/dev-vcs/git-machete/git-machete-3.17.3.ebuild b/dev-vcs/git-machete/git-machete-3.17.3.ebuild
new file mode 100644
index 000000000000..c04f32d1e272
--- /dev/null
+++ b/dev-vcs/git-machete/git-machete-3.17.3.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+DISTUTILS_USE_PEP517=setuptools
+
+inherit bash-completion-r1 distutils-r1
+
+DESCRIPTION="Probably the sharpest git repo organizer & rebase/merge workflow automation tool"
+HOMEPAGE="https://github.com/VirtusLab/git-machete https://pypi.org/project/git-machete/"
+# No tests in PyPI tarballs
+SRC_URI="https://github.com/VirtusLab/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv"
+
+RDEPEND="dev-vcs/git"
+BDEPEND="test? (
+	>=dev-python/pytest-mock-3.10.0[${PYTHON_USEDEP}]
+	>=dev-python/pytest-xdist-3.2.1[${PYTHON_USEDEP}]
+)"
+
+DOCS=( CONTRIBUTING.md README.md )
+
+distutils_enable_sphinx docs/source dev-python/sphinx-rtd-theme
+distutils_enable_tests pytest
+
+src_install() {
+	distutils-r1_src_install
+
+	newbashcomp completion/${PN}.completion.bash ${PN}
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins completion/${PN}.fish
+
+	insinto /usr/share/zsh/site-functions
+	newins completion/${PN}.completion.zsh _${PN}
+}
-- 
cgit v1.2.3-65-gdbad