version bump (bug #299870) with additions from groepaz@gmx.net via bug #258674

(Portage version: 2.1.7.17/cvs/Linux i686)

3 files changed, 118 insertions, 1 deletions

diff --git a/app-emulation/vice/ChangeLog b/app-emulation/vice/ChangeLog
index fa787fd1c0e4..94db7e841fa0 100644
--- a/app-emulation/vice/ChangeLog
+++ b/app-emulation/vice/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for app-emulation/vice
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/vice/ChangeLog,v 1.67 2010/03/08 18:52:38 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/vice/ChangeLog,v 1.68 2010/03/23 22:51:06 mr_bones_ Exp $
+
+*vice-2.2 (23 Mar 2010)
+
+  23 Mar 2010; Michael Sterrett <mr_bones_@gentoo.org> +vice-2.2.ebuild,
+  metadata.xml:
+  version bump (bug #299870) with additions from groepaz@gmx.net via bug
+  #258674
 
   08 Mar 2010; Samuli Suominen <ssuominen@gentoo.org> vice-2.1.ebuild:
   Don't check for obsolete png_check_sig function (because vice will
diff --git a/app-emulation/vice/metadata.xml b/app-emulation/vice/metadata.xml
index 3ae153091e68..2f835f0256e0 100644
--- a/app-emulation/vice/metadata.xml
+++ b/app-emulation/vice/metadata.xml
@@ -3,6 +3,8 @@
 <pkgmetadata>
 <herd>games</herd>
 <use>
+	<flag name='ethernet'>Enable ethernet emulation</flag>
+	<flag name='memmap'>Enable extra monitor features</flag>
 	<flag name='resid'>Enable support for ReSID <pkg>media-libs/resid</pkg></flag>
 	<flag name='xrandr'>Enable support for the X xrandr extension</flag>
 </use>
diff --git a/app-emulation/vice/vice-2.2.ebuild b/app-emulation/vice/vice-2.2.ebuild
new file mode 100644
index 000000000000..d1149ba002b5
--- /dev/null
+++ b/app-emulation/vice/vice-2.2.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/vice/vice-2.2.ebuild,v 1.1 2010/03/23 22:51:06 mr_bones_ Exp $
+
+EAPI=2
+inherit autotools eutils games
+
+DESCRIPTION="The Versatile Commodore 8-bit Emulator"
+HOMEPAGE="http://vice-emu.sourceforge.net/"
+SRC_URI="http://www.zimmers.net/anonftp/pub/cbm/crossplatform/emulators/VICE/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="Xaw3d alsa gnome nls png readline sdl ipv6 memmap ethernet oss zlib X gif jpeg xv dga xrandr ffmpeg lame pulseaudio"
+
+RDEPEND="
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXpm
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libXt
+	x11-libs/libXxf86vm
+	x11-apps/xset
+	Xaw3d? ( x11-libs/Xaw3d )
+	!Xaw3d? ( !gnome? ( x11-libs/libXaw ) )
+	alsa? ( media-libs/alsa-lib )
+	gnome? (
+		x11-libs/gtk+:2
+		dev-libs/atk
+		x11-libs/pango
+	)
+	lame? ( media-sound/lame )
+	ffmpeg? ( >=media-video/ffmpeg-0.5_p20373 )
+	ethernet? (
+	    >=net-libs/libpcap-0.9.8
+	    >=net-libs/libnet-1.1.2.1
+	)
+	nls? ( virtual/libintl )
+	png? ( media-libs/libpng )
+	readline? ( sys-libs/readline )
+	sdl? ( media-libs/libsdl )
+	gif? ( media-libs/giflib )
+	jpeg? ( media-libs/jpeg:0 )
+	xv? ( x11-libs/libXv )
+	dga? ( x11-libs/libXxf86dga )
+	xrandr? ( x11-libs/libXrandr )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	x11-apps/bdftopcf
+	x11-apps/mkfontdir
+	x11-proto/xproto
+	x11-proto/xf86vidmodeproto
+	x11-proto/xextproto
+	dga? ( x11-proto/xf86dgaproto )
+	xv? ( x11-proto/videoproto )
+	nls? ( sys-devel/gettext )"
+
+src_prepare() {
+	sed -i \
+		-e "s:/usr/local/lib/VICE:${GAMES_DATADIR}/${PN}:" \
+		man/vice.1 \
+		$(grep -rl /usr/local/lib doc) \
+		|| die "sed failed"
+	sed -i \
+		-e 's:png_check_sig:png_sig_cmp:g' \
+		-e "/VICEDIR=/s:=.*:=\"${GAMES_DATADIR}/${PN}\";:" \
+		configure.in \
+		|| die "sed failed"
+	AT_NO_RECURSIVE=1 eautoreconf
+}
+
+src_configure() {
+	# don't try to actually run fc-cache (bug #280976)
+	FCCACHE=/bin/true \
+	PKG_CONFIG=pkg-config \
+	egamesconf \
+		--disable-dependency-tracking \
+		--enable-fullscreen \
+		--enable-parsid \
+		--with-resid \
+		--without-arts \
+		--without-esd \
+		--without-midas \
+		$(use_enable ffmpeg) \
+		$(use_enable lame) \
+		$(use_enable gnome gnomeui) \
+		$(use_enable nls) \
+		$(use_with Xaw3d xaw3d) \
+		$(use_with alsa) \
+		$(use_with pulseaudio pulse) \
+		$(use_with png) \
+		$(use_with readline) \
+		$(use_with sdl sdlsound) \
+		$(use_enable ipv6) \
+		$(use_enable oss) \
+		$(use_enable memmap) \
+		$(use_enable ethernet) \
+		$(use_with zlib) \
+		$(use_with X x)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc AUTHORS ChangeLog FEEDBACK README
+	prepgamesdirs
+}