Version bump. Fails tests. Fixes compile issues reported by fkhp <fkhp101@tom.com>: bug #360487, bug #361447.

(Portage version: 2.1.9.42/cvs/Linux i686)

3 files changed, 112 insertions, 4 deletions

diff --git a/dev-lang/v8/ChangeLog b/dev-lang/v8/ChangeLog
index 52262f8998cf..9f3c17b0648d 100644
--- a/dev-lang/v8/ChangeLog
+++ b/dev-lang/v8/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-lang/v8
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/v8/ChangeLog,v 1.50 2011/03/26 20:39:22 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/v8/ChangeLog,v 1.51 2011/04/08 15:32:02 phajdan.jr Exp $
+
+*v8-3.2.8.2 (08 Apr 2011)
+
+  08 Apr 2011; Pawel Hajdan jr <phajdan.jr@gentoo.org> +v8-3.2.8.2.ebuild,
+  v8-9999.ebuild:
+  Version bump. Fails tests. Fixes compile issues reported by fkhp
+  <fkhp101@tom.com>: bug #360487, bug #361447.
 
 *v8-3.2.3.1 (26 Mar 2011)
 
diff --git a/dev-lang/v8/v8-3.2.8.2.ebuild b/dev-lang/v8/v8-3.2.8.2.ebuild
new file mode 100644
index 000000000000..aa4a1194d994
--- /dev/null
+++ b/dev-lang/v8/v8-3.2.8.2.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/v8/v8-3.2.8.2.ebuild,v 1.1 2011/04/08 15:32:02 phajdan.jr Exp $
+
+EAPI="2"
+
+inherit eutils flag-o-matic multilib scons-utils toolchain-funcs
+
+DESCRIPTION="Google's open source JavaScript engine"
+HOMEPAGE="http://code.google.com/p/v8"
+SRC_URI="mirror://gentoo/${P}.tar.gz"
+LICENSE="BSD"
+
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="readline"
+
+RDEPEND="readline? ( >=sys-libs/readline-6.1 )"
+DEPEND="${RDEPEND}"
+
+# To make tests work, we compile with sample=shell and visibility=default.
+# For more info see http://groups.google.com/group/v8-users/browse_thread/thread/61ca70420e4476bc
+# and http://groups.google.com/group/v8-users/browse_thread/thread/165f89728ed6f97d
+EXTRA_ESCONS="library=shared soname=on sample=shell visibility=default importenv=\"LINKFLAGS\""
+
+pkg_setup() {
+	tc-export AR CC CXX RANLIB
+
+	# Make the build respect LDFLAGS.
+	export LINKFLAGS="${LDFLAGS}"
+}
+
+src_prepare() {
+	# Stop -Werror from breaking the build.
+	epatch "${FILESDIR}"/${PN}-no-werror-r0.patch
+
+	# Respect the user's CFLAGS, including the optimization level.
+	epatch "${FILESDIR}"/${PN}-no-O3-r0.patch
+
+	# Remove a test that is known to fail:
+	# http://groups.google.com/group/v8-users/browse_thread/thread/b8a3f42b5aa18d06
+	rm test/mjsunit/debug-script.js || die
+
+	# Remove a test that behaves differently depending on FEATURES="userpriv",
+	# see bug #348558.
+	rm test/mjsunit/d8-os.js || die
+}
+
+src_configure() {
+	# GCC issues multiple warnings about strict-aliasing issues in v8 code.
+	append-flags -fno-strict-aliasing
+}
+
+src_compile() {
+	local myconf=""
+
+	# Use target arch detection logic from bug #354601.
+	case ${CHOST} in
+		i?86-*) myarch=x86 ;;
+		x86_64-*)
+			if [[ $ABI = "" ]] ; then
+				myarch=amd64
+			else
+				myarch="$ABI"
+			fi ;;
+		arm*-*) myarch=arm ;;
+		*) die "Unrecognized CHOST: ${CHOST}"
+	esac
+
+	if [[ $myarch = amd64 ]] ; then
+		myconf+=" arch=x64"
+	elif [[ $myarch = x86 ]] ; then
+		myconf+=" arch=ia32"
+	elif [[ $myarch = arm ]] ; then
+		myconf+=" arch=arm"
+	else
+		die "Failed to determine target arch, got '$myarch'."
+	fi
+
+	escons $(use_scons readline console readline dumb) ${myconf} . || die
+}
+
+src_install() {
+	insinto /usr
+	doins -r include || die
+
+	dobin d8 || die
+
+	dolib libv8-${PV}.so || die
+	dosym libv8-${PV}.so /usr/$(get_libdir)/libv8.so || die
+
+	dodoc AUTHORS ChangeLog || die
+}
+
+src_test() {
+	# Make sure we use the libv8.so from our build directory,
+	# and not the /usr/lib one (it may be missing if we are
+	# installing for the first time or upgrading), see bug #352374.
+	LD_LIBRARY_PATH="${S}" tools/test.py --no-build -p dots || die
+}
diff --git a/dev-lang/v8/v8-9999.ebuild b/dev-lang/v8/v8-9999.ebuild
index 3406e7e4cc82..75148037b937 100644
--- a/dev-lang/v8/v8-9999.ebuild
+++ b/dev-lang/v8/v8-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/v8/v8-9999.ebuild,v 1.7 2011/03/26 20:39:22 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/v8/v8-9999.ebuild,v 1.8 2011/04/08 15:32:02 phajdan.jr Exp $
 
 EAPI="2"
 
@@ -18,9 +18,10 @@ IUSE="readline"
 RDEPEND="readline? ( >=sys-libs/readline-6.1 )"
 DEPEND="${RDEPEND}"
 
-# To make tests work, we compile with sample=shell.
+# To make tests work, we compile with sample=shell and visibility=default.
 # For more info see http://groups.google.com/group/v8-users/browse_thread/thread/61ca70420e4476bc
-EXTRA_ESCONS="library=shared sample=shell importenv=\"LINKFLAGS\""
+# and http://groups.google.com/group/v8-users/browse_thread/thread/165f89728ed6f97d
+EXTRA_ESCONS="library=shared sample=shell visibility=default importenv=\"LINKFLAGS\""
 
 pkg_setup() {
 	tc-export AR CC CXX RANLIB