From bddd1d20b9d1e4a4e5917517dac1def707991d98 Mon Sep 17 00:00:00 2001
From: Alfredo Tupone <tupone@gentoo.org>
Date: Sun, 22 Dec 2024 21:53:20 +0100
Subject: net-misc/unison: fix desktop entry

Closes: https://bugs.gentoo.org/946708
Signed-off-by: Alfredo Tupone <tupone@gentoo.org>
---
 net-misc/unison/unison-2.53.7-r1.ebuild | 145 ++++++++++++++++++++++++++++++++
 net-misc/unison/unison-2.53.7.ebuild    | 145 --------------------------------
 2 files changed, 145 insertions(+), 145 deletions(-)
 create mode 100644 net-misc/unison/unison-2.53.7-r1.ebuild
 delete mode 100644 net-misc/unison/unison-2.53.7.ebuild

(limited to 'net-misc')

diff --git a/net-misc/unison/unison-2.53.7-r1.ebuild b/net-misc/unison/unison-2.53.7-r1.ebuild
new file mode 100644
index 000000000000..f50d2cc3f428
--- /dev/null
+++ b/net-misc/unison/unison-2.53.7-r1.ebuild
@@ -0,0 +1,145 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit desktop xdg-utils
+
+DESCRIPTION="Two-way cross-platform file synchronizer"
+HOMEPAGE="https://www.seas.upenn.edu/~bcpierce/unison/
+	https://github.com/bcpierce00/unison/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/bcpierce00/${PN}.git"
+else
+	SRC_URI="https://github.com/bcpierce00/${PN}/archive/refs/tags/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+	KEYWORDS="~amd64 ~arm ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+fi
+
+LICENSE="GPL-2"
+SLOT="$(ver_cut 1-2)"
+IUSE="doc gui +ocamlopt"
+
+BDEPEND="
+	dev-lang/ocaml:=[ocamlopt?]
+	doc? (
+		app-text/dvipsk
+		app-text/ghostscript-gpl
+		dev-texlive/texlive-latex
+	)
+"
+DEPEND="
+	gui? (
+		dev-ml/lablgtk:3=[ocamlopt?]
+	)
+"
+RDEPEND="
+	>=dev-lang/ocaml-4.08:=
+	gui? (
+		dev-ml/lablgtk:3=[ocamlopt?]
+		|| (
+			net-misc/ssh-askpass-fullscreen
+			net-misc/x11-ssh-askpass
+		)
+	)
+"
+IDEPEND="
+	>=app-eselect/eselect-unison-0.4
+"
+
+DOCS=( CONTRIBUTING.md README.md src/FEATURES.md src/ROADMAP.txt src/TODO.txt )
+
+QA_FLAGS_IGNORED="usr/bin/${PN}-fsmonitor-${SLOT}"
+
+gui_cache_update() {
+	if use gui ; then
+		xdg_icon_cache_update
+		xdg_desktop_database_update
+	fi
+}
+
+src_compile() {
+	local -a myconf=()
+
+	if ! use ocamlopt ; then
+		myconf+=( NATIVE=false )
+	fi
+
+	# Discard cflags as it will try to pass them to ocamlc...
+	emake "${myconf[@]}" CFLAGS="" -j1 tui fsmonitor manpage
+
+	if use gui ; then
+		emake "${myconf[@]}" CFLAGS="" -j1 gui
+	fi
+
+	if use doc ; then
+		VARTEXFONTS="${T}/fonts" emake "${myconf[@]}" CFLAGS="" HEVEA=false docs
+	fi
+}
+
+src_test() {
+	emake test CFLAGS=""
+}
+
+src_install() {
+	# OCaml generates textrels on 32-bit arches
+	if use arm || use ppc || use x86 ; then
+		export QA_TEXTRELS='.*'
+	fi
+
+	# install manually, since it's just too much
+	# work to force the Makefile to do the right thing.
+	cd "${S}/src" || die
+
+	local -a bins=(
+		unison-fsmonitor
+	)
+
+	# Unison GUI is a CLI + GTK GUI in one binary, no need to install both,
+	# see bug https://bugs.gentoo.org/941780
+	if use gui ; then
+		bins+=( unison-gui )
+	else
+		bins+=( unison )
+	fi
+
+	local binname
+	for binname in "${bins[@]}" ; do
+		exeinto /usr/bin
+		newexe "${binname}" "${binname/-gui/}-${SLOT}"
+	done
+
+	cd "${S}" || die
+
+	if use gui ; then
+		newicon -s scalable icons/U.svg "${PN}-${SLOT}.svg"
+		make_desktop_entry "${PN}-${SLOT}" "${PN^} GUI (${SLOT})" "${PN}-${SLOT}"
+	fi
+
+	if use doc ; then
+		DOCS+=( doc/unison-manual.pdf )
+	fi
+
+	doman "man/${PN}.1"
+	einstalldocs
+}
+
+pkg_postinst() {
+	elog "Unison now uses SLOTs, so you can specify servercmd=/usr/bin/unison-${SLOT}"
+	elog "in your profile files to access exactly this version over ssh."
+	elog "Or you can use 'eselect unison' to set the version."
+
+	eselect unison update
+
+	gui_cache_update
+}
+
+pkg_postrm() {
+	eselect unison update
+
+	gui_cache_update
+}
diff --git a/net-misc/unison/unison-2.53.7.ebuild b/net-misc/unison/unison-2.53.7.ebuild
deleted file mode 100644
index b7cb3a039129..000000000000
--- a/net-misc/unison/unison-2.53.7.ebuild
+++ /dev/null
@@ -1,145 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit desktop xdg-utils
-
-DESCRIPTION="Two-way cross-platform file synchronizer"
-HOMEPAGE="https://www.seas.upenn.edu/~bcpierce/unison/
-	https://github.com/bcpierce00/unison/"
-
-if [[ "${PV}" == *9999* ]] ; then
-	inherit git-r3
-
-	EGIT_REPO_URI="https://github.com/bcpierce00/${PN}.git"
-else
-	SRC_URI="https://github.com/bcpierce00/${PN}/archive/refs/tags/v${PV}.tar.gz
-		-> ${P}.gh.tar.gz"
-
-	KEYWORDS="~amd64 ~arm ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
-fi
-
-LICENSE="GPL-2"
-SLOT="$(ver_cut 1-2)"
-IUSE="doc gui +ocamlopt"
-
-BDEPEND="
-	dev-lang/ocaml:=[ocamlopt?]
-	doc? (
-		app-text/dvipsk
-		app-text/ghostscript-gpl
-		dev-texlive/texlive-latex
-	)
-"
-DEPEND="
-	gui? (
-		dev-ml/lablgtk:3=[ocamlopt?]
-	)
-"
-RDEPEND="
-	>=dev-lang/ocaml-4.08:=
-	gui? (
-		dev-ml/lablgtk:3=[ocamlopt?]
-		|| (
-			net-misc/ssh-askpass-fullscreen
-			net-misc/x11-ssh-askpass
-		)
-	)
-"
-IDEPEND="
-	>=app-eselect/eselect-unison-0.4
-"
-
-DOCS=( CONTRIBUTING.md README.md src/FEATURES.md src/ROADMAP.txt src/TODO.txt )
-
-QA_FLAGS_IGNORED="usr/bin/${PN}-fsmonitor-${SLOT}"
-
-gui_cache_update() {
-	if use gui ; then
-		xdg_icon_cache_update
-		xdg_desktop_database_update
-	fi
-}
-
-src_compile() {
-	local -a myconf=()
-
-	if ! use ocamlopt ; then
-		myconf+=( NATIVE=false )
-	fi
-
-	# Discard cflags as it will try to pass them to ocamlc...
-	emake "${myconf[@]}" CFLAGS="" -j1 tui fsmonitor manpage
-
-	if use gui ; then
-		emake "${myconf[@]}" CFLAGS="" -j1 gui
-	fi
-
-	if use doc ; then
-		VARTEXFONTS="${T}/fonts" emake "${myconf[@]}" CFLAGS="" HEVEA=false docs
-	fi
-}
-
-src_test() {
-	emake test CFLAGS=""
-}
-
-src_install() {
-	# OCaml generates textrels on 32-bit arches
-	if use arm || use ppc || use x86 ; then
-		export QA_TEXTRELS='.*'
-	fi
-
-	# install manually, since it's just too much
-	# work to force the Makefile to do the right thing.
-	cd "${S}/src" || die
-
-	local -a bins=(
-		unison-fsmonitor
-	)
-
-	# Unison GUI is a CLI + GTK GUI in one binary, no need to install both,
-	# see bug https://bugs.gentoo.org/941780
-	if use gui ; then
-		bins+=( unison-gui )
-	else
-		bins+=( unison )
-	fi
-
-	local binname
-	for binname in "${bins[@]}" ; do
-		exeinto /usr/bin
-		newexe "${binname}" "${binname/-gui/}-${SLOT}"
-	done
-
-	cd "${S}" || die
-
-	if use gui ; then
-		newicon -s scalable icons/U.svg "${PN}-${SLOT}.svg"
-		make_desktop_entry "${PN}-gui-${SLOT}" "${PN^} GUI (${SLOT})" "${PN}-${SLOT}"
-	fi
-
-	if use doc ; then
-		DOCS+=( doc/unison-manual.pdf )
-	fi
-
-	doman "man/${PN}.1"
-	einstalldocs
-}
-
-pkg_postinst() {
-	elog "Unison now uses SLOTs, so you can specify servercmd=/usr/bin/unison-${SLOT}"
-	elog "in your profile files to access exactly this version over ssh."
-	elog "Or you can use 'eselect unison' to set the version."
-
-	eselect unison update
-
-	gui_cache_update
-}
-
-pkg_postrm() {
-	eselect unison update
-
-	gui_cache_update
-}
-- 
cgit v1.2.3-65-gdbad