Version bump.

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 9433907D693FB5B8!)

1 files changed, 61 insertions, 0 deletions

diff --git a/app-admin/eselect/eselect-1.4.ebuild b/app-admin/eselect/eselect-1.4.ebuild
new file mode 100644
index 000000000000..bd2b4ab34cb1
--- /dev/null
+++ b/app-admin/eselect/eselect-1.4.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/eselect/eselect-1.4.ebuild,v 1.1 2013/12/07 13:23:29 ulm Exp $
+
+EAPI=4
+
+inherit eutils bash-completion-r1
+
+DESCRIPTION="Gentoo's multi-purpose configuration and management tool"
+HOMEPAGE="http://wiki.gentoo.org/wiki/Project:Eselect"
+SRC_URI="http://dev.gentoo.org/~ulm/eselect/${P}.tar.xz"
+
+LICENSE="GPL-2+ || ( GPL-2+ CC-BY-SA-2.5 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc emacs vim-syntax"
+
+RDEPEND="sys-apps/sed
+	|| (
+		sys-apps/coreutils
+		sys-freebsd/freebsd-bin
+		app-misc/realpath
+	)"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	doc? ( dev-python/docutils )"
+RDEPEND="!app-admin/eselect-news
+	${RDEPEND}
+	sys-apps/file
+	sys-libs/ncurses"
+
+PDEPEND="emacs? ( app-emacs/eselect-mode )
+	vim-syntax? ( app-vim/eselect-syntax )"
+
+src_compile() {
+	emake
+	use doc && emake html
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	newbashcomp misc/${PN}.bashcomp ${PN}
+	dodoc AUTHORS ChangeLog NEWS README TODO doc/*.txt
+	use doc && dohtml *.html doc/*
+
+	# needed by news module
+	keepdir /var/lib/gentoo/news
+	if ! use prefix; then
+		fowners root:portage /var/lib/gentoo/news
+		fperms g+w /var/lib/gentoo/news
+	fi
+}
+
+pkg_postinst() {
+	# fowners in src_install doesn't work for the portage group:
+	# merging changes the group back to root
+	if ! use prefix; then
+		chgrp portage "${EROOT}/var/lib/gentoo/news" \
+			&& chmod g+w "${EROOT}/var/lib/gentoo/news"
+	fi
+}