Version bump to latest.

(Portage version: 2.2.0_alpha174/cvs/Linux x86_64, signed Manifest commit with key 8EEE3BE8)

1 files changed, 54 insertions, 0 deletions

diff --git a/app-text/libmspub/libmspub-0.0.6.ebuild b/app-text/libmspub/libmspub-0.0.6.ebuild
new file mode 100644
index 000000000000..5e0f6ddfa71c
--- /dev/null
+++ b/app-text/libmspub/libmspub-0.0.6.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/libmspub/libmspub-0.0.6.ebuild,v 1.1 2013/05/14 09:05:37 scarabeus Exp $
+
+EAPI=5
+
+EGIT_REPO_URI="git://anongit.freedesktop.org/git/libreoffice/${PN}/"
+[[ ${PV} == 9999 ]] && inherit autotools git-2
+inherit base eutils
+
+DESCRIPTION="Library parsing the Microsoft Publisher documents"
+HOMEPAGE="http://www.freedesktop.org/wiki/Software/libmspub"
+[[ ${PV} == 9999 ]] || SRC_URI="http://dev-www.libreoffice.org/src/${P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+
+# Don't move KEYWORDS on the previous line or ekeyword won't work # 399061
+[[ ${PV} == 9999 ]] || \
+KEYWORDS="~amd64 ~arm ~ppc ~x86"
+
+IUSE="doc static-libs"
+
+RDEPEND="
+	app-text/libwpd:0.9
+	app-text/libwpg:0.2
+	dev-libs/icu:=
+	sys-libs/zlib
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	dev-libs/boost
+	sys-devel/libtool
+	doc? ( app-doc/doxygen )
+"
+
+src_prepare() {
+	base_src_prepare
+	[[ -d m4 ]] || mkdir "m4"
+	[[ ${PV} == 9999 ]] && eautoreconf
+}
+
+src_configure() {
+	econf \
+		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
+		$(use_enable static-libs static) \
+		--disable-werror \
+		$(use_with doc docs)
+}
+
+src_install() {
+	default
+	prune_libtool_files --all
+}