Fixed compilation failure, bug #154734.

(Portage version: 2.1.1-r1)

4 files changed, 107 insertions, 1 deletions

diff --git a/media-sound/audacity/ChangeLog b/media-sound/audacity/ChangeLog
index d661599ff4eb..48b9242941ec 100644
--- a/media-sound/audacity/ChangeLog
+++ b/media-sound/audacity/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/audacity
 # Copyright 2002-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/audacity/ChangeLog,v 1.51 2006/11/10 16:36:18 dberkholz Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/audacity/ChangeLog,v 1.52 2006/11/16 16:49:50 matsuu Exp $
+
+*audacity-1.3.2-r1 (16 Nov 2006)
+
+  16 Nov 2006; MATSUU Takuto <matsuu@gentoo.org>
+  +files/audacity-1.3.2-disable-optimization.patch,
+  +audacity-1.3.2-r1.ebuild:
+  Fixed compilation failure, bug #154734.
 
   10 Nov 2006; Donnie Berkholz <dberkholz@gentoo.org>;
   audacity-1.3.2.ebuild:
diff --git a/media-sound/audacity/audacity-1.3.2-r1.ebuild b/media-sound/audacity/audacity-1.3.2-r1.ebuild
new file mode 100644
index 000000000000..e3d35af64924
--- /dev/null
+++ b/media-sound/audacity/audacity-1.3.2-r1.ebuild
@@ -0,0 +1,85 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/audacity/audacity-1.3.2-r1.ebuild,v 1.1 2006/11/16 16:49:50 matsuu Exp $
+
+inherit eutils autotools
+
+IUSE="flac ladspa libsamplerate mp3 sse unicode vorbis"
+
+MY_P="${PN}-src-${PV}"
+DESCRIPTION="Free crossplatform audio editor"
+HOMEPAGE="http://audacity.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+RESTRICT="test"
+
+DEPEND=">=x11-libs/wxGTK-2.6
+	>=app-arch/zip-2.3
+	dev-libs/expat
+	vorbis? ( >=media-libs/libvorbis-1.0 )
+	mp3? ( >=media-libs/libmad-0.14.2b
+		media-libs/libid3tag )
+	flac? ( media-libs/flac )
+	>=media-libs/libsndfile-1.0.0
+	libsamplerate? ( >=media-libs/libsamplerate-0.1.2 )"
+RDEPEND="${DEPEND}
+	mp3? ( >=media-sound/lame-3.70 )"
+
+S="${WORKDIR}/${MY_P}-beta"
+
+src_unpack() {
+	unpack ${A}
+
+	cd "${S}"
+	epatch "${FILESDIR}"/${P}-gentoo.patch
+	if ! use sse ; then
+		epatch "${FILESDIR}"/${P}-no-msse.patch
+		epatch "${FILESDIR}"/${P}-disable-optimization.patch
+	fi
+
+	eautoreconf || die
+	pushd "${S}"/lib-src/soundtouch
+	eautoreconf
+	popd
+}
+
+src_compile() {
+	local myconf
+
+	myconf="${myconf} --with-libsndfile=system"
+	myconf="${myconf} --with-libexpat=system"
+
+	if use libsamplerate ; then
+		myconf="${myconf} --with-libsamplerate=system --without-libresample"
+	else
+		myconf="${myconf} --without-libsamplerate" # --with-libresample=local
+	fi
+
+	econf \
+		$(use_enable unicode) \
+		$(use_with ladspa) \
+		$(use_with vorbis vorbis system) \
+		$(use_with mp3 libmad system) \
+		$(use_with mp3 id3tag system) \
+		$(use_with flac flac system) \
+		${myconf} || die
+
+	# parallel borks
+	emake -j1 || die
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+
+	# Remove bad doc install
+	rm -rf "${D}"/usr/share/doc
+
+	# Install our docs
+	dodoc README.txt
+
+	insinto /usr/share/audacity/
+	newins images/AudacityLogo48x48.xpm audacity.xpm
+}
diff --git a/media-sound/audacity/files/audacity-1.3.2-disable-optimization.patch b/media-sound/audacity/files/audacity-1.3.2-disable-optimization.patch
new file mode 100644
index 000000000000..98583ce74db0
--- /dev/null
+++ b/media-sound/audacity/files/audacity-1.3.2-disable-optimization.patch
@@ -0,0 +1,11 @@
+diff -Naur audacity-src-1.3.2-beta.orig/lib-src/soundtouch/include/STTypes.h audacity-src-1.3.2-beta/lib-src/soundtouch/include/STTypes.h
+--- audacity-src-1.3.2-beta.orig/lib-src/soundtouch/include/STTypes.h	2006-10-29 08:06:01.000000000 +0900
++++ audacity-src-1.3.2-beta/lib-src/soundtouch/include/STTypes.h	2006-11-17 01:27:15.000000000 +0900
+@@ -92,7 +92,6 @@
+     /// However, if you're having difficulties getting the optimized routines
+     /// compiled with your compler (e.g. some gcc compiler versions may be picky),
+     /// you may wish to disable the optimizations to make the library compile.
+-    #define ALLOW_OPTIMIZATIONS     1
+ 
+ 
+     // If defined, allows the SIMD-optimized routines to take minor shortcuts
diff --git a/media-sound/audacity/files/digest-audacity-1.3.2-r1 b/media-sound/audacity/files/digest-audacity-1.3.2-r1
new file mode 100644
index 000000000000..760a330b81a9
--- /dev/null
+++ b/media-sound/audacity/files/digest-audacity-1.3.2-r1
@@ -0,0 +1,3 @@
+MD5 bf63673140254f1283dfd55b61ff2422 audacity-src-1.3.2.tar.gz 6683449
+RMD160 b61747103675881bdf32762deea7635a2827b0de audacity-src-1.3.2.tar.gz 6683449
+SHA256 aa37c00014ee79516fb5dce4c56e1038a7eaf5ad22a10743f0609ed186baf621 audacity-src-1.3.2.tar.gz 6683449