From 88d8489cdf74c37c0fe6435486e6cbfcf65bbbdd Mon Sep 17 00:00:00 2001
From: Ulrich Müller <ulm@gentoo.org>
Date: Sun, 8 Jul 2018 00:55:50 +0200
Subject: games-puzzle/world-of-goo: Don't inherit games.eclass.

Bump EAPI to 6. Fix DISTDIR usage in pkg_nofetch.

Closes: https://bugs.gentoo.org/659334
Package-Manager: Portage-2.3.41, Repoman-2.3.9
---
 .../world-of-goo/world-of-goo-1.41-r1.ebuild       | 67 ----------------------
 .../world-of-goo/world-of-goo-1.41-r2.ebuild       | 66 +++++++++++++++++++++
 2 files changed, 66 insertions(+), 67 deletions(-)
 delete mode 100644 games-puzzle/world-of-goo/world-of-goo-1.41-r1.ebuild
 create mode 100644 games-puzzle/world-of-goo/world-of-goo-1.41-r2.ebuild

(limited to 'games-puzzle')

diff --git a/games-puzzle/world-of-goo/world-of-goo-1.41-r1.ebuild b/games-puzzle/world-of-goo/world-of-goo-1.41-r1.ebuild
deleted file mode 100644
index b941fe96f8d3..000000000000
--- a/games-puzzle/world-of-goo/world-of-goo-1.41-r1.ebuild
+++ /dev/null
@@ -1,67 +0,0 @@
-# Copyright 1999-2015 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=5
-inherit eutils games
-
-DESCRIPTION="A puzzle game with a strong emphasis on physics"
-HOMEPAGE="http://2dboy.com/"
-
-if [[ ${PN} == *-demo ]] ; then
-	MY_PN="WorldOfGooDemo"
-	SRC_URI="${MY_PN}.${PV}.tar.gz"
-else
-	MY_PN="WorldOfGoo"
-	SRC_URI="${MY_PN}Setup.${PV}.tar.gz"
-fi
-
-LICENSE="2dboy-EULA"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE=""
-RESTRICT="fetch strip"
-
-RDEPEND="media-libs/libsdl[alsa,sound,opengl,video]
-	media-libs/sdl-mixer[vorbis]
-	sys-libs/glibc
-	virtual/opengl
-	virtual/glu
-	>=sys-devel/gcc-3.4"
-DEPEND=""
-
-S=${WORKDIR}/${MY_PN}
-dir=${GAMES_PREFIX_OPT}/${PN}
-
-QA_PREBUILT="${dir:1}/${MY_PN%Demo}.bin32
-	${dir:1}/${MY_PN%Demo}.bin64"
-
-pkg_nofetch() {
-	if [[ ${PN} == *-demo ]] ; then
-		elog "To download the demo, visit http://worldofgoo.com/dl2.php?lk=demo"
-		elog "and download ${A} and place it in ${DISTDIR}"
-	else
-		elog "Download ${A} from ${HOMEPAGE} and place it in ${DISTDIR}"
-	fi
-}
-
-src_install() {
-	exeinto "${dir}"
-	doexe ${MY_PN%Demo}{,.$(usex amd64 bin64 bin32)}
-
-	games_make_wrapper ${PN} "${dir}"/${MY_PN%Demo}
-
-	insinto "${dir}"
-	doins -r icons properties res
-	newicon icons/scalable.svg ${PN}.svg
-
-	if [[ ${PN} == *-demo ]] ; then
-		make_desktop_entry ${PN} "World of Goo (Demo)"
-	else
-		make_desktop_entry ${PN} "World of Goo"
-	fi
-
-	dodoc linux-issues.txt
-	dohtml readme.html
-
-	prepgamesdirs
-}
diff --git a/games-puzzle/world-of-goo/world-of-goo-1.41-r2.ebuild b/games-puzzle/world-of-goo/world-of-goo-1.41-r2.ebuild
new file mode 100644
index 000000000000..51f7f12ff569
--- /dev/null
+++ b/games-puzzle/world-of-goo/world-of-goo-1.41-r2.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit desktop eutils		# eutils for make_wrapper()
+
+DESCRIPTION="A puzzle game with a strong emphasis on physics"
+HOMEPAGE="http://2dboy.com/"
+
+if [[ ${PN} == *-demo ]] ; then
+	MY_PN="WorldOfGooDemo"
+	SRC_URI="${MY_PN}.${PV}.tar.gz"
+else
+	MY_PN="WorldOfGoo"
+	SRC_URI="${MY_PN}Setup.${PV}.tar.gz"
+fi
+
+LICENSE="2dboy-EULA"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+RESTRICT="fetch bindist strip"
+
+RDEPEND="media-libs/libsdl[alsa,sound,opengl,video]
+	media-libs/sdl-mixer[vorbis]
+	sys-libs/glibc
+	virtual/opengl
+	virtual/glu
+	>=sys-devel/gcc-3.4"
+
+S="${WORKDIR}/${MY_PN}"
+dir="/opt/${PN}"
+
+QA_PREBUILT="${dir:1}/${MY_PN%Demo}.bin32
+	${dir:1}/${MY_PN%Demo}.bin64"
+
+pkg_nofetch() {
+	if [[ ${PN} == *-demo ]] ; then
+		elog "To download the demo, visit http://worldofgoo.com/dl2.php?lk=demo"
+		elog "and download ${A} and place it in your DISTDIR directory."
+	else
+		elog "Download ${A} from ${HOMEPAGE}"
+		elog "and place it in your DISTDIR directory."
+	fi
+}
+
+src_install() {
+	exeinto "${dir}"
+	doexe ${MY_PN%Demo}{,.$(usex amd64 bin64 bin32)}
+
+	make_wrapper ${PN} "${dir}"/${MY_PN%Demo}
+
+	insinto "${dir}"
+	doins -r icons properties res
+	newicon icons/scalable.svg ${PN}.svg
+
+	if [[ ${PN} == *-demo ]] ; then
+		make_desktop_entry ${PN} "World of Goo (Demo)"
+	else
+		make_desktop_entry ${PN} "World of Goo"
+	fi
+
+	dodoc linux-issues.txt
+	docinto html
+	dodoc readme.html
+}
-- 
cgit v1.2.3-65-gdbad