From bde161a98463ba58ae82e96280381f3fed8f7e8b Mon Sep 17 00:00:00 2001
From: "Matthew S. Turnbull" <sparky@bluefang-logic.com>
Date: Sun, 23 Jun 2024 23:53:06 -0400
Subject: gnome-extra/cinnamon-settings-daemon: add 6.2.0

Bug: https://bugs.gentoo.org/934783
Signed-off-by: Matthew S. Turnbull <sparky@bluefang-logic.com>
Signed-off-by: Eli Schwartz <eschwartz@gentoo.org>
---
 gnome-extra/cinnamon-settings-daemon/Manifest      |  1 +
 .../cinnamon-settings-daemon-6.2.0.ebuild          | 95 ++++++++++++++++++++++
 2 files changed, 96 insertions(+)
 create mode 100644 gnome-extra/cinnamon-settings-daemon/cinnamon-settings-daemon-6.2.0.ebuild

(limited to 'gnome-extra')

diff --git a/gnome-extra/cinnamon-settings-daemon/Manifest b/gnome-extra/cinnamon-settings-daemon/Manifest
index 5af75bf3b287..0d832fc83741 100644
--- a/gnome-extra/cinnamon-settings-daemon/Manifest
+++ b/gnome-extra/cinnamon-settings-daemon/Manifest
@@ -1,2 +1,3 @@
 DIST cinnamon-settings-daemon-5.8.1.tar.gz 573541 BLAKE2B 50d8e6fb1fde50db7cc40c931e0904c0abfa429dc5757160fdb87ee2753f4d9e732ba4a0837c0480a73a3caffb084881c8aac336f8600afe976adc519b09aa01 SHA512 a5e92aa9ba463cff7db02e9d377a28b39e4c1dd25226ab9d4d59b5fd7b38267c6da5f31cfa052f1a8243de601c7484040be158e633b8932e2e68726860c7bfc3
 DIST cinnamon-settings-daemon-6.0.0.tar.gz 578061 BLAKE2B f05e14e9d3c15bc94df5435b0f317e1924993fbf4908491ea5a825b623c6a6f127ce20f5c31f54bfbd547a70ad645c3dbe71d9c55f790a3e0730d55bc58d6316 SHA512 44348765bf8c0cb941d177a6765aef10796d72f5c215dbffa4b514523956e257128d6bbbb0dcd9c3f0b2bcde24745e082ad82a7cee149125903e13b349c07200
+DIST cinnamon-settings-daemon-6.2.0.tar.gz 578907 BLAKE2B 24b9591f5e6bbacd92f564bfb4f1960c14bca78194dd00746ff4b31f2a6b99d09a701ca939aa39b932141c7c13d998b1a061185bd7b751815dbd8b43d1fceec2 SHA512 c2102ace141448694a4d22331f1b039ccdca41988165f0e1af4446c527be89f8ae2f87e0555a0cf4fa5bbb31e5c866f0c9c7a52174a1664183695695b5eed7be
diff --git a/gnome-extra/cinnamon-settings-daemon/cinnamon-settings-daemon-6.2.0.ebuild b/gnome-extra/cinnamon-settings-daemon/cinnamon-settings-daemon-6.2.0.ebuild
new file mode 100644
index 000000000000..bf665356ce46
--- /dev/null
+++ b/gnome-extra/cinnamon-settings-daemon/cinnamon-settings-daemon-6.2.0.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit meson gnome2-utils python-any-r1 xdg
+
+DESCRIPTION="Cinnamon's settings daemon"
+HOMEPAGE="https://projects.linuxmint.com/cinnamon/ https://github.com/linuxmint/cinnamon-settings-daemon"
+SRC_URI="https://github.com/linuxmint/cinnamon-settings-daemon/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+ LGPL-2+ LGPL-2.1 LGPL-2.1+ MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="+colord cups input_devices_wacom smartcard systemd wayland"
+
+RDEPEND="
+	>=dev-libs/glib-2.40.0:2[dbus]
+	dev-libs/libgudev
+	>=gnome-base/libgnomekbd-3.6:=
+	>=gnome-extra/cinnamon-desktop-6.2:0=
+	media-libs/fontconfig
+	>=media-libs/lcms-2.2:2
+	media-libs/libcanberra[gtk3,pulseaudio]
+	>=media-libs/libpulse-0.9.16[glib]
+	>=sys-auth/polkit-0.97
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	>=x11-libs/gtk+-3.14.0:3[wayland=]
+	>=x11-libs/libnotify-0.7.3
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	>=x11-libs/libxklavier-5.0:=
+	>=x11-libs/pango-1.20.0
+	>=sys-power/upower-0.9.11:=
+
+	colord? ( >=x11-misc/colord-0.1.27:= )
+	cups? (
+		>=net-print/cups-1.4[dbus]
+		app-admin/system-config-printer
+		net-print/cups-pk-helper )
+	input_devices_wacom? (
+		>=dev-libs/libwacom-0.7:=
+		>=gnome-base/librsvg-2.36.2 )
+	smartcard? (
+		dev-libs/nspr
+		>=dev-libs/nss-3.11.2
+	)
+	systemd? ( sys-apps/systemd:0= )
+	!systemd? ( sys-auth/elogind )
+"
+DEPEND="
+	${RDEPEND}
+	dev-libs/libxml2:2
+	x11-base/xorg-proto
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-util/glib-utils
+	dev-util/gdbus-codegen
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	python_fix_shebang install-scripts
+}
+
+src_configure() {
+	# gudev not optional on Linux platforms
+	local emesonargs=(
+		-Duse_gudev=enabled
+		-Duse_polkit=enabled
+		-Duse_logind=enabled
+		$(meson_feature colord use_color)
+		$(meson_feature cups use_cups)
+		$(meson_feature smartcard use_smartcard)
+		$(meson_feature input_devices_wacom use_wacom)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
-- 
cgit v1.2.3-65-gdbad