Revision bump, add "api" USE flag for salt-api, this will install an init script and replaces the cherrypy USE flag. Remove patches from 9999 ebuild (bug #529272).

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0xE3F69979BB4B8928DA78E3D17CBF44EF)

7 files changed, 147 insertions, 6 deletions

diff --git a/app-admin/salt/ChangeLog b/app-admin/salt/ChangeLog
index ea5d0e6a1b2b..6e5646e807be 100644
--- a/app-admin/salt/ChangeLog
+++ b/app-admin/salt/ChangeLog
@@ -1,6 +1,15 @@
 # ChangeLog for app-admin/salt
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/salt/ChangeLog,v 1.51 2014/11/13 03:58:29 chutzpah Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/salt/ChangeLog,v 1.52 2014/12/03 22:10:14 chutzpah Exp $
+
+*salt-2014.7.0-r1 (01 Dec 2014)
+
+  01 Dec 2014; Patrick McLean <chutzpah@gentoo.org> +salt-2014.7.0-r1.ebuild,
+  salt-9999.ebuild, +files/api-confd-1, +files/api-initd-3,
+  +files/salt-api.service, metadata.xml:
+  Revision bump, add "api" USE flag for salt-api, this will install an init
+  script and replaces the cherrypy USE flag. Remove patches from 9999 ebuild
+  (bug #529272).
 
 *salt-2014.7.0 (13 Nov 2014)
 
diff --git a/app-admin/salt/files/api-confd-1 b/app-admin/salt/files/api-confd-1
new file mode 100644
index 000000000000..c70e8e766da0
--- /dev/null
+++ b/app-admin/salt/files/api-confd-1
@@ -0,0 +1,5 @@
+# /etc/conf.d/salt-master: config file for /etc/init.d/salt-master
+
+# see man pages for salt-minion or run `salt-master --help`
+# for valid cmdline options
+SALT_OPTS="--log-level=warning"
diff --git a/app-admin/salt/files/api-initd-3 b/app-admin/salt/files/api-initd-3
new file mode 100644
index 000000000000..ccd5d922efe2
--- /dev/null
+++ b/app-admin/salt/files/api-initd-3
@@ -0,0 +1,14 @@
+#!/sbin/runscript
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/salt/files/api-initd-3,v 1.1 2014/12/03 22:10:14 chutzpah Exp $
+
+command="/usr/bin/salt-api"
+command_args="${SALT_OPTS}"
+command_background="1"
+pidfile="/var/run/salt-api.pid"
+name="SALT API daemon"
+
+depend() {
+	use net logger
+}
diff --git a/app-admin/salt/files/salt-api.service b/app-admin/salt/files/salt-api.service
new file mode 100644
index 000000000000..fd9f665fff09
--- /dev/null
+++ b/app-admin/salt/files/salt-api.service
@@ -0,0 +1,10 @@
+[Unit]
+Description=The Salt Master Server
+After=syslog.target network.target
+
+[Service]
+Type=simple
+ExecStart=/usr/bin/salt-api
+
+[Install]
+WantedBy=multi-user.target
diff --git a/app-admin/salt/metadata.xml b/app-admin/salt/metadata.xml
index 3349a941c5af..04a6efbeb817 100644
--- a/app-admin/salt/metadata.xml
+++ b/app-admin/salt/metadata.xml
@@ -21,6 +21,7 @@ Between the remote execution system, and state management Salt addresses the
 backbone of cloud and data center management.
 </longdescription>
 	<use>
+		<flag name="api">Enable support for salt-api.</flag>
 		<flag name="cherrypy">Enable support for cherrypy.</flag>
 		<flag name="libcloud">Enable salt-cloud support via libcloud.</flag>
 		<flag name="libvirt">Support managing virtual machines with app-emulation/libvirt.</flag>
diff --git a/app-admin/salt/salt-2014.7.0-r1.ebuild b/app-admin/salt/salt-2014.7.0-r1.ebuild
new file mode 100644
index 000000000000..53faa1e6198a
--- /dev/null
+++ b/app-admin/salt/salt-2014.7.0-r1.ebuild
@@ -0,0 +1,106 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/salt/salt-2014.7.0-r1.ebuild,v 1.1 2014/12/03 22:10:14 chutzpah Exp $
+
+EAPI=5
+PYTHON_COMPAT=(python2_7)
+
+inherit eutils distutils-r1 systemd
+
+DESCRIPTION="Salt is a remote execution and configuration manager"
+HOMEPAGE="http://saltstack.org/"
+
+if [[ ${PV} == 9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="git://github.com/${PN}stack/${PN}.git"
+	EGIT_BRANCH="develop"
+	SRC_URI=""
+	KEYWORDS=""
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~x86 ~amd64"
+fi
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="api ldap libcloud libvirt gnupg keyring mako mongodb mysql nova"
+IUSE+=" openssl redis timelib raet +zeromq test"
+
+RDEPEND="sys-apps/pciutils
+	dev-python/jinja[${PYTHON_USEDEP}]
+	>=dev-python/msgpack-0.3[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/markupsafe[${PYTHON_USEDEP}]
+	>=dev-python/requests-1.0.0[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	libcloud? ( >=dev-python/libcloud-0.14.0[${PYTHON_USEDEP}] )
+	mako? ( dev-python/mako[${PYTHON_USEDEP}] )
+	ldap? ( dev-python/python-ldap[${PYTHON_USEDEP}] )
+	openssl? ( dev-python/pyopenssl[${PYTHON_USEDEP}] )
+	libvirt? ( dev-python/libvirt-python[${PYTHON_USEDEP}] )
+	raet? (
+		dev-python/libnacl[${PYTHON_USEDEP}]
+		dev-python/ioflo[${PYTHON_USEDEP}]
+		dev-python/raet[${PYTHON_USEDEP}]
+	)
+	zeromq? (
+		>=dev-python/pyzmq-2.2.0[${PYTHON_USEDEP}]
+		dev-python/m2crypto[${PYTHON_USEDEP}]
+		dev-python/pycrypto[${PYTHON_USEDEP}]
+	)
+	api? (
+		|| (
+			dev-python/cherrypy[${PYTHON_USEDEP}]
+			www-servers/tornado[${PYTHON_USEDEP}]
+		)
+	)
+	mongodb? ( dev-python/pymongo[${PYTHON_USEDEP}] )
+	keyring? ( dev-python/keyring[${PYTHON_USEDEP}] )
+	mysql? ( dev-python/mysql-python[${PYTHON_USEDEP}] )
+	redis? ( dev-python/redis-py[${PYTHON_USEDEP}] )
+	timelib? ( dev-python/timelib[${PYTHON_USEDEP}] )
+	nova? ( >=dev-python/python-novaclient-2.17.0[${PYTHON_USEDEP}] )
+	gnupg? ( dev-python/python-gnupg[${PYTHON_USEDEP}] )"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pip[${PYTHON_USEDEP}]
+		dev-python/virtualenv[${PYTHON_USEDEP}]
+		dev-python/timelib[${PYTHON_USEDEP}]
+		>=dev-python/SaltTesting-2014.4.24[${PYTHON_USEDEP}]
+		${RDEPEND}
+	)"
+
+DOCS=(README.rst AUTHORS)
+
+REQUIRED_USE="|| ( raet zeromq )"
+
+PATCHES=(
+	"${FILESDIR}/${P}-remove-pydsl-includes-test.patch"
+)
+
+python_prepare() {
+	# this test fails because it trys to "pip install distribute"
+	rm tests/unit/{modules,states}/zcbuildout_test.py
+}
+
+python_install_all() {
+	USE_SETUPTOOLS=1 distutils-r1_python_install_all
+
+	for s in minion master syndic $(use api && echo api); do
+		newinitd "${FILESDIR}"/${s}-initd-3 salt-${s}
+		newconfd "${FILESDIR}"/${s}-confd-1 salt-${s}
+		systemd_dounit "${FILESDIR}"/salt-${s}.service
+	done
+
+	insinto /etc/${PN}
+	doins -r conf/*
+}
+
+python_test() {
+	# testsuite likes lots of files
+	ulimit -n 3072
+
+	# using ${T} for the TMPDIR makes some tests needs paths that exceed PATH_MAX
+	USE_SETUPTOOLS=1 SHELL="/bin/bash" TMPDIR="/tmp" \
+		./tests/runtests.py --unit-tests --no-report --verbose || die "testing failed"
+}
diff --git a/app-admin/salt/salt-9999.ebuild b/app-admin/salt/salt-9999.ebuild
index a55c21fc09af..df258e7a77ee 100644
--- a/app-admin/salt/salt-9999.ebuild
+++ b/app-admin/salt/salt-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/salt/salt-9999.ebuild,v 1.13 2014/11/13 03:58:29 chutzpah Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/salt/salt-9999.ebuild,v 1.14 2014/12/03 22:10:14 chutzpah Exp $
 
 EAPI=5
 PYTHON_COMPAT=(python2_7)
@@ -69,10 +69,6 @@ DOCS=(README.rst AUTHORS)
 
 REQUIRED_USE="|| ( raet zeromq )"
 
-PATCHES=(
-	"${FILESDIR}/${P}-remove-pydsl-includes-test.patch"
-)
-
 python_prepare() {
 	# this test fails because it trys to "pip install distribute"
 	rm tests/unit/{modules,states}/zcbuildout_test.py