1 files changed, 0 insertions, 112 deletions
diff --git a/media-gfx/slic3r/slic3r-9999.ebuild b/media-gfx/slic3r/slic3r-9999.ebuild
deleted file mode 100644
index 0232e08..0000000
--- a/media-gfx/slic3r/slic3r-9999.ebuild
+++ /dev/null
@@ -1,112 +0,0 @@
-# Copyright 1999-2016 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI=6
-
-inherit eutils git-r3 perl-module
-
-DESCRIPTION="A mesh slicer to generate G-code for 3D fused-filament-fabrication (vulgo 3D printers)"
-HOMEPAGE="http://slic3r.org"
-SRC_URI=""
-EGIT_REPO_URI="https://github.com/alexrj/Slic3r.git"
-
-LICENSE="AGPL-3 CC-BY-3.0"
-SLOT="0"
-KEYWORDS=""
-IUSE="+gui test"
-
-# check Build.PL for dependencies
-RDEPEND="!=dev-lang/perl-5.16*
-	>=dev-libs/boost-1.55[threads]
-	dev-perl/Class-XSAccessor
-	dev-perl/Devel-Size
-	>=dev-perl/Encode-Locale-1.50
-	dev-perl/IO-stringy
-	>=dev-perl/Math-PlanePath-53
-	>=dev-perl/Moo-1.3.1
-	dev-perl/XML-SAX-ExpatXS
-	virtual/perl-Carp
-	virtual/perl-Encode
-	virtual/perl-File-Spec
-	virtual/perl-Getopt-Long
-	virtual/perl-parent
-	virtual/perl-Scalar-List-Utils
-	virtual/perl-Test-Simple
-	virtual/perl-Thread-Semaphore
-	>=virtual/perl-threads-1.960
-	virtual/perl-Time-HiRes
-	virtual/perl-Unicode-Normalize
-	virtual/perl-XSLoader
-	gui? ( dev-perl/Class-Accessor
-		dev-perl/Growl-GNTP
-		dev-perl/libwww-perl
-		dev-perl/Module-Pluggable
-		dev-perl/Net-Bonjour
-		dev-perl/Net-DBus
-		dev-perl/OpenGL
-		>=dev-perl/Wx-0.991.800
-		dev-perl/Wx-GLCanvas
-		>=media-libs/freeglut-3
-		virtual/perl-Math-Complex
-		>=virtual/perl-Socket-2.16
-		x11-libs/libXmu
-	)"
-DEPEND="${RDEPEND}
-	dev-perl/Devel-CheckLib
-	>=dev-perl/ExtUtils-CppGuess-0.70
-	>=dev-perl/ExtUtils-Typemaps-Default-1.05
-	>=dev-perl/ExtUtils-XSpp-0.170
-	>=dev-perl/Module-Build-0.380
-	>=dev-perl/Module-Build-WithXSpp-0.140
-	>=virtual/perl-ExtUtils-MakeMaker-6.80
-	>=virtual/perl-ExtUtils-ParseXS-3.22
-	test? (	virtual/perl-Test-Harness
-		virtual/perl-Test-Simple )"
-
-SRC_TEST="do"
-S="${WORKDIR}/slic3r-${PV}/xs"
-
-src_unpack() {
-	git-r3_src_unpack
-}
-
-src_prepare() {
-	pushd "${WORKDIR}/slic3r-${PV}" || die
-	eapply "${FILESDIR}/${P}-adjust_var_path.patch"
-	eapply_user
-	popd || die
-}
-
-src_configure() {
-	SLIC3R_NO_AUTO=1 perl-module_src_configure
-}
-
-src_test() {
-	perl-module_src_test
-	pushd .. || die
-	prove -Ixs/blib/arch -Ixs/blib/lib/ t/ || die "Tests failed"
-	popd || die
-}
-
-src_install() {
-	perl-module_src_install
-
-	pushd .. || die
-	insinto "${VENDOR_LIB}"
-	doins -r lib/Slic3r.pm lib/Slic3r
-
-	insinto "${VENDOR_LIB}"/Slic3r
-	doins -r var
-
-	exeinto "${VENDOR_LIB}"/Slic3r
-	doexe slic3r.pl
-
-	dosym "${VENDOR_LIB}"/Slic3r/slic3r.pl /usr/bin/slic3r.pl
-
-	make_desktop_entry slic3r.pl \
-		Slic3r \
-		"${VENDOR_LIB}/Slic3r/var/Slic3r_128px.png" \
-		"Graphics;3DGraphics;Engineering;Development"
-	popd || die
-}