From c8918d47344c8d5e776b1b960d40c52ec79139e3 Mon Sep 17 00:00:00 2001
From: Zac Medico <zmedico@gentoo.org>
Date: Sat, 17 Oct 2020 21:48:08 -0700
Subject: sys-apps/flatpak: Initial import

Closes: https://bugs.gentoo.org/722680
Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Zac Medico <zmedico@gentoo.org>
---
 sys-apps/flatpak/Manifest             |  1 +
 sys-apps/flatpak/flatpak-1.8.2.ebuild | 93 +++++++++++++++++++++++++++++++++++
 sys-apps/flatpak/metadata.xml         | 11 +++++
 3 files changed, 105 insertions(+)
 create mode 100644 sys-apps/flatpak/Manifest
 create mode 100644 sys-apps/flatpak/flatpak-1.8.2.ebuild
 create mode 100644 sys-apps/flatpak/metadata.xml

(limited to 'sys-apps/flatpak')

diff --git a/sys-apps/flatpak/Manifest b/sys-apps/flatpak/Manifest
new file mode 100644
index 000000000000..3fcd56345efd
--- /dev/null
+++ b/sys-apps/flatpak/Manifest
@@ -0,0 +1 @@
+DIST flatpak-1.8.2.tar.xz 1424468 BLAKE2B 4ade582176cd4ed494d0afc2a75b81168dc2263183d4ec2ef731b2d3ccbd96a7cc0fdb012f07966b4429529ab69c79b32abbcc4c1a8640b030d3ba2edfbce36d SHA512 f27c05b2621328dce31e4c31ae097765864bac84f6c1fada23f48c0235c6b85f447948a07861653f7bed4e17e43f8ff3d2c60263e23426c765c787b5f447a4e2
diff --git a/sys-apps/flatpak/flatpak-1.8.2.ebuild b/sys-apps/flatpak/flatpak-1.8.2.ebuild
new file mode 100644
index 000000000000..9ea245581686
--- /dev/null
+++ b/sys-apps/flatpak/flatpak-1.8.2.ebuild
@@ -0,0 +1,93 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit autotools linux-info python-any-r1
+
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.xz"
+DESCRIPTION="Linux application sandboxing and distribution framework"
+HOMEPAGE="https://flatpak.org/"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc gtk kde introspection policykit seccomp systemd"
+
+RDEPEND="
+	acct-group/flatpak
+	acct-user/flatpak
+	>=app-arch/libarchive-2.8
+	app-arch/zstd
+	>=app-crypt/gpgme-1.1.8
+	>=dev-libs/appstream-glib-0.5.10
+	>=dev-libs/glib-2.56:2
+	>=dev-libs/libxml2-2.4
+	dev-libs/json-glib
+	>=dev-util/ostree-2019.5[gpg(+)]
+	|| (
+		dev-util/ostree[curl]
+		dev-util/ostree[soup]
+	)
+	>=gnome-base/dconf-0.26
+	>=net-libs/libsoup-2.4
+	sys-apps/bubblewrap
+	sys-apps/dbus
+	>=sys-fs/fuse-2.9.9:0
+	sys-apps/xdg-dbus-proxy
+	x11-apps/xauth
+	x11-libs/gdk-pixbuf:2
+	x11-libs/libXau
+	policykit? ( >=sys-auth/polkit-0.98 )
+	seccomp? ( sys-libs/libseccomp )
+	systemd? ( sys-apps/systemd )
+"
+
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>=sys-devel/automake-1.13.4
+	>=sys-devel/gettext-0.18.2
+	virtual/pkgconfig
+	dev-util/gdbus-codegen
+	sys-devel/bison
+	introspection? ( >=dev-libs/gobject-introspection-1.40 )
+	doc? (
+		>=dev-util/gtk-doc-1.20
+		dev-libs/libxslt
+	)
+	$(python_gen_any_dep 'dev-python/pyparsing[${PYTHON_USEDEP}]')
+"
+
+PDEPEND="
+	gtk? ( sys-apps/xdg-desktop-portal-gtk )
+	kde? ( kde-plasma/xdg-desktop-portal-kde )
+"
+
+python_check_deps() {
+	has_version -b "dev-python/pyparsing[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	local CONFIG_CHECK="~USER_NS"
+	linux-info_pkg_setup
+	python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-sandboxed-triggers
+		--enable-xauth
+		--localstatedir="${EPREFIX}"/var
+		--with-system-bubblewrap
+		--with-system-dbus-proxy
+		$(use_enable doc documentation)
+		$(use_enable doc gtk-doc)
+		$(use_enable introspection)
+		$(use_enable policykit system-helper)
+		$(use_enable seccomp)
+		$(use_with systemd)
+	)
+
+	econf "${myeconfargs[@]}"
+}
diff --git a/sys-apps/flatpak/metadata.xml b/sys-apps/flatpak/metadata.xml
new file mode 100644
index 000000000000..55de060f05cf
--- /dev/null
+++ b/sys-apps/flatpak/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>zmedico@gentoo.org</email>
+		<name>Zac Medico</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">flatpak/flatpak</remote-id>
+	</upstream>
+</pkgmetadata>
-- 
cgit v1.2.3-65-gdbad