Version bumped. Fixed LICENSE. Changed HOMEPAGE.

(Portage version: 2.1.6.7/cvs/Linux x86_64)

1 files changed, 44 insertions, 0 deletions

diff --git a/app-i18n/dbskkd-cdb/dbskkd-cdb-2.00.ebuild b/app-i18n/dbskkd-cdb/dbskkd-cdb-2.00.ebuild
new file mode 100644
index 000000000000..afa37182d3c2
--- /dev/null
+++ b/app-i18n/dbskkd-cdb/dbskkd-cdb-2.00.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/dbskkd-cdb/dbskkd-cdb-2.00.ebuild,v 1.1 2009/02/15 04:27:35 matsuu Exp $
+
+EAPI="2"
+inherit eutils multilib toolchain-funcs
+
+DESCRIPTION="Yet another Dictionary server for the SKK Japanese-input software"
+HOMEPAGE="http://dbskkd-cdb.googlecode.com/"
+SRC_URI="http://dbskkd-cdb.googlecode.com/files/${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86"
+IUSE=""
+
+DEPEND="|| ( dev-db/cdb dev-db/tinycdb )"
+RDEPEND=">=app-i18n/skk-jisyo-200705[cdb]
+	sys-apps/xinetd"
+
+pkg_setup() {
+	enewuser dbskkd -1 -1 -1
+}
+
+src_prepare() {
+	epatch "${FILESDIR}/${P}-gentoo.patch"
+	sed -i -e "/^CDBLIB/s:lib:$(get_libdir):" Makefile || die
+	if has_version dev-db/cdb ; then
+		sed -i -e "/^CDBLIB/s:$: /usr/$(get_libdir)/byte.a /usr/$(get_libdir)/unix.a:" Makefile || die
+	fi
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)" || die
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+
+	insinto /etc/xinetd.d
+	newins "${FILESDIR}/${PN}.xinetd" ${PN} || die
+
+	dodoc CHANGES README* *.txt
+}