Version bump. Fix qt4 handling, bug #360839.

(Portage version: 2.2.0_alpha29/cvs/Linux x86_64, RepoMan options: --force)

4 files changed, 222 insertions, 8 deletions

diff --git a/app-misc/tracker/ChangeLog b/app-misc/tracker/ChangeLog
index 05b3022f6370..22b880835561 100644
--- a/app-misc/tracker/ChangeLog
+++ b/app-misc/tracker/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-misc/tracker
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/tracker/ChangeLog,v 1.100 2011/03/27 08:11:39 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/tracker/ChangeLog,v 1.101 2011/04/03 21:13:37 eva Exp $
+
+*tracker-0.10.6 (03 Apr 2011)
+
+  03 Apr 2011; Gilles Dartiguelongue <eva@gentoo.org> tracker-0.10.5.ebuild,
+  +tracker-0.10.6.ebuild, tracker-9999.ebuild:
+  Version bump. Fix qt4 handling, bug #360839.
 
   27 Mar 2011; Samuli Suominen <ssuominen@gentoo.org> tracker-0.8.17.ebuild,
   tracker-0.10.5.ebuild, tracker-9999.ebuild:
diff --git a/app-misc/tracker/tracker-0.10.5.ebuild b/app-misc/tracker/tracker-0.10.5.ebuild
index 701cc63bd89f..49c78f1004c0 100644
--- a/app-misc/tracker/tracker-0.10.5.ebuild
+++ b/app-misc/tracker/tracker-0.10.5.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/tracker/tracker-0.10.5.ebuild,v 1.2 2011/03/27 08:11:39 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/tracker/tracker-0.10.5.ebuild,v 1.3 2011/04/03 21:13:37 eva Exp $
 
 EAPI="3"
 GCONF_DEBUG="no"
