blob: cb062b2471161057e3c437ebb1991730b76a9881 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit toolchain-funcs
DESCRIPTION="Password hashing software that won the Password Hashing Competition (PHC)"
HOMEPAGE="https://github.com/P-H-C/phc-winner-argon2"
SRC_URI="https://github.com/P-H-C/phc-winner-argon2/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="|| ( Apache-2.0 CC0-1.0 )"
SLOT="0/1"
KEYWORDS="alpha amd64 ~arm arm64 hppa ia64 ~mips ~ppc ~ppc64 ~s390 sparc ~x86"
IUSE="static-libs"
S="${WORKDIR}/phc-winner-${P}"
DOCS=( argon2-specs.pdf CHANGELOG.md README.md )
src_prepare() {
default
if ! use static-libs; then
sed -i -e '/LIBRARIES =/s/\$(LIB_ST)//' Makefile || die
fi
sed -i \
-e 's/-O3//' \
-e 's/-g//' \
-e 's/-march=\$(OPTTARGET)//' \
Makefile || die
tc-export CC
if use amd64 || use x86; then
OPTTEST=0
else
OPTTEST=1
fi
}
src_compile() {
emake OPTTEST="${OPTTEST}" LIBRARY_REL="$(get_libdir)" \
ARGON2_VERSION="0~${PV}"
}
src_test() {
emake OPTTEST="${OPTTEST}" test
}
src_install() {
emake OPTTEST="${OPTTEST}" DESTDIR="${ED}" LIBRARY_REL="$(get_libdir)" install
einstalldocs
doman man/argon2.1
}
|
GitWeb
