From c09acbf63247eb3b53338282b4353f5dd4b3540d Mon Sep 17 00:00:00 2001
From: Mark Wright <gienah@gentoo.org>
Date: Tue, 19 Apr 2016 20:36:06 +1000
Subject: sys-firmware/iwl3160-ucode: Bump 12, 13 slots, thanks to Elizabeth
 Myers.

Bump 12 slot to 0.12.17.25, 13 slot to 0.13.30.25, 16 slot to 0.16.242414,
thanks to Elizabeth Myers for 12 and 13 slot ebuilds, and for reporting.

Gentoo-bug: 561502

Package-Manager: portage-2.2.28
---
 .../iwl3160-ucode/iwl3160-ucode-0.16.242414.ebuild | 47 ++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 sys-firmware/iwl3160-ucode/iwl3160-ucode-0.16.242414.ebuild

(limited to 'sys-firmware/iwl3160-ucode/iwl3160-ucode-0.16.242414.ebuild')

diff --git a/sys-firmware/iwl3160-ucode/iwl3160-ucode-0.16.242414.ebuild b/sys-firmware/iwl3160-ucode/iwl3160-ucode-0.16.242414.ebuild
new file mode 100644
index 000000000000..42a5a8331b44
--- /dev/null
+++ b/sys-firmware/iwl3160-ucode/iwl3160-ucode-0.16.242414.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit linux-info versionator
+
+DEV_N="${PN:3:4}"
+vc=($(get_all_version_components "${PV}"))
+MY_PV="${vc[2]}.${vc[4]}.${vc[0]}"
+MY_PN="iwlwifi-${DEV_N}-ucode"
+
+DV_MAJOR="4"
+DV_MINOR="3"
+DV_PATCH="0"
+
+DESCRIPTION="Firmware for Intel (R) Dual Band Wireless-AC ${DEV_N}"
+HOMEPAGE="https://wireless.kernel.org/en/users/Drivers/iwlwifi"
+SRC_URI="https://wireless.wiki.kernel.org/_media/en/users/drivers/${MY_PN}-${MY_PV}.tgz -> ${P}.tgz"
+
+LICENSE="ipw3945"
+SLOT="${vc[2]}"
+KEYWORDS="~amd64 ~x86"
+IUSE="bluetooth"
+
+DEPEND=""
+RDEPEND="bluetooth? ( sys-firmware/iwl3160-7260-bt-ucode )
+	!sys-kernel/linux-firmware[-savedconfig]"
+
+S="${WORKDIR}/${MY_PN}-${MY_PV}"
+
+CONFIG_CHECK="~IWLMVM"
+ERROR_IWLMVM="CONFIG_IWLMVM is required to be enabled in /usr/src/linux/.config for the kernel to be able to load the ${DEV_N} firmware"
+
+pkg_pretend() {
+	if kernel_is lt "${DV_MAJOR}" "${DV_MINOR}" "${DV_PATCH}"; then
+		ewarn "Your kernel version is ${KV_MAJOR}.${KV_MINOR}.${KV_PATCH}."
+		ewarn "This microcode image requires a kernel >= ${DV_MAJOR}.${DV_MINOR}.${DV_PATCH}."
+		ewarn "For kernel versions < ${DV_MAJOR}.${DV_MINOR}.${DV_PATCH}, you may install older SLOTS"
+	fi
+}
+
+src_install() {
+	insinto /lib/firmware
+	doins "${S}/iwlwifi-${DEV_N}-${vc[2]}.ucode"
+	dodoc README*
+}
-- 
cgit v1.2.3-65-gdbad