@@ -138,8 +138,8 @@ pkg_setup() {
 		G2CONF="${G2CONF} VALAC=$(type -P valac-0.12)"
 	fi
 
-	if use mp3; then
-		G2CONF="${G2CONF} $(use_enable gtk gdkpixbuf) $(use_enable qt4 qt)"
+	if use mp3 && (use gtk || use qt4); then
+		G2CONF="${G2CONF} $(use_enable !qt4 gdkpixbuf) $(use_enable qt4 qt)"
 	fi
 
 	# unicode-support: libunistring, libicu or glib ?
diff --git a/app-misc/tracker/tracker-0.10.6.ebuild b/app-misc/tracker/tracker-0.10.6.ebuild
new file mode 100644
index 000000000000..9d0c01b65dae
--- /dev/null
+++ b/app-misc/tracker/tracker-0.10.6.ebuild
@@ -0,0 +1,208 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/tracker/tracker-0.10.6.ebuild,v 1.1 2011/04/03 21:13:37 eva Exp $
+
+EAPI="3"
+GCONF_DEBUG="no"
+PYTHON_DEPEND="2:2.6"
+
+inherit eutils gnome2 linux-info python virtualx
+
+DESCRIPTION="A tagging metadata database, search tool and indexer"
+HOMEPAGE="http://www.tracker-project.org/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+# USE="doc" is managed by eclass.
+IUSE="applet doc eds exif flac gif gnome-keyring gsf gstreamer gtk iptc +jpeg laptop mp3 nautilus networkmanager pdf playlist qt4 rss strigi test +tiff upnp +vorbis xine +xml xmp"
+
+# Test suite highly disfunctional, loops forever
+# putting aside for now
+RESTRICT="test"
+
+# TODO: rest -> flickr
+# vala is built with debug by default (see VALAFLAGS)
+RDEPEND="
+	>=app-i18n/enca-1.9
+	>=dev-db/sqlite-3.7[threadsafe]
+	>=dev-libs/glib-2.26:2
+	>=dev-libs/icu-4
+	|| (
+		>=media-gfx/imagemagick-5.2.1[png,jpeg=]
+		media-gfx/graphicsmagick[imagemagick,png,jpeg=] )
+	>=media-libs/libpng-1.2
+	>=x11-libs/pango-1
+	sys-apps/util-linux
+
+	applet? (
+		>=gnome-base/gnome-panel-2.91
+		>=x11-libs/gtk+-3:3 )
+	eds? (
+		>=mail-client/evolution-2.32
+		>=gnome-extra/evolution-data-server-2.32 )
+	exif? ( >=media-libs/libexif-0.6 )
+	flac? ( >=media-libs/flac-1.2.1 )
+	gif? ( media-libs/giflib )
+	gnome-keyring? ( >=gnome-base/gnome-keyring-2.26 )
+	gsf? (
+		app-text/odt2txt
+		>=gnome-extra/libgsf-1.13 )
+	upnp? ( >=media-libs/gupnp-dlna-0.5 )
+	!upnp? (
+		gstreamer? ( >=media-libs/gstreamer-0.10.31:0.10 )
+		!gstreamer? ( !xine? ( || ( media-video/totem media-video/mplayer ) ) )
+	)
+	gtk? (
+		>=dev-libs/libgee-0.3
+		>=x11-libs/gtk+-2.18:2 )
+	iptc? ( media-libs/libiptcdata )
+	jpeg? ( virtual/jpeg:0 )
+	laptop? ( >=sys-power/upower-0.9 )
+	mp3? (
+		>=media-libs/taglib-1.6
+		gtk? ( x11-libs/gdk-pixbuf:2 )
+		qt4? ( >=x11-libs/qt-gui-4.7.1:4 ) )
+	nautilus? (
+		gnome-base/nautilus
+		>=x11-libs/gtk+-2.18:2 )
+	networkmanager? ( >=net-misc/networkmanager-0.8 )
+	pdf? (
+		>=x11-libs/cairo-1
+		>=app-text/poppler-0.16[cairo,utils]
+		>=x11-libs/gtk+-2.12:2 )
+	playlist? ( dev-libs/totem-pl-parser )
+	rss? ( net-libs/libgrss )
+	strigi? ( >=app-misc/strigi-0.7 )
+	tiff? ( media-libs/tiff )
+	vorbis? ( >=media-libs/libvorbis-0.22 )
+	xine? ( >=media-libs/xine-lib-1 )
+	xml? ( >=dev-libs/libxml2-2.6 )
+	xmp? ( >=media-libs/exempi-2.1 )"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.40
+	>=sys-devel/gettext-0.17
+	>=dev-util/pkgconfig-0.20
+	applet? ( >=dev-lang/vala-0.11.4:0.12 )
+	gtk? (
+		app-office/dia
+		>=dev-lang/vala-0.11.4:0.12
+		>=dev-libs/libgee-0.3 )
+	doc? (
+		>=dev-util/gtk-doc-1.8
+		media-gfx/graphviz )
+	test? (
+		>=dev-libs/dbus-glib-0.82-r1
+		>=sys-apps/dbus-1.3.1[X] )
+"
+
+function inotify_enabled() {
+	if linux_config_exists; then
+		if ! linux_chkconfig_present INOTIFY_USER; then
+			ewarn "You should enable the INOTIFY support in your kernel."
+			ewarn "Check the 'Inotify support for userland' under the 'File systems'"
+			ewarn "option. It is marked as CONFIG_INOTIFY_USER in the config"
+			die 'missing CONFIG_INOTIFY'
+		fi
+	else
+		einfo "Could not check for INOTIFY support in your kernel."
+	fi
+}
+
+pkg_setup() {
+	linux-info_pkg_setup
+
+	inotify_enabled
+
+	if use upnp ; then
+		G2CONF="${G2CONF} --enable-video-extractor=gupnp-dlna"
+	elif use gstreamer ; then
+		G2CONF="${G2CONF}
+			--enable-video-extractor=gstreamer
+			--enable-gstreamer-tagreadbin"
+		# --enable-gstreamer-helix (real media)
+	elif use xine ; then
+		G2CONF="${G2CONF} --enable-video-extractor=xine"
+	else
+		G2CONF="${G2CONF} --enable-video-extractor=external"
+	fi
+
+	# upower is used for AC power detection
+	if use laptop; then
+		G2CONF="${G2CONF} --disable-hal --enable-upower"
+	else
+		G2CONF="${G2CONF} --disable-hal --disable-upower"
+	fi
+
+	if use applet || use gtk; then
+		G2CONF="${G2CONF} VALAC=$(type -P valac-0.12)"
+	fi
+
+	if use mp3 && (use gtk || use qt4); then
+		G2CONF="${G2CONF} $(use_enable !qt4 gdkpixbuf) $(use_enable qt4 qt)"
+	fi
+
+	# unicode-support: libunistring, libicu or glib ?
+	G2CONF="${G2CONF}
+		--enable-tracker-fts
+		--with-enca
+		--with-unicode-support=libicu
+		--enable-guarantee-metadata
+		$(use_enable applet tracker-search-bar)
+		$(use_enable eds miner-evolution)
+		$(use_enable exif libexif)
+		$(use_enable flac libflac)
+		$(use_enable gnome-keyring)
+		$(use_enable gsf libgsf)
+		$(use_enable gtk tracker-explorer)
+		$(use_enable gtk tracker-preferences)
+		$(use_enable gtk tracker-needle)
+		$(use_enable iptc libiptcdata)
+		$(use_enable jpeg libjpeg)
+		$(use_enable mp3 taglib)
+		$(use_enable nautilus nautilus-extension)
+		$(use_enable networkmanager network-manager)
+		$(use_enable pdf poppler)
+		$(use_enable playlist)
+		$(use_enable rss miner-rss)
+		$(use_enable strigi libstreamanalyzer)
+		$(use_enable test functional-tests)
+		$(use_enable test unit-tests)
+		$(use_enable tiff libtiff)
+		$(use_enable vorbis libvorbis)
+		$(use_enable xml libxml2)
+		$(use_enable xmp exempi)"
+
+	DOCS="AUTHORS ChangeLog NEWS README"
+
+	python_set_active_version 2
+}
+
+src_prepare() {
+	# Fix build failures with USE=strigi
+	epatch "${FILESDIR}/${PN}-0.8.0-strigi.patch"
+
+	# Fix functional tests scripts
+	find "${S}" -name "*.pyc" -delete
+	python_convert_shebangs 2 "${S}"/tests/tracker-writeback/*.py
+	python_convert_shebangs 2 "${S}"/tests/functional-tests/*.py
+	python_convert_shebangs 2 "${S}"/utils/data-generators/cc/{*.py,generate}
+	python_convert_shebangs 2 "${S}"/utils/gtk-sparql/*.py
+	python_convert_shebangs 2 "${S}"/examples/rss-reader/*.py
+
+	# FIXME: report broken tests
+	sed -e '/\/libtracker-miner\/tracker-password-provider\/setting/,+1 s:^\(.*\)$:/*\1*/:' \
+		-e '/\/libtracker-miner\/tracker-password-provider\/getting/,+1 s:^\(.*\)$:/*\1*/:' \
+		-i tests/libtracker-miner/tracker-password-provider-test.c || die
+}
+
+src_test() {
+	unset DBUS_SESSION_BUS_ADDRESS
+	Xemake check XDG_DATA_HOME="${T}" XDG_CONFIG_HOME="${T}" || die "tests failed"
+}
+
+src_install() {
+	gnome2_src_install
+	# Tracker and none of the plugins it provides needs la files
+	find "${ED}" -name "*.la" -delete || die
+}
diff --git a/app-misc/tracker/tracker-9999.ebuild b/app-misc/tracker/tracker-9999.ebuild
index 40a2e9c733d4..24da886a7e62 100644
--- a/app-misc/tracker/tracker-9999.ebuild
+++ b/app-misc/tracker/tracker-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/tracker/tracker-9999.ebuild,v 1.38 2011/03/27 08:11:39 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/tracker/tracker-9999.ebuild,v 1.39 2011/04/03 21:13:37 eva Exp $
 
 EAPI="3"
 GCONF_DEBUG="no"
@@ -48,7 +48,7 @@ RDEPEND="
 		>=gnome-extra/libgsf-1.13 )
 	upnp? ( >=media-libs/gupnp-dlna-0.5 )
 	!upnp? (
-		gstreamer? ( >=media-libs/gstreamer-0.10.12 )
+		gstreamer? ( >=media-libs/gstreamer-0.10.31:0.10 )
 		!gstreamer? ( !xine? ( || ( media-video/totem media-video/mplayer ) ) )
 	)
 	gtk? (
@@ -137,8 +137,8 @@ pkg_setup() {
 		G2CONF="${G2CONF} VALAC=$(type -P valac-0.12)"
 	fi
 
-	if use mp3; then
-		G2CONF="${G2CONF} $(use_enable gtk gdkpixbuf) $(use_enable qt4 qt)"
+	if use mp3 && (use gtk || use qt4); then
+		G2CONF="${G2CONF} $(use_enable !qt4 gdkpixbuf) $(use_enable qt4 qt)"
 	fi
 
 	# unicode-support: libunistring, libicu or glib ?