Version bumped. Fixed static-libs handling. Added lzo and gcrypt USE flags.

(Portage version: 2.1.9.50/cvs/Linux x86_64)

5 files changed, 101 insertions, 3 deletions

diff --git a/app-backup/dar/ChangeLog b/app-backup/dar/ChangeLog
index 128409f6f41d..2c4851e1827a 100644
--- a/app-backup/dar/ChangeLog
+++ b/app-backup/dar/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-backup/dar
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-backup/dar/ChangeLog,v 1.41 2011/05/11 16:26:43 matsuu Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-backup/dar/ChangeLog,v 1.42 2011/06/07 23:34:19 matsuu Exp $
+
+*dar-2.4.0 (07 Jun 2011)
+
+  07 Jun 2011; MATSUU Takuto <matsuu@gentoo.org> dar-2.3.11.ebuild,
+  +dar-2.4.0.ebuild, +files/dar-2.4.0-gcc.patch, metadata.xml:
+  Version bumped. Fixed static-libs handling. Added lzo and gcrypt USE flags.
 
 *dar-2.3.11 (11 May 2011)
 
diff --git a/app-backup/dar/dar-2.3.11.ebuild b/app-backup/dar/dar-2.3.11.ebuild
index 8a339d7184b5..aab8ce30b1f7 100644
--- a/app-backup/dar/dar-2.3.11.ebuild
+++ b/app-backup/dar/dar-2.3.11.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-backup/dar/dar-2.3.11.ebuild,v 1.1 2011/05/11 16:26:43 matsuu Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-backup/dar/dar-2.3.11.ebuild,v 1.2 2011/06/07 23:34:19 matsuu Exp $
 
 EAPI="3"
 inherit confutils flag-o-matic
@@ -56,7 +56,9 @@ src_configure() {
 src_install() {
 	emake DESTDIR="${D}" pkgdatadir=/usr/share/doc/${PF}/html install || die
 
-	use static-libs || find "${ED}" -name '*.la' -o -name '*.a' -exec rm {} +
+	if ! use static-libs ; then
+		find "${ED}" "(" -name '*.la' -o -name '*.a' ")" -delete || die
+	fi
 
 	dodoc AUTHORS ChangeLog NEWS README THANKS TODO || die
 }
diff --git a/app-backup/dar/dar-2.4.0.ebuild b/app-backup/dar/dar-2.4.0.ebuild
new file mode 100644
index 000000000000..8bee4d03f88f
--- /dev/null
+++ b/app-backup/dar/dar-2.4.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-backup/dar/dar-2.4.0.ebuild,v 1.1 2011/06/07 23:34:19 matsuu Exp $
+
+EAPI="3"
+inherit confutils eutils flag-o-matic
+
+DESCRIPTION="A full featured backup tool, aimed for disks (floppy,CDR(W),DVDR(W),zip,jazz etc.)"
+HOMEPAGE="http://dar.linux.free.fr/"
+SRC_URI="mirror://sourceforge/dar/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="acl dar32 dar64 doc gcrypt lzo nls static static-libs"
+
+RESTRICT="test" # need to be run as root
+
+RDEPEND=">=sys-libs/zlib-1.2.3
+	>=app-arch/bzip2-1.0.2
+	acl? (
+		static? ( sys-apps/attr[static-libs] )
+		!static? ( sys-apps/attr )
+	)
+	gcrypt? ( dev-libs/libgcrypt )
+	lzo? ( dev-libs/lzo )
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )
+	doc? ( app-doc/doxygen )"
+
+pkg_setup() {
+	confutils_use_conflict dar32 dar64
+}
+
+src_prepare() {
+	epatch "${FILESDIR}/${P}-gcc.patch"
+}
+
+src_configure() {
+	local myconf="--disable-upx"
+
+	# Bug 103741
+	filter-flags -fomit-frame-pointer
+
+	use acl || myconf="${myconf} --disable-ea-support"
+	use dar32 && myconf="${myconf} --enable-mode=32"
+	use dar64 && myconf="${myconf} --enable-mode=64"
+	use doc || myconf="${myconf} --disable-build-html"
+	# use examples && myconf="${myconf} --enable-examples"
+	use gcrypt || myconf="${myconf} --disable-libgcrypt-linking"
+	use lzo || myconf="${myconf} --disable-liblzo2-linking"
+	use nls || myconf="${myconf} --disable-nls"
+	if ! use static ; then
+		myconf="${myconf} --disable-dar-static"
+		if ! use static-libs ; then
+			myconf="${myconf} --disable-static"
+		fi
+	fi
+
+	econf ${myconf} || die
+}
+
+src_install() {
+	emake DESTDIR="${D}" pkgdatadir=/usr/share/doc/${PF}/html install || die
+
+	if ! use static-libs ; then
+		find "${ED}" "(" -name '*.la' -o -name '*.a' ")" -delete || die
+	fi
+
+	dodoc AUTHORS ChangeLog NEWS README THANKS TODO || die
+}
diff --git a/app-backup/dar/files/dar-2.4.0-gcc.patch b/app-backup/dar/files/dar-2.4.0-gcc.patch
new file mode 100644
index 000000000000..cb251174d541
--- /dev/null
+++ b/app-backup/dar/files/dar-2.4.0-gcc.patch
@@ -0,0 +1,17 @@
+diff -Naur dar-2.4.0.orig/src/check/all_features.cpp dar-2.4.0/src/check/all_features.cpp
+--- dar-2.4.0.orig/src/check/all_features.cpp	2011-04-01 04:21:02.000000000 +0900
++++ dar-2.4.0/src/check/all_features.cpp	2011-06-07 09:03:47.772855768 +0900
+@@ -25,6 +25,13 @@
+ 
+ #include "../my_config.h"
+ 
++extern "C"
++{
++#if HAVE_STDLIB_H
++#include <stdlib.h>
++#endif
++}
++
+ #include "libdar.hpp"
+ 
+ using namespace libdar;
diff --git a/app-backup/dar/metadata.xml b/app-backup/dar/metadata.xml
index 37612aa339e8..1adb16fa75e2 100644
--- a/app-backup/dar/metadata.xml
+++ b/app-backup/dar/metadata.xml
@@ -17,5 +17,6 @@ operations, including with ssh.
 		by 32 bit integers</flag>
 	<flag name='dar64'>Enables --enable-mode=64 option, which replace infinite
 		by 64 bit integers</flag>
+	<flag name='gcrypt'>Enables strong encryption support</flag>
 </use>
 </pkgmetadata>