Version bump, bug 258028.

(Portage version: 2.2_rc23/cvs/Linux i686)

1 files changed, 48 insertions, 0 deletions

diff --git a/app-emacs/yasnippet/yasnippet-0.5.9.ebuild b/app-emacs/yasnippet/yasnippet-0.5.9.ebuild
new file mode 100644
index 000000000000..036cff45f5bc
--- /dev/null
+++ b/app-emacs/yasnippet/yasnippet-0.5.9.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emacs/yasnippet/yasnippet-0.5.9.ebuild,v 1.1 2009/02/09 13:35:45 ulm Exp $
+
+inherit elisp
+
+DESCRIPTION="Yet another snippet extension for Emacs"
+HOMEPAGE="http://code.google.com/p/yasnippet/"
+SRC_URI="http://yasnippet.googlecode.com/files/${P}.tar.bz2
+	doc? ( http://yasnippet.googlecode.com/files/${PN}-doc-${PV}.tar.bz2 )"
+
+# Homepage says MIT licence, source contains GPL-2 copyright notice
+LICENSE="MIT GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+DEPEND=">=app-emacs/dropdown-list-20080316"
+RDEPEND="${DEPEND}"
+
+SITEFILE="50${PN}-gentoo.el"
+
+src_unpack() {
+	elisp_src_unpack
+
+	cd "${S}"
+	# remove inlined copy of dropdown-list
+	sed -i -e '/^;;/N;/Contents of dropdown-list\.el/,$d' yasnippet.el || die
+}
+
+src_install() {
+	elisp_src_install
+
+	insinto "${SITEETC}/${PN}"
+	doins -r snippets || die "doins failed"
+
+	if use doc; then
+		dohtml -r "${WORKDIR}"/doc/* || die "dohtml failed"
+	fi
+}
+
+pkg_postinst() {
+	elisp-site-regen
+
+	elog "Please add the following code into your .emacs to use yasnippet:"
+	elog "(yas/initialize)"
+	elog "(yas/load-directory \"${SITEETC}/${PN}/snippets\")"
+}