blob: 2103adde055980428ae9c31028f03480d1509596 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake edo optfeature virtualx xdg
DESCRIPTION="Clipboard manager with advanced features"
HOMEPAGE="https://github.com/hluk/CopyQ"
SRC_URI="https://github.com/hluk/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/CopyQ-${PV}"
LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="debug kde qt6 test"
# Qt6 tests fail with "Failed to stop server" error
RESTRICT="
qt6? ( test )
!test? ( test )
"
RDEPEND="
dev-libs/wayland
x11-libs/libX11
x11-libs/libXfixes
x11-libs/libXtst
!qt6? (
dev-qt/qtcore:5
dev-qt/qtdeclarative:5
dev-qt/qtgui:5
dev-qt/qtnetwork:5
dev-qt/qtsvg:5
dev-qt/qtwayland:5
dev-qt/qtwidgets:5
dev-qt/qtx11extras:5
dev-qt/qtxml:5
kde? ( kde-frameworks/knotifications:5 )
test? ( dev-qt/qttest:5 )
)
qt6? (
dev-qt/qtbase:6=[X,gui,network,test?,widgets,xml(+)]
dev-qt/qtdeclarative:6
dev-qt/qtsvg:6
dev-qt/qtwayland:6
)
"
DEPEND="${RDEPEND}
x11-base/xorg-proto
"
BDEPEND="
kde-frameworks/extra-cmake-modules:5
!qt6? (
dev-qt/linguist-tools:5
dev-qt/qtwaylandscanner:5
)
qt6? (
dev-qt/qttools:6[linguist]
dev-qt/qtwayland:6
dev-util/wayland-scanner
)
test? (
app-crypt/gnupg
x11-wm/icewm
)
"
src_configure() {
if use debug; then
# Add debug definitions
CMAKE_BUILD_TYPE="Debug"
fi
local mycmakeargs=(
-DPLUGIN_INSTALL_PREFIX="${EPREFIX}/usr/$(get_libdir)/${PN}/plugins"
-DWITH_NATIVE_NOTIFICATIONS=$(usex kde)
-DWITH_QT6=$(usex qt6)
-DWITH_TESTS=$(usex test)
)
cmake_src_configure
}
my_src_test() {
local -x COPYQ_TESTS_RERUN_FAILED=0
local -x COPYQ_TESTS_NO_NETWORK=1
local plug
local plugins=(
itemencrypted
itemfakevim
itempinned
#itemsync -- failure in avoidDuplicateItemsAddedFromClipboard()
itemtags
)
ebegin "Starting IceWM"
icewm &
sleep 5
eend 0
cd "${BUILD_DIR}" || die
mkdir -p "${HOME}"/.gnupg || die
for plug in "${plugins[@]}"; do
edo ./copyq tests PLUGINS:"${plug}"
done
# ScriptError: Failed to send key presses
#edo ./copyq tests
}
src_test() {
virtx my_src_test
}
pkg_postinst() {
xdg_pkg_postinst
optfeature "encryption support" app-crypt/gnupg
}
|
GitWeb