Version bump, drop old, co-maintain it (as we are in fact doing for some time)

(Portage version: 2.2.12/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

4 files changed, 114 insertions, 95 deletions

diff --git a/net-libs/gupnp-igd/ChangeLog b/net-libs/gupnp-igd/ChangeLog
index a6af7d1bf3f9..08780b30211d 100644
--- a/net-libs/gupnp-igd/ChangeLog
+++ b/net-libs/gupnp-igd/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-libs/gupnp-igd
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/gupnp-igd/ChangeLog,v 1.60 2014/06/24 22:16:31 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gupnp-igd/ChangeLog,v 1.61 2014/10/02 11:52:56 pacho Exp $
+
+*gupnp-igd-0.2.4 (02 Oct 2014)
+
+  02 Oct 2014; Pacho Ramos <pacho@gentoo.org> +gupnp-igd-0.2.4.ebuild,
+  -gupnp-igd-0.2.3.ebuild, metadata.xml:
+  Version bump, drop old, co-maintain it (as we are in fact doing for some time)
 
   24 Jun 2014; Michał Górny <mgorny@gentoo.org> gupnp-igd-0.2.3-r1.ebuild:
   Lower dev-libs/glib dep to first known EAPI=5 version, requested by Funtoo for
diff --git a/net-libs/gupnp-igd/gupnp-igd-0.2.3.ebuild b/net-libs/gupnp-igd/gupnp-igd-0.2.3.ebuild
deleted file mode 100644
index 5bd9a2ce149f..000000000000
--- a/net-libs/gupnp-igd/gupnp-igd-0.2.3.ebuild
+++ /dev/null
@@ -1,89 +0,0 @@
-# Copyright 1999-2014 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/gupnp-igd/gupnp-igd-0.2.3.ebuild,v 1.1 2014/02/06 22:14:39 eva Exp $
-
-EAPI=5
-
-PYTHON_COMPAT=( python2_7 )
-AUTOTOOLS_AUTORECONF=true
-
-inherit autotools-utils gnome.org python-r1
-
-DESCRIPTION="Library to handle UPnP IGD port mapping for GUPnP"
-HOMEPAGE="http://gupnp.org"
-
-LICENSE="LGPL-2"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
-IUSE="+introspection python"
-
-RDEPEND="
-	>=dev-libs/glib-2.26:2
-	net-libs/gssdp
-	>=net-libs/gupnp-0.18
-	introspection? ( >=dev-libs/gobject-introspection-0.10 )
-	python? (
-		>=dev-libs/gobject-introspection-0.10
-		>=dev-python/pygobject-2.16:2[${PYTHON_USEDEP}]
-	)"
-DEPEND="${RDEPEND}
-	dev-util/gtk-doc-am
-	sys-devel/gettext
-	virtual/pkgconfig
-"
-
-# The only existing test is broken
-RESTRICT="test"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-0.1.11-disable_static_modules.patch
-)
-
-src_prepare() {
-	# Python bindings are built/installed manually.
-	if use python; then
-		sed -e "/PYTHON_SUBDIR =/s/ python//" -i Makefile.am Makefile.in || die
-	fi
-	autotools-utils_src_prepare
-}
-
-src_configure() {
-	local myeconfargs=(
-		--disable-static
-		--disable-gtk-doc
-		$(use_enable introspection)
-		$(use_enable python)
-	)
-	autotools-utils_src_configure
-}
-
-src_compile() {
-	autotools-utils_src_compile
-
-	if use python; then
-		python_copy_sources
-
-		building() {
-			cd "${BUILD_DIR}"/python || die
-			emake \
-				PYTHON_INCLUDES="-I$(python_get_includedir)" \
-				pyexecdir="$(python_get_sitedir)"
-		}
-		python_foreach_impl building
-	fi
-}
-
-src_install() {
-	autotools-utils_src_install
-
-	if use python; then
-		installation() {
-			cd "${BUILD_DIR}"/python || die
-			emake \
-				DESTDIR="${D}" \
-				pyexecdir="$(python_get_sitedir)" \
-				install
-		}
-		python_foreach_impl installation
-	fi
-}
diff --git a/net-libs/gupnp-igd/gupnp-igd-0.2.4.ebuild b/net-libs/gupnp-igd/gupnp-igd-0.2.4.ebuild
new file mode 100644
index 000000000000..72a7a753c636
--- /dev/null
+++ b/net-libs/gupnp-igd/gupnp-igd-0.2.4.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gupnp-igd/gupnp-igd-0.2.4.ebuild,v 1.1 2014/10/02 11:52:56 pacho Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+AUTOTOOLS_AUTORECONF=true
+
+inherit eutils gnome.org python-r1 multilib-minimal
+
+DESCRIPTION="Library to handle UPnP IGD port mapping for GUPnP"
+HOMEPAGE="http://gupnp.org"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="+introspection python"
+
+RDEPEND="
+	>=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
+	>=net-libs/gssdp-0.14.7[${MULTILIB_USEDEP}]
+	>=net-libs/gupnp-0.20.10[${MULTILIB_USEDEP}]
+	introspection? ( >=dev-libs/gobject-introspection-0.10 )
+	python? (
+		>=dev-libs/gobject-introspection-0.10
+		>=dev-python/pygobject-2.16:2[${PYTHON_USEDEP}]
+	)"
+DEPEND="${RDEPEND}
+	dev-util/gtk-doc-am
+	sys-devel/gettext
+	>=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
+"
+
+# The only existing test is broken
+RESTRICT="test"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.1.11-disable_static_modules.patch
+)
+
+multilib_src_configure() {
+	local myconf=(
+		--disable-static
+		--disable-gtk-doc
+		$(multilib_native_use_enable introspection)
+		# python is built separately
+		--disable-python
+	)
+
+	ECONF_SOURCE=${S} \
+	econf "${myconf[@]}"
+
+	if multilib_is_native_abi; then
+		ln -s "${S}"/doc/html doc/html || die
+
+		python_configure() {
+			mkdir -p "${BUILD_DIR}" || die
+			cd "${BUILD_DIR}" || die
+
+			ECONF_SOURCE=${S} \
+			econf "${myconf[@]}" \
+				--enable-python
+		}
+
+		use python && python_parallel_foreach_impl python_configure
+	fi
+}
+
+multilib_src_compile() {
+	default
+
+	if multilib_is_native_abi && use python; then
+		local native_builddir=${BUILD_DIR}
+
+		python_compile() {
+			emake -C "${BUILD_DIR}"/python \
+				VPATH="${S}/python:${native_builddir}/python" \
+				igd_la_LIBADD="\$(PYGUPNP_IGD_LIBS) ${native_builddir}/libgupnp-igd/libgupnp-igd-1.0.la"
+		}
+
+		python_foreach_impl python_compile
+	fi
+}
+
+multilib_src_install() {
+	default
+
+	if multilib_is_native_abi && use python; then
+		local native_builddir=${BUILD_DIR}
+
+		python_install() {
+			emake -C "${BUILD_DIR}"/python \
+				VPATH="${S}/python:${native_builddir}/python" \
+				DESTDIR="${D}" install
+		}
+
+		python_foreach_impl python_install
+	fi
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files
+}
diff --git a/net-libs/gupnp-igd/metadata.xml b/net-libs/gupnp-igd/metadata.xml
index 9198b0537de5..45183de7300e 100644
--- a/net-libs/gupnp-igd/metadata.xml
+++ b/net-libs/gupnp-igd/metadata.xml
@@ -1,9 +1,6 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-  <herd>net-p2p</herd>
-  <use>
-    <flag name="introspection">Use <pkg>dev-libs/gobject-introspection</pkg> for
-			introspection</flag>
-  </use>
+<herd>gnome</herd>
+<herd>net-p2p</herd>
 </pkgmetadata>