Bump to liblist-2.4, fixing bug #362067 and moving to autotools-util and EAPI=4.

(Portage version: 2.2.0_alpha41-r1/cvs/Linux x86_64)

2 files changed, 60 insertions, 1 deletions

diff --git a/dev-libs/liblist/ChangeLog b/dev-libs/liblist/ChangeLog
index f79a0755a669..4291fbd7ee3d 100644
--- a/dev-libs/liblist/ChangeLog
+++ b/dev-libs/liblist/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/liblist
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/liblist/ChangeLog,v 1.11 2011/07/01 03:50:35 binki Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/liblist/ChangeLog,v 1.12 2011/07/01 22:13:56 binki Exp $
+
+*liblist-2.4 (01 Jul 2011)
+
+  01 Jul 2011; Nathan Phillip Brink <binki@gentoo.org> +liblist-2.4.ebuild:
+  Bump to liblist-2.4, fixing bug #362067 and moving to autotools-util and
+  EAPI=4.
 
   01 Jul 2011; Nathan Phillip Brink <binki@gentoo.org> metadata.xml:
   Set myself (binki) as maintainer.
diff --git a/dev-libs/liblist/liblist-2.4.ebuild b/dev-libs/liblist/liblist-2.4.ebuild
new file mode 100644
index 000000000000..6fe9011ad628
--- /dev/null
+++ b/dev-libs/liblist/liblist-2.4.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/liblist/liblist-2.4.ebuild,v 1.1 2011/07/01 22:13:56 binki Exp $
+
+EAPI=4
+
+inherit autotools-utils multilib
+
+DESCRIPTION="This package provides generic linked-list manipulation routines, plus queues and stacks"
+HOMEPAGE="http://ohnopub.net/liblist"
+SRC_URI="ftp://ohnopublishing.net/mirror/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-linux"
+IUSE="doc examples static-libs"
+
+RDEPEND="doc? ( media-gfx/transfig
+		dev-texlive/texlive-metapost
+		virtual/latex-base )"
+DEPEND="${RDEPEND}"
+
+src_configure() {
+	local myeconfargs=(
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+		$(use_enable doc docs)
+		$(use_enable examples)
+	)
+
+	autotools-utils_src_configure
+}
+
+src_install() {
+	autotools-utils_src_install
+
+	dodoc README
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins examples/{*.c,Makefile,README}
+		insinto /usr/share/doc/${PF}/examples/cache
+		doins examples/cache/{*.c,README}
+	fi
+
+	docompress -x /usr/share/doc/${PF}/{list.0,paper.dvi,examples}
+}
+
+pkg_postinst() {
+	elog "Note that man pages for this package have been renamed to avoid"
+	elog "name collisions with some system functions. However, the libs"
+	elog "and header files have not been changed."
+	elog "The new names are liblist, lcache, liblist_queue, and liblist_stack."
+}