From 4c0fb90e550f472a8ad3bd4d9338469287cd60a4 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Sun, 28 Mar 2021 15:20:37 +0200
Subject: media-libs/libcdr: 0.1.7 version bump

Package-Manager: Portage-3.0.17, Repoman-3.0.2
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 media-libs/libcdr/libcdr-0.1.7.ebuild | 57 +++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 media-libs/libcdr/libcdr-0.1.7.ebuild

(limited to 'media-libs/libcdr/libcdr-0.1.7.ebuild')

diff --git a/media-libs/libcdr/libcdr-0.1.7.ebuild b/media-libs/libcdr/libcdr-0.1.7.ebuild
new file mode 100644
index 000000000000..fb7137dfd9bc
--- /dev/null
+++ b/media-libs/libcdr/libcdr-0.1.7.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} = 9999 ]]; then
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/libreoffice/libcdr.git"
+	inherit autotools git-r3
+else
+	SRC_URI="https://dev-www.libreoffice.org/src/libcdr/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+fi
+
+DESCRIPTION="Library parsing the Corel cdr documents"
+HOMEPAGE="https://wiki.documentfoundation.org/DLP/Libraries/libcdr"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+IUSE="doc test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/icu:=
+	dev-libs/librevenge
+	media-libs/lcms:2
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}
+	dev-libs/boost
+"
+BDEPEND="
+	sys-devel/libtool
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	test? ( dev-util/cppunit )
+"
+
+src_prepare() {
+	default
+	[[ -d m4 ]] || mkdir "m4"
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-static
+		$(use_with doc docs)
+		$(use_enable test tests)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
-- 
cgit v1.2.3-65-gdbad