Revrite ebuild and add few new flags so user can now decide what he wants to install from package

(Portage version: 2.1.3.19)

2 files changed, 171 insertions, 0 deletions

diff --git a/x11-themes/gentoo-artwork/files/digest-gentoo-artwork-0.4.2-r1 b/x11-themes/gentoo-artwork/files/digest-gentoo-artwork-0.4.2-r1
new file mode 100644
index 000000000000..e634fe021cdb
--- /dev/null
+++ b/x11-themes/gentoo-artwork/files/digest-gentoo-artwork-0.4.2-r1
@@ -0,0 +1,18 @@
+MD5 b767350c867c2b06d6897d9b99892068 gentoo-artwork-0.2.tar.bz2 8169652
+RMD160 6fee92536de392a153a206af2df28e8f1080163b gentoo-artwork-0.2.tar.bz2 8169652
+SHA256 e12ef6d99e3dba9217579f7182bcaf558b509680717629f8018f7d2309932f14 gentoo-artwork-0.2.tar.bz2 8169652
+MD5 ca71fa5257bc0bccaf020245111f8086 gentoo-artwork-0.3.tar.bz2 24870943
+RMD160 c4f1619b8d37d9f6a2c70d23250224baa91b7358 gentoo-artwork-0.3.tar.bz2 24870943
+SHA256 1f78f0efb927d7493aad9df61b1833e0f89e039590531c61bebda78c6405c163 gentoo-artwork-0.3.tar.bz2 24870943
+MD5 a7a44fbd295effb62d1dc12cbc19cec6 gentoo-artwork-0.4.1.tar.bz2 2794643
+RMD160 ac1148fe4992400ec133b29f5b0810de26fb308a gentoo-artwork-0.4.1.tar.bz2 2794643
+SHA256 fc345f241282319c9085def4eae33e69b77f1f53301861be349173c49fbc87ca gentoo-artwork-0.4.1.tar.bz2 2794643
+MD5 48f3454eda918e9ac63a296017cf939a gentoo-artwork-0.4.2.tar.bz2 612218
+RMD160 2ca115ebd742e7e559c43b8b2054ef9fa019666e gentoo-artwork-0.4.2.tar.bz2 612218
+SHA256 4a0574dee6bd2c75c9e90fdeeba93ee2782ded954b41e0957bf5ad43343a40ec gentoo-artwork-0.4.2.tar.bz2 612218
+MD5 1278d57bf591a901b50be562637b0768 gentoo-artwork-0.4.tar.bz2 26804896
+RMD160 22e839f57e71b8bcf1a856540111d9cfe2fbb2ba gentoo-artwork-0.4.tar.bz2 26804896
+SHA256 1564fdf9beeb2a8147882f77be8b49591b6025ec61dfb96e069467b9e6d52030 gentoo-artwork-0.4.tar.bz2 26804896
+MD5 121d310c1d7769965598c330127b0580 gentoo-bubble-icons-20060811.tar.gz 2340198
+RMD160 df2604ef6aa4bdb2c4292a109b8fa6752c29ea19 gentoo-bubble-icons-20060811.tar.gz 2340198
+SHA256 519416f265fed18dae57e703727acc34ce479dd2f6c16f84155a2d3e5e87632b gentoo-bubble-icons-20060811.tar.gz 2340198
diff --git a/x11-themes/gentoo-artwork/gentoo-artwork-0.4.2-r1.ebuild b/x11-themes/gentoo-artwork/gentoo-artwork-0.4.2-r1.ebuild
new file mode 100644
index 000000000000..78d810c8565d
--- /dev/null
+++ b/x11-themes/gentoo-artwork/gentoo-artwork-0.4.2-r1.ebuild
@@ -0,0 +1,153 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-themes/gentoo-artwork/gentoo-artwork-0.4.2-r1.ebuild,v 1.1 2008/01/15 12:09:45 cla Exp $
+
+EAPI="1"
+
+BI_VER="20060811"
+
+DESCRIPTION="A collection of miscellaneous Gentoo Linux logos and artwork"
+SRC_URI="pixmaps? (
+		mirror://gentoo/gentoo-artwork-0.2.tar.bz2
+		mirror://gentoo/gentoo-artwork-0.3.tar.bz2
+		mirror://gentoo/gentoo-artwork-0.4.tar.bz2
+		mirror://gentoo/gentoo-artwork-0.4.1.tar.bz2
+		mirror://gentoo/gentoo-artwork-0.4.2.tar.bz2
+		icons? ( mirror://gentoo/gentoo-bubble-icons-${BI_VER}.tar.gz )
+	)
+	!pixmaps? (
+		icons? (
+			mirror://gentoo/gentoo-artwork-0.2.tar.bz2
+			mirror://gentoo/gentoo-artwork-0.3.tar.bz2
+			mirror://gentoo/gentoo-artwork-0.4.tar.bz2
+			mirror://gentoo/gentoo-artwork-0.4.2.tar.bz2
+			mirror://gentoo/gentoo-bubble-icons-${BI_VER}.tar.gz
+		)
+		!icons? (
+			kde? ( mirror://gentoo/gentoo-artwork-0.2.tar.bz2 )
+			!kde? ( grub? ( mirror://gentoo/gentoo-artwork-0.2.tar.bz2 ) )
+			lilo? ( mirror://gentoo/gentoo-artwork-0.4.tar.bz2 )
+		)
+	)"
+HOMEPAGE="http://www.gentoo.org/index-graphics.html"
+
+KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="kde offensive +icons +pixmaps +grub lilo"
+RESTRICT="binchecks strip"
+
+DEPEND=""
+
+src_unpack() {
+	mkdir -p "${WORKDIR}"/${PN}0.2
+	if use pixmaps || use icons || use kde || use grub; then
+		unpack ${PN}-0.2.tar.bz2
+	fi
+	# rename unpacked dir so that updated files get overwritten
+	mv "${WORKDIR}"/${PN}-0.2 "${WORKDIR}"/${PN}-0.3
+	if use pixmaps || use icons; then
+		unpack gentoo-artwork-0.3.tar.bz2
+	fi
+	mv "${WORKDIR}"/${PN}-0.3 "${WORKDIR}"/${PN}-0.4
+	if use pixmaps || use icons || use lilo; then
+		unpack ${PN}-0.4.tar.bz2
+	fi
+	mv "${WORKDIR}"/${PN}-0.4 "${WORKDIR}"/${PN}-0.4.1
+	if use pixmaps; then
+		unpack ${PN}-0.4.1.tar.bz2
+	fi
+	mv "${WORKDIR}"/${PN}-0.4.1 "${WORKDIR}"/${PN}-0.4.2
+	if use pixmaps || use icons; then
+		unpack ${PN}-0.4.2.tar.bz2
+	fi
+
+	if use icons ; then
+		# Gentoo Bubble Icons
+		unpack gentoo-bubble-icons-${BI_VER}.tar.gz
+		cd "${WORKDIR}"/${PN}-0.4.2/icons/gentoo
+
+
+		cp "${FILESDIR}"/index.theme .
+
+		mv l33t/l33t_BRO_lynx.png l33t/l33t_BRO_lynx2.png
+		mv "${WORKDIR}"/gentoo-bubble-icons/README bubble-icons-README
+		find "${WORKDIR}"/gentoo-bubble-icons -name '*.png' \
+			-exec mv "{}" l33t/ \;
+
+		# fix errors in filenames
+		mv l33t/l33t_nero.png l33t/l33t_UTI_nero.png
+
+		# remove misspelled files
+		rm "${S}"/icons/gentoo/{32x32,48x48,64x64}/slypheed.png
+	fi
+
+	if use pixmaps ; then
+		# bug #132271
+		rm "${S}"/pixmaps/1024x768/gentoo-blue-leaf-1024x768.jpg
+		rm "${S}"/pixmaps/1024x768/gentoo-blue-ute-1024x768.jpg
+
+		# move images with wrong size to misc
+		mv "${S}"/pixmaps/800x600/OpenSource_in_the_sun-1280x960.png \
+			"${S}"/pixmaps/misc/OpenSource_in_the_sun-1280x960.png
+		mv "${S}"/pixmaps/1024x768/Gentoo_2parts_1024x768.png \
+			"${S}"/pixmaps/misc/Gentoo_2parts_1024x786.png
+		mv "${S}"/pixmaps/1024x768/Gentoo_transparant_1024x768.png \
+			"${S}"/pixmaps/misc/Gentoo_transparant_960x768.png
+		mv "${S}"/pixmaps/1280x1024/gentoo-freedom-1280x1024,jpg \
+			"${S}"/pixmaps/misc/gentoo-freedom-1280x1012.jpg
+		mv "${S}"/pixmaps/1280x1024/gentoowired.jpg \
+			"${S}"/pixmaps/misc/gentoowired-1280x960.jpg
+		mv "${S}"/pixmaps/1600x1200/gentoo-slip-1600x1200.jpg \
+			"${S}"/pixmaps/misc/gentoo-slip-1200x1024.jpg
+	fi
+
+	if ! use offensive ; then
+		for i in $(<"${FILESDIR}"/offensive_list) ; do
+			rm -f "${S}/${i}"
+		done
+	fi
+}
+
+src_install() {
+	if use pixmaps ; then
+		# pixmaps
+		dodir /usr/share/pixmaps/gentoo/
+		cd "${S}"/pixmaps
+		cp -pPR . "${D}"/usr/share/pixmaps/gentoo/
+		rm "${D}"/usr/share/pixmaps/gentoo/CREDITS
+		dodoc "${S}"/pixmaps/CREDITS
+	fi
+
+	if use kde ; then
+		# a Gentoo colour scheme for KDE
+		insinto /usr/share/apps/kdisplay/color-schemes
+		doins "${S}"/misc/Gentoo.kcsrc
+	fi
+
+	if use icons ; then
+		# Gentoo icons
+		dodir /usr/share/icons/gentoo
+		cp -pR "${S}"/icons/gentoo/* "${D}"/usr/share/icons/gentoo/
+	fi
+
+	if use grub ; then
+		# grub splash images
+		dodir /usr/share/grub/splashimages
+		insinto /usr/share/grub/splashimages
+		doins "${S}"/grub/*.xpm.gz
+	fi
+
+	if use lilo ; then
+		# lilo splash images
+		dodir /usr/share/lilo/splashimages
+		insinto /usr/share/lilo/splashimages
+		doins "${S}"/lilo/*
+		rm "${D}"/usr/share/lilo/splashimages/lilo.txt
+		dodoc "${S}"/lilo/lilo.txt
+	fi
+}
+
+pkg_postinst() {
+	einfo "E-mail any artwork for this package at artwork@gentoo.org"
+}