From 304759386bfcbedbcc940a9938ec56cc1dba69f9 Mon Sep 17 00:00:00 2001
From: Mart Raudsepp <leio@gentoo.org>
Date: Sat, 1 Aug 2020 12:46:02 +0300
Subject: gnome-base/librsvg: bump to 2.48.8

Closes: https://bugs.gentoo.org/648990
Closes: https://bugs.gentoo.org/645036
Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio@gentoo.org>
---
 gnome-base/librsvg/Manifest              |  1 +
 gnome-base/librsvg/librsvg-2.48.8.ebuild | 95 ++++++++++++++++++++++++++++++++
 2 files changed, 96 insertions(+)
 create mode 100644 gnome-base/librsvg/librsvg-2.48.8.ebuild

(limited to 'gnome-base/librsvg')

diff --git a/gnome-base/librsvg/Manifest b/gnome-base/librsvg/Manifest
index f4e67a4a2da1..a5142954819c 100644
--- a/gnome-base/librsvg/Manifest
+++ b/gnome-base/librsvg/Manifest
@@ -1 +1,2 @@
 DIST librsvg-2.40.21.tar.xz 1655860 BLAKE2B a3fd7915d39984057e860da90115d9d95cef97e61d3f5e4c3aaaf399c4b3bfe781e6a7b969958ae84a3b7f2c788576fe26f56b037ca0a6a2e059b53f2bd1b9fc SHA512 db0563d8e0edaae642a6b2bcd239cf54191495058ac8c7ff614ebaf88c0e30bd58dbcd41f58d82a9d5ed200ced45fc5bae22f2ed3cf3826e9348a497009e1280
+DIST librsvg-2.48.8.tar.xz 15302184 BLAKE2B 7d44b58d894afbeff0cb4606ed64191c028e7ac9d987dd3248b90df4ae0c000ee47b02484116bf7ee6e7aad567b91df7a2aae6880514f5ddee3ef4826c2e828e SHA512 7b35afbbad17927168acb3a308bff59ea66e8e1ac18c2ab5626a7d494e90d87d2dc552959ad72974d3ed8ba4c2f919335cf9110a0d0a09148e606222e4fcee43
diff --git a/gnome-base/librsvg/librsvg-2.48.8.ebuild b/gnome-base/librsvg/librsvg-2.48.8.ebuild
new file mode 100644
index 000000000000..c5ec2752fa96
--- /dev/null
+++ b/gnome-base/librsvg/librsvg-2.48.8.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 multilib-minimal rust-toolchain vala
+
+DESCRIPTION="Scalable Vector Graphics (SVG) rendering library"
+HOMEPAGE="https://wiki.gnome.org/Projects/LibRsvg"
+
+LICENSE="LGPL-2+"
+SLOT="2"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+IUSE="+introspection +vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND="
+	>=x11-libs/cairo-1.16.0[${MULTILIB_USEDEP}]
+	>=media-libs/freetype-2.9:2[${MULTILIB_USEDEP}]
+	>=x11-libs/gdk-pixbuf-2.20:2[introspection?,${MULTILIB_USEDEP}]
+	>=dev-libs/glib-2.50.0:2[${MULTILIB_USEDEP}]
+	>=media-libs/harfbuzz-2.0.0:=[${MULTILIB_USEDEP}]
+	>=dev-libs/libxml2-2.9.1-r4:2[${MULTILIB_USEDEP}]
+	>=x11-libs/pango-1.38.0[${MULTILIB_USEDEP}]
+
+	introspection? ( >=dev-libs/gobject-introspection-0.10.8:= )
+"
+DEPEND="${RDEPEND}
+	>=virtual/rust-1.39[${MULTILIB_USEDEP}]
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+# >=gtk-doc-am-1.13, gobject-introspection-common, vala-common needed by eautoreconf
+
+RESTRICT="test" # Lots of issues on 32bit builds, 64bit build seems to get into an infinite compilation sometimes, etc.
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+multilib_src_configure() {
+	local myconf=(
+		--disable-static
+		--disable-debug
+		--disable-tools # the tools/ subdirectory is useful only for librsvg devs
+		$(multilib_native_use_enable introspection)
+		$(multilib_native_use_enable vala)
+		--enable-pixbuf-loader
+	)
+
+	if ! multilib_is_native_abi; then
+		myconf+=(
+			# Set the rust target, which can differ from CHOST
+			RUST_TARGET="$(rust_abi)"
+			# RUST_TARGET is only honored if cross_compiling, but non-native ABIs aren't cross as
+			# far as C parts and configure auto-detection are concerned as CHOST equals CBUILD
+			cross_compiling=yes
+		)
+	fi
+
+	ECONF_SOURCE=${S} \
+	gnome2_src_configure "${myconf[@]}"
+
+	if multilib_is_native_abi; then
+		ln -s "${S}"/doc/html doc/html || die
+	fi
+}
+
+multilib_src_compile() {
+	# causes segfault if set, see bug #411765
+	unset __GL_NO_DSO_FINALIZER
+	gnome2_src_compile
+}
+
+multilib_src_install() {
+	gnome2_src_install
+}
+
+pkg_postinst() {
+	# causes segfault if set, see bug 375615
+	unset __GL_NO_DSO_FINALIZER
+	multilib_foreach_abi gnome2_pkg_postinst
+}
+
+pkg_postrm() {
+	# causes segfault if set, see bug 375615
+	unset __GL_NO_DSO_FINALIZER
+	multilib_foreach_abi gnome2_pkg_postrm
+}
-- 
cgit v1.2.3-65-gdbad