Revision bump with no changes so all users get eautoreconfed version.

(Portage version: 2.1.5.4)

1 files changed, 61 insertions, 0 deletions

diff --git a/app-cdr/serpentine/serpentine-0.9-r2.ebuild b/app-cdr/serpentine/serpentine-0.9-r2.ebuild
new file mode 100644
index 000000000000..55dd9d081d89
--- /dev/null
+++ b/app-cdr/serpentine/serpentine-0.9-r2.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-cdr/serpentine/serpentine-0.9-r2.ebuild,v 1.1 2008/06/08 17:44:20 drac Exp $
+
+GCONF_DEBUG=no
+
+inherit autotools eutils gnome2 mono multilib python
+
+DESCRIPTION="An application for writing CD-Audio discs. It aims for simplicity, usability and compability."
+HOMEPAGE="http://irrepupavel.com/projects/serpentine/"
+SRC_URI="mirror://berlios/serpentine/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="muine"
+
+RDEPEND=">=dev-lang/python-2.4
+	>=dev-python/pygtk-2.6
+	>=dev-python/gnome-python-desktop-2.14.0
+	>=dev-python/gst-python-0.10
+	gnome-base/gconf
+	>=media-plugins/gst-plugins-gnomevfs-0.10
+	muine? ( media-sound/muine )"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	dev-util/intltool
+	dev-util/pkgconfig"
+
+pkg_setup() {
+	G2CONF="${G2CONF} $(use_enable muine)"
+	DOCS="AUTHORS ChangeLog NEWS README TODO"
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	echo serpentine/gtkutil.py >> po/POTFILES.skip
+	echo serpentine/plugins/plugsuspend.py >> po/POTFILES.skip
+
+	epatch "${FILESDIR}"/${P}-drop_pyxml.patch \
+		"${FILESDIR}"/${P}-python24_compat.patch
+
+	rm -f py-compile || die "rm failed."
+	ln -s $(type -P true) py-compile || die "ln failed."
+
+	intltoolize --force --copy --automake || die "intltoolize failed."
+	eautoreconf
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	python_version
+	python_mod_optimize /usr/$(get_libdir)/python${PYVER}/site-packages/${PN}
+}
+
+pkg_postrm() {
+	gnome2_pkg_postrm
+	python_mod_cleanup
+}