From f7e3fb37f3159af53bdf851e812278655b512a3a Mon Sep 17 00:00:00 2001
From: James Le Cuirot <chewi@gentoo.org>
Date: Sun, 25 Jun 2023 22:39:11 +0100
Subject: games-action/dxx-rebirth: Bump snapshot to 20230625

My new patch was merged upstream already.

Signed-off-by: James Le Cuirot <chewi@gentoo.org>
---
 games-action/dxx-rebirth/Manifest                  |   2 +-
 .../dxx-rebirth-0.61.0_pre20230618.ebuild          | 260 ---------------------
 .../dxx-rebirth-0.61.0_pre20230625.ebuild          | 256 ++++++++++++++++++++
 ...x-rebirth-0.61.0_pre20230618-sdl12-compat.patch |  38 ---
 4 files changed, 257 insertions(+), 299 deletions(-)
 delete mode 100644 games-action/dxx-rebirth/dxx-rebirth-0.61.0_pre20230618.ebuild
 create mode 100644 games-action/dxx-rebirth/dxx-rebirth-0.61.0_pre20230625.ebuild
 delete mode 100644 games-action/dxx-rebirth/files/dxx-rebirth-0.61.0_pre20230618-sdl12-compat.patch

(limited to 'games-action')

diff --git a/games-action/dxx-rebirth/Manifest b/games-action/dxx-rebirth/Manifest
index 69e7f50bc883..1e9f551586c4 100644
--- a/games-action/dxx-rebirth/Manifest
+++ b/games-action/dxx-rebirth/Manifest
@@ -1 +1 @@
-DIST dxx-rebirth-0.61.0_pre20230618.tar.gz 2063234 BLAKE2B d602e8e92f8a494eabe3645e4c465f1f1b1bc10a0b27d4b518a617f07c90c86c903b7a6bed42085bfe992cd8533f57ac6eca2c10ee0b02d5fc677859f0d80bd3 SHA512 a0a0318169ed55ef9969fe9827d87871bec3d168fb94bed1e7d0c61ce62fdad9f57040181f2c05f9107a0f898ba4876b802e74d43028c90169eefebd2b9eb79d
+DIST dxx-rebirth-0.61.0_pre20230625.tar.gz 2063234 BLAKE2B 5ca7c699e7240553c6106fc008acf08e56fbbf8eed15fa6988390b82f149f91c522bf1fcaebf463fc0923ed2b5518f71f913b17c446a04176addc8f6fa03fab7 SHA512 21a1fa46da4f4b20515e79c746bc6eac82164777c88caf6dd048f8e289f85914c1ae844f8bad6f858855172e8556649f60daa17b9ea23c2d6854e4acb777ee2a
diff --git a/games-action/dxx-rebirth/dxx-rebirth-0.61.0_pre20230618.ebuild b/games-action/dxx-rebirth/dxx-rebirth-0.61.0_pre20230618.ebuild
deleted file mode 100644
index 833ffdb92ee8..000000000000
--- a/games-action/dxx-rebirth/dxx-rebirth-0.61.0_pre20230618.ebuild
+++ /dev/null
@@ -1,260 +0,0 @@
-# Copyright 2017-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{10..11} )
-MY_COMMIT="111f6f2f0dd8de7c2f669eb4d784a0d9e9f124f9"
-
-# Games under Gentoo are marked as 'testing' by convention
-#
-# Other architectures are reported to work, but not tested regularly by
-# the core team.
-#
-# Raspberry Pi support is tested by an outside contributor, and his
-# fixes are merged into the main source by upstream.
-#
-# Cross-compilation to Windows is also supported.
-KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
-
-inherit desktop flag-o-matic python-any-r1 scons-utils toolchain-funcs xdg
-
-if [[ "${PV}" = 9999 ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/dxx-rebirth/dxx-rebirth"
-	unset KEYWORDS
-elif [[ -n ${MY_COMMIT} ]]; then
-	S="${WORKDIR}/${PN}-${MY_COMMIT}"
-	SRC_URI="https://codeload.github.com/dxx-rebirth/dxx-rebirth/tar.gz/${MY_COMMIT} -> ${PN}-${PVR}.tar.gz"
-	unset MY_COMMIT
-else
-	S="${WORKDIR}/${PN}_${PV##*_pre}-src"
-	SRC_URI="https://www.dxx-rebirth.com/download/dxx/rebirth/${PN}_${PV##*_pre}-src.tar.xz"
-fi
-
-DESCRIPTION="Descent Rebirth - enhanced Descent 1 & 2 engine"
-HOMEPAGE="https://www.dxx-rebirth.com/"
-
-LICENSE="DXX-Rebirth GPL-3"
-SLOT="0"
-
-# Default to building both game engines.  The total size is relatively
-# small.
-IUSE="+d1x +d2x +data debug editor +flac ipv6 +joystick l10n_de +midi +mp3 +music +opengl opl3-musicpack +png sc55-musicpack sdl2 tracker valgrind +vorbis"
-
-# Game data is stored in HOG files.
-# Game movies are in MVL files.
-# Various add-ons use zip files to bundle their content together.
-#
-# PNG support enables writing screenshots as PNG instead of TGA (for
-# USE=opengl) or PCX (for USE=-opengl).
-DEPEND="dev-games/physfs[hog,mvl,zip]
-	opengl? (
-		virtual/opengl
-		virtual/glu )
-	png? ( media-libs/libpng )
-"
-
-# As of this writing, there is no Portage shorthand syntax to express:
-# "
-# 	flag1? ( package[flag1] )
-# 	flag2? ( package[flag2] )
-# 	...
-# 	flagN? ( package[flagN] )
-# ", such that unsetting all flags removes the dependency on package.
-# Fake it by using a text fragment that is repeatedly expanded with
-# differing substitutions.
-#
-# The use of single quotes is intentional here.  The ${word} is a
-# placeholder to be matched by text substitution when the fragment is
-# expanded, not a shell variable reference.
-#
-# For each flag, depend on freedata using the same flag.  If none of the
-# flags are set, freedata is not needed.
-DXX_RDEPEND_USE_FREEDATA_FRAGMENT='
-	${USE}? ( games-action/descent${ENGINE}-freedata[${USE}] )
-'
-# Block <0.59.100 due to file collision.
-#
-# If USE=data, then require a game data package.
-# The build process does not use the game data, nor change how the game
-# is built based on what game data will be used.  At startup, the game
-# will search for both types of game data and use what it finds.  Users
-# can switch between shareware/retail data at any time by
-# adding/removing the appropriate data packages.  A rebuild is _not_
-# required after swapping the data files.
-#
-# USE-depend on freedata for various extras, but only if any of those
-# extras are enabled.
-DXX_RDEPEND_ENGINE_FRAGMENT='
-	d${ENGINE}x? (
-		!<games-action/d${ENGINE}x-rebirth-0.59.100
-		data? (
-			|| (
-				games-action/descent${ENGINE}-data
-				games-action/descent${ENGINE}-demodata
-			)
-		)
-		'"
-		${DXX_RDEPEND_USE_FREEDATA_FRAGMENT//\$\{USE\}/l10n_de}
-		${DXX_RDEPEND_USE_FREEDATA_FRAGMENT//\$\{USE\}/opl3-musicpack}
-		${DXX_RDEPEND_USE_FREEDATA_FRAGMENT//\$\{USE\}/sc55-musicpack}
-		"'
-	)
-'
-
-DXX_DEPEND_USE_SDL_VERSION_FRAGMENT='
-	media-libs/lib${SDL_version}[joystick?,opengl?,sound,video]
-	media-libs/${SDL_version}-image
-	music? ( media-libs/${SDL_version}-mixer )
-'
-DXX_RDEPEND_USE_SDL_VERSION_FRAGMENT='
-	music? ( media-libs/${SDL_version}-mixer[flac?,midi?,mp3?,vorbis?] )
-'
-DEPEND="${DEPEND}
-	!sdl2? ( ${DXX_DEPEND_USE_SDL_VERSION_FRAGMENT//\$\{SDL_version\}/sdl} )
-	sdl2? ( ${DXX_DEPEND_USE_SDL_VERSION_FRAGMENT//\$\{SDL_version\}/sdl2} )
-"
-unset DXX_DEPEND_USE_SDL_VERSION_FRAGMENT
-
-unset DXX_RDEPEND_USE_FREEDATA_FRAGMENT
-RDEPEND="${DEPEND}
-	!sdl2? ( ${DXX_RDEPEND_USE_SDL_VERSION_FRAGMENT//\$\{SDL_version\}/sdl} )
-	sdl2? ( ${DXX_RDEPEND_USE_SDL_VERSION_FRAGMENT//\$\{SDL_version\}/sdl2} )
-	${DXX_RDEPEND_ENGINE_FRAGMENT//\$\{ENGINE\}/1}
-	${DXX_RDEPEND_ENGINE_FRAGMENT//\$\{ENGINE\}/2}
-"
-unset DXX_RDEPEND_ENGINE_FRAGMENT
-unset DXX_RDEPEND_USE_SDL_VERSION_FRAGMENT
-
-# USE=valgrind enables use of a Valgrind header.  A build with valgrind
-# instrumentation can be run without installing Valgrind, so this
-# dependency is only in DEPEND, instead of being in both DEPEND and
-# RDEPEND.
-DEPEND+='
-	valgrind? ( dev-util/valgrind )
-'
-
-# This ebuild builds d1x-rebirth, d2x-rebirth, or both.  Building none
-# would mean this ebuild installs zero files.
-#
-# For each of the supported music flags, require USE=music, so that the
-# package is built with sdl-mixer support.  Individual music types can be
-# changed without a Rebirth rebuild by rebuilding sdl-mixer with
-# appropriate support, but Rebirth must have sdl-mixer support at build
-# time in order to support any of these music formats at runtime.
-#
-# All music files in the optional musicpack downloads are .ogg, so
-# require USE=vorbis if those packs are enabled.
-REQUIRED_USE='
-	|| ( d1x d2x )
-	flac? ( music )
-	midi? ( music )
-	mp3? ( music )
-	vorbis? ( music )
-	opl3-musicpack? ( vorbis )
-	sc55-musicpack? ( vorbis )
-	sdl2? ( opengl )
-'
-
-BDEPEND="virtual/pkgconfig"
-
-# As of this writing, IUSE_RUNTIME is a GLEP, but not an implemented
-# feature.  This variable is stored here to be ready to activate when
-# Portage implements this feature.
-#
-# Note that while individual music formats can be switched without a
-# rebuild, the master flag USE=music controls whether sdl-mixer is used,
-# and therefore requires a rebuild when changed.
-#IUSE_RUNTIME="flac l10n_de midi mp3 opl3-musicpack sc55-musicpack vorbis"
-
-PATCHES=(
-	"${FILESDIR}"/${P}-sdl12-compat.patch
-)
-
-dxx_scons() {
-	# Always build profile `m`.  If use editor, also build profile `e`.
-	# Set most variables in the default anonymous profile.  Only
-	# `builddir` and `editor` are set in the named profiles, since those
-	# must be different between the two builds.
-	#
-	# Notes for end users:
-	# - Per-engine options can be set with an engine prefix, as shown
-	#   for sharepath.  Such options are used in place of
-	#   engine-unqualified options.  For example, to disable sdlmixer
-	#   for Descent 2: Rebirth, but use the setting below for Descent 1:
-	#   Rebirth, set EXTRA_ESCONS="d2x_sdlmixer=0".
-	# - Profile `site` is searched before the anonymous profile, and is
-	#   deliberately unused in this ebuild.  Set options in the site
-	#   profile to affect both engines:
-	#   EXTRA_ESCONS="site_verbosebuild=0".
-	local scons_build_profile=m mysconsargs=(
-		sdl2=$(usex sdl2 1 0)
-		sdlmixer=$(usex music 1 0)
-		verbosebuild=1
-		debug=$(usex debug 1 0)
-		ipv6=$(usex ipv6 1 0)
-		opengl=$(usex opengl 1 0)
-		use_tracker=$(usex tracker 1 0)
-		prefix="${EPREFIX}"/usr
-		screenshot=$(usex png png legacy)
-		m_builddir=build/main/
-		m_editor=0
-	)
-	if use editor; then
-		scons_build_profile+=+e
-		mysconsargs+=( \
-			e_builddir=build/editor/
-			e_editor=1
-		)
-	fi
-	if ! use joystick; then
-		mysconsargs+=( \
-			max_joysticks=0
-		)
-	fi
-	# Add sharepath and enable build of selected games.  The trailing
-	# comma after `$scons_build_profile` is required to cause scons to
-	# search the anonymous profile.  If omitted, only settings from the
-	# named profile would be used.
-	use d1x && mysconsargs+=( d1x_sharepath="/usr/share/games/d1x" d1x="$scons_build_profile,site," )
-	use d2x && mysconsargs+=( d2x_sharepath="/usr/share/games/d2x" d2x="$scons_build_profile,site," )
-	use valgrind && mysconsargs+=( poison=valgrind )
-	escons "${mysconsargs[@]}" "$@"
-}
-
-src_compile() {
-	tc-export CXX PKG_CONFIG
-	replace-flags -O3 -O2 #831896
-	dxx_scons register_install_target=0 build
-}
-
-src_install() {
-	# Use upstream install target to handle the various combinations of
-	# enabled/disabled engines and optional editor support.
-	dxx_scons register_compile_target=0 register_install_target=1 DESTDIR="${D}" "${D}"
-	local DV
-	for DV in 1 2; do
-		if ! use d${DV}x; then
-			continue
-		fi
-		local PROGRAM=d${DV}x-rebirth
-		docinto "${PROGRAM}"
-		dodoc "${PROGRAM}"/*.txt
-		make_desktop_entry "${PROGRAM}" "Descent ${DV} Rebirth" "${PROGRAM}"
-		doicon "${PROGRAM}/${PROGRAM}.xpm"
-	done
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-	if ! use data; then
-		elog "${PN} requires game data to play."
-		elog "Game data is not included in this package.  To play the game,"
-		elog "emerge the packages required by USE=data or install the game"
-		elog "data by hand."
-		elog
-		elog "Changing USE=data does not change how this package is built,"
-		elog "only its runtime dependencies."
-	fi
-}
diff --git a/games-action/dxx-rebirth/dxx-rebirth-0.61.0_pre20230625.ebuild b/games-action/dxx-rebirth/dxx-rebirth-0.61.0_pre20230625.ebuild
new file mode 100644
index 000000000000..dc93d9200327
--- /dev/null
+++ b/games-action/dxx-rebirth/dxx-rebirth-0.61.0_pre20230625.ebuild
@@ -0,0 +1,256 @@
+# Copyright 2017-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..11} )
+MY_COMMIT="e9daf03769d8408719c1b420a133155cb700b9a2"
+
+# Games under Gentoo are marked as 'testing' by convention
+#
+# Other architectures are reported to work, but not tested regularly by
+# the core team.
+#
+# Raspberry Pi support is tested by an outside contributor, and his
+# fixes are merged into the main source by upstream.
+#
+# Cross-compilation to Windows is also supported.
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+
+inherit desktop flag-o-matic python-any-r1 scons-utils toolchain-funcs xdg
+
+if [[ "${PV}" = 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/dxx-rebirth/dxx-rebirth"
+	unset KEYWORDS
+elif [[ -n ${MY_COMMIT} ]]; then
+	S="${WORKDIR}/${PN}-${MY_COMMIT}"
+	SRC_URI="https://codeload.github.com/dxx-rebirth/dxx-rebirth/tar.gz/${MY_COMMIT} -> ${PN}-${PVR}.tar.gz"
+	unset MY_COMMIT
+else
+	S="${WORKDIR}/${PN}_${PV##*_pre}-src"
+	SRC_URI="https://www.dxx-rebirth.com/download/dxx/rebirth/${PN}_${PV##*_pre}-src.tar.xz"
+fi
+
+DESCRIPTION="Descent Rebirth - enhanced Descent 1 & 2 engine"
+HOMEPAGE="https://www.dxx-rebirth.com/"
+
+LICENSE="DXX-Rebirth GPL-3"
+SLOT="0"
+
+# Default to building both game engines.  The total size is relatively
+# small.
+IUSE="+d1x +d2x +data debug editor +flac ipv6 +joystick l10n_de +midi +mp3 +music +opengl opl3-musicpack +png sc55-musicpack sdl2 tracker valgrind +vorbis"
+
+# Game data is stored in HOG files.
+# Game movies are in MVL files.
+# Various add-ons use zip files to bundle their content together.
+#
+# PNG support enables writing screenshots as PNG instead of TGA (for
+# USE=opengl) or PCX (for USE=-opengl).
+DEPEND="dev-games/physfs[hog,mvl,zip]
+	opengl? (
+		virtual/opengl
+		virtual/glu )
+	png? ( media-libs/libpng )
+"
+
+# As of this writing, there is no Portage shorthand syntax to express:
+# "
+# 	flag1? ( package[flag1] )
+# 	flag2? ( package[flag2] )
+# 	...
+# 	flagN? ( package[flagN] )
+# ", such that unsetting all flags removes the dependency on package.
+# Fake it by using a text fragment that is repeatedly expanded with
+# differing substitutions.
+#
+# The use of single quotes is intentional here.  The ${word} is a
+# placeholder to be matched by text substitution when the fragment is
+# expanded, not a shell variable reference.
+#
+# For each flag, depend on freedata using the same flag.  If none of the
+# flags are set, freedata is not needed.
+DXX_RDEPEND_USE_FREEDATA_FRAGMENT='
+	${USE}? ( games-action/descent${ENGINE}-freedata[${USE}] )
+'
+# Block <0.59.100 due to file collision.
+#
+# If USE=data, then require a game data package.
+# The build process does not use the game data, nor change how the game
+# is built based on what game data will be used.  At startup, the game
+# will search for both types of game data and use what it finds.  Users
+# can switch between shareware/retail data at any time by
+# adding/removing the appropriate data packages.  A rebuild is _not_
+# required after swapping the data files.
+#
+# USE-depend on freedata for various extras, but only if any of those
+# extras are enabled.
+DXX_RDEPEND_ENGINE_FRAGMENT='
+	d${ENGINE}x? (
+		!<games-action/d${ENGINE}x-rebirth-0.59.100
+		data? (
+			|| (
+				games-action/descent${ENGINE}-data
+				games-action/descent${ENGINE}-demodata
+			)
+		)
+		'"
+		${DXX_RDEPEND_USE_FREEDATA_FRAGMENT//\$\{USE\}/l10n_de}
+		${DXX_RDEPEND_USE_FREEDATA_FRAGMENT//\$\{USE\}/opl3-musicpack}
+		${DXX_RDEPEND_USE_FREEDATA_FRAGMENT//\$\{USE\}/sc55-musicpack}
+		"'
+	)
+'
+
+DXX_DEPEND_USE_SDL_VERSION_FRAGMENT='
+	media-libs/lib${SDL_version}[joystick?,opengl?,sound,video]
+	media-libs/${SDL_version}-image
+	music? ( media-libs/${SDL_version}-mixer )
+'
+DXX_RDEPEND_USE_SDL_VERSION_FRAGMENT='
+	music? ( media-libs/${SDL_version}-mixer[flac?,midi?,mp3?,vorbis?] )
+'
+DEPEND="${DEPEND}
+	!sdl2? ( ${DXX_DEPEND_USE_SDL_VERSION_FRAGMENT//\$\{SDL_version\}/sdl} )
+	sdl2? ( ${DXX_DEPEND_USE_SDL_VERSION_FRAGMENT//\$\{SDL_version\}/sdl2} )
+"
+unset DXX_DEPEND_USE_SDL_VERSION_FRAGMENT
+
+unset DXX_RDEPEND_USE_FREEDATA_FRAGMENT
+RDEPEND="${DEPEND}
+	!sdl2? ( ${DXX_RDEPEND_USE_SDL_VERSION_FRAGMENT//\$\{SDL_version\}/sdl} )
+	sdl2? ( ${DXX_RDEPEND_USE_SDL_VERSION_FRAGMENT//\$\{SDL_version\}/sdl2} )
+	${DXX_RDEPEND_ENGINE_FRAGMENT//\$\{ENGINE\}/1}
+	${DXX_RDEPEND_ENGINE_FRAGMENT//\$\{ENGINE\}/2}
+"
+unset DXX_RDEPEND_ENGINE_FRAGMENT
+unset DXX_RDEPEND_USE_SDL_VERSION_FRAGMENT
+
+# USE=valgrind enables use of a Valgrind header.  A build with valgrind
+# instrumentation can be run without installing Valgrind, so this
+# dependency is only in DEPEND, instead of being in both DEPEND and
+# RDEPEND.
+DEPEND+='
+	valgrind? ( dev-util/valgrind )
+'
+
+# This ebuild builds d1x-rebirth, d2x-rebirth, or both.  Building none
+# would mean this ebuild installs zero files.
+#
+# For each of the supported music flags, require USE=music, so that the
+# package is built with sdl-mixer support.  Individual music types can be
+# changed without a Rebirth rebuild by rebuilding sdl-mixer with
+# appropriate support, but Rebirth must have sdl-mixer support at build
+# time in order to support any of these music formats at runtime.
+#
+# All music files in the optional musicpack downloads are .ogg, so
+# require USE=vorbis if those packs are enabled.
+REQUIRED_USE='
+	|| ( d1x d2x )
+	flac? ( music )
+	midi? ( music )
+	mp3? ( music )
+	vorbis? ( music )
+	opl3-musicpack? ( vorbis )
+	sc55-musicpack? ( vorbis )
+	sdl2? ( opengl )
+'
+
+BDEPEND="virtual/pkgconfig"
+
+# As of this writing, IUSE_RUNTIME is a GLEP, but not an implemented
+# feature.  This variable is stored here to be ready to activate when
+# Portage implements this feature.
+#
+# Note that while individual music formats can be switched without a
+# rebuild, the master flag USE=music controls whether sdl-mixer is used,
+# and therefore requires a rebuild when changed.
+#IUSE_RUNTIME="flac l10n_de midi mp3 opl3-musicpack sc55-musicpack vorbis"
+
+dxx_scons() {
+	# Always build profile `m`.  If use editor, also build profile `e`.
+	# Set most variables in the default anonymous profile.  Only
+	# `builddir` and `editor` are set in the named profiles, since those
+	# must be different between the two builds.
+	#
+	# Notes for end users:
+	# - Per-engine options can be set with an engine prefix, as shown
+	#   for sharepath.  Such options are used in place of
+	#   engine-unqualified options.  For example, to disable sdlmixer
+	#   for Descent 2: Rebirth, but use the setting below for Descent 1:
+	#   Rebirth, set EXTRA_ESCONS="d2x_sdlmixer=0".
+	# - Profile `site` is searched before the anonymous profile, and is
+	#   deliberately unused in this ebuild.  Set options in the site
+	#   profile to affect both engines:
+	#   EXTRA_ESCONS="site_verbosebuild=0".
+	local scons_build_profile=m mysconsargs=(
+		sdl2=$(usex sdl2 1 0)
+		sdlmixer=$(usex music 1 0)
+		verbosebuild=1
+		debug=$(usex debug 1 0)
+		ipv6=$(usex ipv6 1 0)
+		opengl=$(usex opengl 1 0)
+		use_tracker=$(usex tracker 1 0)
+		prefix="${EPREFIX}"/usr
+		screenshot=$(usex png png legacy)
+		m_builddir=build/main/
+		m_editor=0
+	)
+	if use editor; then
+		scons_build_profile+=+e
+		mysconsargs+=( \
+			e_builddir=build/editor/
+			e_editor=1
+		)
+	fi
+	if ! use joystick; then
+		mysconsargs+=( \
+			max_joysticks=0
+		)
+	fi
+	# Add sharepath and enable build of selected games.  The trailing
+	# comma after `$scons_build_profile` is required to cause scons to
+	# search the anonymous profile.  If omitted, only settings from the
+	# named profile would be used.
+	use d1x && mysconsargs+=( d1x_sharepath="/usr/share/games/d1x" d1x="$scons_build_profile,site," )
+	use d2x && mysconsargs+=( d2x_sharepath="/usr/share/games/d2x" d2x="$scons_build_profile,site," )
+	use valgrind && mysconsargs+=( poison=valgrind )
+	escons "${mysconsargs[@]}" "$@"
+}
+
+src_compile() {
+	tc-export CXX PKG_CONFIG
+	replace-flags -O3 -O2 #831896
+	dxx_scons register_install_target=0 build
+}
+
+src_install() {
+	# Use upstream install target to handle the various combinations of
+	# enabled/disabled engines and optional editor support.
+	dxx_scons register_compile_target=0 register_install_target=1 DESTDIR="${D}" "${D}"
+	local DV
+	for DV in 1 2; do
+		if ! use d${DV}x; then
+			continue
+		fi
+		local PROGRAM=d${DV}x-rebirth
+		docinto "${PROGRAM}"
+		dodoc "${PROGRAM}"/*.txt
+		make_desktop_entry "${PROGRAM}" "Descent ${DV} Rebirth" "${PROGRAM}"
+		doicon "${PROGRAM}/${PROGRAM}.xpm"
+	done
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	if ! use data; then
+		elog "${PN} requires game data to play."
+		elog "Game data is not included in this package.  To play the game,"
+		elog "emerge the packages required by USE=data or install the game"
+		elog "data by hand."
+		elog
+		elog "Changing USE=data does not change how this package is built,"
+		elog "only its runtime dependencies."
+	fi
+}
diff --git a/games-action/dxx-rebirth/files/dxx-rebirth-0.61.0_pre20230618-sdl12-compat.patch b/games-action/dxx-rebirth/files/dxx-rebirth-0.61.0_pre20230618-sdl12-compat.patch
deleted file mode 100644
index 4c01c8cd0dbb..000000000000
--- a/games-action/dxx-rebirth/files/dxx-rebirth-0.61.0_pre20230618-sdl12-compat.patch
+++ /dev/null
@@ -1,38 +0,0 @@
-From e9daf03769d8408719c1b420a133155cb700b9a2 Mon Sep 17 00:00:00 2001
-From: James Le Cuirot <chewi@gentoo.org>
-Date: Sun, 25 Jun 2023 15:16:55 +0100
-Subject: [PATCH] Skip SDL OpenGL build check when the SDL2 wrapper is detected
-
-The wrapper does not define SDL_VIDEO_OPENGL in SDL_config.h. This
-appears to be deliberate, although it's not entirely clear why.
-
-    /* Don't define most of the SDL backends, under the assumption checking for these against the headers won't work anyhow.
-       The exception is the X11 backend; you need its define to know if you can use its syswm interface. */
-
-We could check SDL2's SDL_config.h instead, but that seems awkward to
-pull off.
-
-Closes: https://github.com/dxx-rebirth/dxx-rebirth/issues/689
----
- SConstruct | 2 ++
- 1 file changed, 2 insertions(+)
-
-diff --git a/SConstruct b/SConstruct
-index c98a22bc8..59210a802 100644
---- a/SConstruct
-+++ b/SConstruct
-@@ -1586,9 +1586,11 @@ static void terminate_handler()
- 		init_cdrom = '0' if sdl2 else 'SDL_INIT_CDROM'
- 		error_text_opengl_mismatch = f'Rebirth configured with OpenGL enabled, but SDL{sdl2} configured with OpenGL disabled.  Disable Rebirth OpenGL or install an SDL{sdl2} with OpenGL enabled.'
- 		test_opengl = (f'''
-+#if !((SDL_MAJOR_VERSION == 1) && (SDL_MINOR_VERSION == 2) && (SDL_PATCHLEVEL >= 50))
- #ifndef SDL_VIDEO_OPENGL
- #error "{error_text_opengl_mismatch}"
- #endif
-+#endif
- ''') if user_settings.opengl else ''
- 		main = '''
- 	SDL_RWops *ops = reinterpret_cast<SDL_RWops *>(argv);
--- 
-2.40.1
-
-- 
cgit v1.2.3-65-gdbad