From c81d197b536bd22d1ec51b014998a6a9cd64f476 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Sun, 12 Nov 2023 10:24:54 +0100
Subject: kde-frameworks/breeze-icons-rcc: 5.112.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 kde-frameworks/breeze-icons-rcc/Manifest           |  1 +
 .../breeze-icons-rcc-5.112.0.ebuild                | 49 ++++++++++++++++++++++
 2 files changed, 50 insertions(+)
 create mode 100644 kde-frameworks/breeze-icons-rcc/breeze-icons-rcc-5.112.0.ebuild

(limited to 'kde-frameworks/breeze-icons-rcc')

diff --git a/kde-frameworks/breeze-icons-rcc/Manifest b/kde-frameworks/breeze-icons-rcc/Manifest
index 4837ef72614f..c2fd629c14bb 100644
--- a/kde-frameworks/breeze-icons-rcc/Manifest
+++ b/kde-frameworks/breeze-icons-rcc/Manifest
@@ -1,2 +1,3 @@
 DIST breeze-icons-5.110.0.tar.xz 2173008 BLAKE2B 68c84b739228ad7ed91bcebcf10ec4402f36f70461449d85172e07d1c77923ae1a47c4dc6915c432230b0b7a936186454cfb94bf51af7393ec22302485b58000 SHA512 f13bde27c3da39c60dd3ec2e250eaefaa9fe29b01f740e87a0774d0717f95499b72c0fefed786f9ec66e7e31fd9d853837dd1e8ce300c4456d94ad8d56eb2321
 DIST breeze-icons-5.111.0.tar.xz 2172892 BLAKE2B 43b82d46adc720d14e190410e7e8570edcf6e91911dcae8d71dba5f9a88d54ea97b878c2fa97a5f7bead19b475ea800b8a5a136c0ca10ee7d088902b0242cf6d SHA512 ef3671517ba244e973b246e3b0854e64d179949447f6f0d619cd48e3cd561f648bd38cd256ad5670a754c38d90754bd75eca6bb8976c82e39d74417fdabd1598
+DIST breeze-icons-5.112.0.tar.xz 2172852 BLAKE2B 0b00973c6d8fbb9aa42b8f3f7b4143b26d878f5f9e53444d021d1e6fa0f17490ceea93a2ae5608700d70f00f66842f58b00bb876a32c032dd9dadf6f0633121a SHA512 7773d209b3b6a5c2d1ebc8be4cfb53fe443245c6baab0af65999903b4c29a36677a0b4215ed59ddf8ffb607d08f1fe354cd723ba95b8ee4f610da8d33ede214d
diff --git a/kde-frameworks/breeze-icons-rcc/breeze-icons-rcc-5.112.0.ebuild b/kde-frameworks/breeze-icons-rcc/breeze-icons-rcc-5.112.0.ebuild
new file mode 100644
index 000000000000..9d5e3a45cfcf
--- /dev/null
+++ b/kde-frameworks/breeze-icons-rcc/breeze-icons-rcc-5.112.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KDE_ORG_NAME="breeze-icons"
+PVCUT=$(ver_cut 1-2)
+PYTHON_COMPAT=( python3_{10..12} )
+inherit cmake frameworks.kde.org python-any-r1
+
+DESCRIPTION="Breeze SVG icon theme binary resource"
+LICENSE="LGPL-3"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="test"
+
+RESTRICT="!test? ( test )"
+
+DEPEND="test? ( dev-qt/qttest:5 )"
+BDEPEND="${PYTHON_DEPS}
+	$(python_gen_any_dep 'dev-python/lxml[${PYTHON_USEDEP}]')
+	dev-qt/qtcore:5
+	>=kde-frameworks/extra-cmake-modules-${PVCUT}:5
+	test? ( app-misc/fdupes )
+"
+
+python_check_deps() {
+	python_has_version "dev-python/lxml[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	cmake_src_prepare
+	use test || cmake_comment_add_subdirectory autotests
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPython_EXECUTABLE="${PYTHON}"
+		-DBINARY_ICONS_RESOURCE=ON
+		-DSKIP_INSTALL_ICONS=ON
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	# provided by kde-frameworks/breeze-icons
+	rm -rv "${ED}"/usr/$(get_libdir)/cmake/KF5BreezeIcons || die
+}
-- 
cgit v1.2.3-65-gdbad