version bump

(Portage version: 2.1.1-r2)

3 files changed, 90 insertions, 2 deletions

diff --git a/dev-games/cegui/ChangeLog b/dev-games/cegui/ChangeLog
index ebc0f36e0d5a..2640c63483b6 100644
--- a/dev-games/cegui/ChangeLog
+++ b/dev-games/cegui/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-games/cegui
-# Copyright 1999-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-games/cegui/ChangeLog,v 1.9 2006/11/20 15:51:59 nyhm Exp $
+# Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-games/cegui/ChangeLog,v 1.10 2007/02/07 17:09:49 mr_bones_ Exp $
+
+*cegui-0.5.0b (07 Feb 2007)
+
+  07 Feb 2007; Michael Sterrett <mr_bones_@gentoo.org> +cegui-0.5.0b.ebuild:
+  version bump
 
 *cegui-0.5.0 (20 Nov 2006)
 
diff --git a/dev-games/cegui/cegui-0.5.0b.ebuild b/dev-games/cegui/cegui-0.5.0b.ebuild
new file mode 100644
index 000000000000..c8c04da86339
--- /dev/null
+++ b/dev-games/cegui/cegui-0.5.0b.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-games/cegui/cegui-0.5.0b.ebuild,v 1.1 2007/02/07 17:09:49 mr_bones_ Exp $
+
+inherit eutils
+
+MY_P=CEGUI-${PV}
+DESCRIPTION="Crazy Eddie's GUI System"
+HOMEPAGE="http://www.cegui.org.uk/"
+SRC_URI="mirror://sourceforge/crayzedsgui/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="devil doc examples expat lua opengl xerces-c xml"
+
+RDEPEND="dev-libs/libpcre
+	=media-libs/freetype-2*
+	devil? ( media-libs/devil )
+	expat? ( dev-libs/expat )
+	lua? ( dev-lang/lua )
+	opengl? ( virtual/opengl
+		virtual/glu
+		virtual/glut )
+	xerces-c? ( dev-libs/xerces-c )
+	xml? ( dev-libs/libxml2 )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+S=${WORKDIR}/${MY_P/b/}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	if use examples ; then
+		cp -r Samples Samples.clean
+		rm -f $(find Samples.clean -name 'Makefile*')
+		rm -rf Samples.clean/bin
+	fi
+}
+
+src_compile() {
+	econf \
+		$(use_enable devil) \
+		$(use_enable examples samples) \
+		$(use_enable expat) \
+		$(use_enable lua lua-module) \
+		$(use_enable lua toluacegui) \
+		$(use_enable opengl opengl-renderer) \
+		$(use_enable xerces-c) \
+		$(use_enable xml libxml) \
+		--enable-static \
+		--enable-tga \
+		--enable-tinyxml \
+		--disable-corona \
+		--disable-dependency-tracking \
+		--disable-freeimage \
+		--disable-irrlicht-renderer \
+		--disable-samples \
+		--disable-silly \
+		--without-gtk2 \
+		--without-ogre-renderer \
+		|| die
+	emake || die "emake failed"
+	if use doc ; then
+		mkdir -p documentation/api_reference
+		doxygen || die "doxygen failed"
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc AUTHORS ChangeLog README TODO
+	use doc && dohtml -r documentation/api_reference
+	if use examples ; then
+		insinto /usr/share/doc/${PF}/Samples
+		doins -r Samples.clean/* || die "doins failed"
+	fi
+}
diff --git a/dev-games/cegui/files/digest-cegui-0.5.0b b/dev-games/cegui/files/digest-cegui-0.5.0b
new file mode 100644
index 000000000000..12103a3d99b2
--- /dev/null
+++ b/dev-games/cegui/files/digest-cegui-0.5.0b
@@ -0,0 +1,3 @@
+MD5 b42322a33c6a06eede76b15f75694a17 CEGUI-0.5.0b.tar.gz 2240192
+RMD160 a60f5ee74315dc83db860cfa91f93449ed7b01f9 CEGUI-0.5.0b.tar.gz 2240192
+SHA256 50c1036f3adc741478966bf29a1e3104b983af8bfd82e201ed35ad2039e166ff CEGUI-0.5.0b.tar.gz 2240192