Add USE flags for plugins that were integrated in the newer qca version. The USE flags pull the plugins implicitly making it easier to create useful deps on qca with plugins. Patch prepared by Roman Kuzmitsky (damex).

(Portage version: 2.2.17/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

2 files changed, 88 insertions, 1 deletions

diff --git a/app-crypt/qca/ChangeLog b/app-crypt/qca/ChangeLog
index c1845a9acd84..0e1db9932a68 100644
--- a/app-crypt/qca/ChangeLog
+++ b/app-crypt/qca/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for app-crypt/qca
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-crypt/qca/ChangeLog,v 1.101 2015/02/02 16:39:28 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/qca/ChangeLog,v 1.102 2015/02/21 11:37:31 mgorny Exp $
+
+*qca-2.0.3-r1 (21 Feb 2015)
+
+  21 Feb 2015; Michał Górny <mgorny@gentoo.org> +qca-2.0.3-r1.ebuild:
+  Add USE flags for plugins that were integrated in the newer qca version. The
+  USE flags pull the plugins implicitly making it easier to create useful deps
+  on qca with plugins. Patch prepared by Roman Kuzmitsky (damex).
 
   02 Feb 2015; Jeroen Roovers <jer@gentoo.org> qca-2.1.0.3.ebuild:
   Marked ~hppa (bug #538550).
diff --git a/app-crypt/qca/qca-2.0.3-r1.ebuild b/app-crypt/qca/qca-2.0.3-r1.ebuild
new file mode 100644
index 000000000000..4753875eb88a
--- /dev/null
+++ b/app-crypt/qca/qca-2.0.3-r1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/qca/qca-2.0.3-r1.ebuild,v 1.1 2015/02/21 11:37:31 mgorny Exp $
+
+EAPI="3"
+
+inherit eutils multilib qt4-r2
+
+DESCRIPTION="Qt Cryptographic Architecture (QCA)"
+HOMEPAGE="http://delta.affinix.com/qca/"
+SRC_URI="http://delta.affinix.com/download/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~sparc-solaris"
+IUSE="aqua debug doc examples gpg logger openssl pkcs11 sasl"
+RESTRICT="test"
+
+DEPEND="dev-qt/qtcore:4[debug?]"
+RDEPEND="${DEPEND}
+	!<app-crypt/qca-1.0-r3:0"
+
+PDEPEND="gpg? ( app-crypt/qca-gnupg )
+	logger? ( app-crypt/qca-logger )
+	openssl? ( app-crypt/qca-ossl )
+	pkcs11? ( app-crypt/qca-pkcs11 )
+	sasl? ( app-crypt/qca-cyrus-sasl )"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.0.2-pcfilespath.patch \
+		"${FILESDIR}"/${P}+gcc-4.7.patch
+
+	if use aqua; then
+		sed -i -e "s|QMAKE_LFLAGS_SONAME =.*|QMAKE_LFLAGS_SONAME = -Wl,-install_name,|g" \
+			src/src.pro || die
+	fi
+}
+
+src_configure() {
+	# Ensure proper rpath
+	export EXTRA_QMAKE_RPATH="${EPREFIX}/usr/$(get_libdir)/qca2"
+
+	ABI= ./configure \
+		--prefix="${EPREFIX}"/usr \
+		--qtdir="${EPREFIX}"/usr \
+		--includedir="${EPREFIX}"/usr/include/qca2 \
+		--libdir="${EPREFIX}"/usr/$(get_libdir)/qca2 \
+		--certstore-path="${EPREFIX}"/etc/ssl/certs/ca-certificates.crt \
+		--no-separate-debug-info \
+		--disable-tests \
+		--$(use debug && echo debug || echo release) \
+		--no-framework \
+		|| die "configure failed"
+
+	eqmake4
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install || die
+	dodoc README TODO || die
+
+	cat <<-EOF > "${WORKDIR}"/44qca2
+	LDPATH="${EPREFIX}/usr/$(get_libdir)/qca2"
+	EOF
+	doenvd "${WORKDIR}"/44qca2 || die
+
+	if use doc; then
+		dohtml "${S}"/apidocs/html/* || die
+	fi
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/
+		doins -r "${S}"/examples || die
+	fi
+
+	# add the proper rpath for packages that do CONFIG += crypto
+	echo "QMAKE_RPATHDIR += \"${EPREFIX}/usr/$(get_libdir)/qca2\"" >> \
+		"${D%/}${EPREFIX}/usr/share/qt4/mkspecs/features/crypto.prf" \
+		|| die "failed to add rpath to crypto.prf"
+}