blob: f6f51d048670b68ba5d40c7510f123999ae4fdc6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PLOCALES="
ar ast be bg bn bs ca cs da de el en_AU en_CA en_GB eo es et eu fa fi fo fr
gl he hi hr hu hy ia id it ja ko ku ky lt lv ms my nb nds nl nn pl pt pt_BR
ro ru se si sk sl sq sr sv ta te th tr ug uk uz vi zh_CN zh_TW"
PYTHON_COMPAT=( python2_7 )
PYTHON_REQ_USE="sqlite(+)"
inherit distutils-r1 eutils l10n
DESCRIPTION="Clean junk to free disk space and to maintain privacy"
HOMEPAGE="https://www.bleachbit.org"
SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+gtk nls"
RDEPEND="
dev-python/notify-python[$PYTHON_USEDEP]
gtk? ( dev-python/pygtk:2[$PYTHON_USEDEP] )"
DEPEND="${RDEPEND}
nls? ( sys-devel/gettext )"
python_prepare_all() {
rem_locale() {
rm "po/${1}.po" &>/dev/null
if [[ $? -ne 0 ]]; then
eerror "Removing of ${1}.po failed"
die
fi
}
l10n_find_plocales_changes po "" ".po"
l10n_for_each_disabled_locale_do rem_locale
# choose correct Python implementation, bug #465254
sed -i 's/python/$(PYTHON)/g' po/Makefile || die
distutils-r1_python_prepare_all
}
python_compile_all() {
use nls && emake -C po
}
python_install_all() {
distutils-r1_python_install_all
use nls && emake -C po DESTDIR="${D}" install
# https://bugs.gentoo.org/388999
insinto /usr/share/${PN}/cleaners
doins cleaners/*.xml
newbin ${PN}.py ${PN}
python_replicate_script "${D}/usr/bin/${PN}"
doicon ${PN}.png
domenu ${PN}.desktop
}
|
GitWeb
