blob: a93b7873ccff49badcdea45a89f78956e77ea2b3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# Copyright 2022-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
# Note: if bumping pax-utils because of syscall changes in glibc, please
# revbump glibc and update the dependency in its ebuild for the affected
# versions.
PYTHON_COMPAT=( python3_{9..11} )
inherit meson python-single-r1
DESCRIPTION="ELF utils that can check files for security relevant properties"
HOMEPAGE="https://wiki.gentoo.org/index.php?title=Project:Hardened/PaX_Utilities"
if [[ ${PV} == 9999 ]]; then
EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/pax-utils.git"
inherit git-r3
else
SRC_URI="https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${P}.tar.xz
https://dev.gentoo.org/~vapier/dist/${P}.tar.xz"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~sparc64-solaris ~x64-solaris"
fi
LICENSE="GPL-2"
SLOT="0"
IUSE="caps +man python seccomp test"
_PYTHON_DEPS="
${PYTHON_DEPS}
$(python_gen_cond_dep '
dev-python/pyelftools[${PYTHON_USEDEP}]
')
"
RDEPEND="caps? ( >=sys-libs/libcap-2.24 )
python? ( ${_PYTHON_DEPS} )
"
DEPEND="${RDEPEND}"
BDEPEND="
caps? ( virtual/pkgconfig )
man? ( app-text/xmlto )
python? ( ${_PYTHON_DEPS} )
"
REQUIRED_USE="
python? ( ${PYTHON_REQUIRED_USE} )
test? ( python )
"
RESTRICT="
!test? ( test )
"
PATCHES=(
"${FILESDIR}/pax-utils-1.3.5-man-reorder-xmlto-arguments.patch"
)
pkg_setup() {
if use test || use python; then
python-single-r1_pkg_setup
fi
}
src_configure() {
local emesonargs=(
"-Dlddtree_implementation=$(usex python python sh)"
$(meson_feature caps use_libcap)
$(meson_feature man build_manpages)
$(meson_use seccomp use_seccomp)
$(meson_use test tests)
# fuzzing is currently broken
-Duse_fuzzing=false
)
meson_src_configure
}
src_install() {
meson_src_install
use python && python_fix_shebang "${ED}"/usr/bin/lddtree
}
|
GitWeb