Fix plugdev group device node permissions, install devices.md by default, and add missing gtk+ dep (bug #521886).

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

1 files changed, 59 insertions, 0 deletions

diff --git a/app-misc/solaar/solaar-0.9.2-r3.ebuild b/app-misc/solaar/solaar-0.9.2-r3.ebuild
new file mode 100644
index 000000000000..a3bcd85da747
--- /dev/null
+++ b/app-misc/solaar/solaar-0.9.2-r3.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/solaar/solaar-0.9.2-r3.ebuild,v 1.1 2014/11/24 08:02:40 radhermit Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+inherit distutils-r1 udev user linux-info gnome2-utils
+
+DESCRIPTION="A Linux device manager for Logitech's Unifying Receiver peripherals"
+HOMEPAGE="http://pwr.github.com/Solaar/"
+SRC_URI="https://github.com/pwr/Solaar/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="doc"
+
+RDEPEND=">=dev-python/pyudev-0.13[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	x11-libs/gtk+:3[introspection]"
+
+S=${WORKDIR}/Solaar-${PV}
+
+CONFIG_CHECK="~HID_LOGITECH_DJ ~HIDRAW"
+
+python_prepare_all() {
+	# don't autostart (bug #494608)
+	sed -i '/yield autostart_path/d' setup.py || die
+
+	# grant plugdev group rw access
+	sed -i 's/#MODE=/MODE=/' rules.d/42-logitech-unify-permissions.rules || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	udev_dorules rules.d/*.rules
+
+	dodoc docs/devices.md
+	if use doc; then
+		dodoc -r docs/*
+	fi
+}
+
+pkg_postinst() {
+	enewgroup plugdev
+
+	if [[ -z ${REPLACING_VERSIONS} ]] ; then
+		elog "Users must be in the plugdev group to use this application."
+	fi
+
+	gnome2_icon_cache_update
+}
+
+pkg_preinst() { gnome2_icon_savelist; }
+pkg_postrm() { gnome2_icon_cache_update; }