Version bump, remove old

(Portage version: 2.1.8.3/cvs/Linux x86_64)

1 files changed, 48 insertions, 0 deletions

diff --git a/app-admin/pessulus/pessulus-2.30.2.ebuild b/app-admin/pessulus/pessulus-2.30.2.ebuild
new file mode 100644
index 000000000000..fb6d55df2275
--- /dev/null
+++ b/app-admin/pessulus/pessulus-2.30.2.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/pessulus/pessulus-2.30.2.ebuild,v 1.1 2010/06/22 12:55:27 pacho Exp $
+
+EAPI="2"
+GCONF_DEBUG="no"
+
+inherit gnome2 python
+
+DESCRIPTION="Lockdown editor for GNOME"
+HOMEPAGE="http://live.gnome.org/Pessulus"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE=""
+
+RDEPEND=">=dev-python/pygtk-2.13.0
+	dev-python/pygobject
+	>=gnome-base/gconf-2"
+DEPEND="${RDEPEND}
+	>=dev-util/pkgconfig-0.9
+	sys-devel/gettext
+	>=dev-util/intltool-0.35"
+
+DOCS="AUTHORS ChangeLog HACKING MAINTAINERS NEWS README TODO"
+
+src_prepare() {
+	gnome2_src_prepare
+	# disable pyc compiling
+	mv "${S}"/py-compile "${S}"/py-compile.orig
+	ln -s $(type -P true) "${S}"/py-compile
+
+	# Fix intltoolize broken file, see upstream #577133
+	sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in \
+		|| die "sed failed"
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	python_need_rebuild
+	python_mod_optimize $(python_get_sitedir)/Pessulus
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+	python_mod_cleanup /usr/$(get_libdir)/python*/site-packages/Pessulus
+}