incorporate cleanups by Stelian Ionescu <sionescu@common-lisp.net>

(Portage version: 2.1.3_rc7)

4 files changed, 207 insertions, 2 deletions

diff --git a/dev-lisp/sbcl/ChangeLog b/dev-lisp/sbcl/ChangeLog
index bc4ff499ebf0..7a97193a6240 100644
--- a/dev-lisp/sbcl/ChangeLog
+++ b/dev-lisp/sbcl/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-lisp/sbcl
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lisp/sbcl/ChangeLog,v 1.115 2007/07/09 12:27:32 hkbst Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lisp/sbcl/ChangeLog,v 1.116 2007/07/11 13:20:27 hkbst Exp $
+
+*sbcl-1.0.6-r2 (11 Jul 2007)
+
+  11 Jul 2007; Marijn Schouten <hkBst@gentoo.org> sbcl-1.0.6-r1.ebuild,
+  +sbcl-1.0.6-r2.ebuild:
+  incorporate cleanups by Stelian Ionescu <sionescu@common-lisp.net>
 
   09 Jul 2007; Marijn Schouten <hkBst@gentoo.org> sbcl-1.0.6-r1.ebuild:
   add alpha SRC_URI
diff --git a/dev-lisp/sbcl/files/digest-sbcl-1.0.6-r2 b/dev-lisp/sbcl/files/digest-sbcl-1.0.6-r2
new file mode 100644
index 000000000000..458f61beb9dc
--- /dev/null
+++ b/dev-lisp/sbcl/files/digest-sbcl-1.0.6-r2
@@ -0,0 +1,24 @@
+MD5 f6b5eddb055df93b990ea137b667df20 sbcl-0.9.12-alpha-linux-binary.tar.bz2 7147697
+RMD160 09fa934242a9da6c765056420f694c8f23bba925 sbcl-0.9.12-alpha-linux-binary.tar.bz2 7147697
+SHA256 3a16825480ca476c986bc18d1a1a2c5cad5a1e71ff6ba21d5c5011f69b119245 sbcl-0.9.12-alpha-linux-binary.tar.bz2 7147697
+MD5 dbdc309a44b269ab51d201b7afa1e691 sbcl-0.9.12-mips-linux-binary.tar.bz2 6946654
+RMD160 41350780a7f8618e4bbde98e056604b62e246c9d sbcl-0.9.12-mips-linux-binary.tar.bz2 6946654
+SHA256 8d94b47f76f09cc474e22edf8ea04fafeb08303de2a27b0fca25bebe719e766b sbcl-0.9.12-mips-linux-binary.tar.bz2 6946654
+MD5 e4e294832e3dbaa45563094759c529d4 sbcl-0.9.12-mipsel-linux-binary.tar.bz2 7310807
+RMD160 9226b04cb240611dd3897a9684b70ded9c04f086 sbcl-0.9.12-mipsel-linux-binary.tar.bz2 7310807
+SHA256 7cb979d33ce804a8b84c93dfd8aafbb5be8579bea911c005afce78a642c457bc sbcl-0.9.12-mipsel-linux-binary.tar.bz2 7310807
+MD5 a7cbf41b8fb27f8b0b9bff2bda2f63e0 sbcl-0.9.17-sparc-linux-binary.tar.bz2 7322996
+RMD160 b9887c767ddc693fade88b04cc919859aef1b79a sbcl-0.9.17-sparc-linux-binary.tar.bz2 7322996
+SHA256 9238d9de88be3d05c3369cd15f52ae2819a82e7e55f9b85133c947d102ce4059 sbcl-0.9.17-sparc-linux-binary.tar.bz2 7322996
+MD5 ba1d967bbdba88da7c8ea965c5508f26 sbcl-1.0-powerpc-linux-binary.tar.bz2 6841127
+RMD160 11cba4cec1efed9d9b322ab80d58ec63b93f66e4 sbcl-1.0-powerpc-linux-binary.tar.bz2 6841127
+SHA256 912bdbee882907b5d4437fb9611637e31801db5303ddcd34f9514a386b0b995f sbcl-1.0-powerpc-linux-binary.tar.bz2 6841127
+MD5 e8803f82e607dbabc1c8cc618314067a sbcl-1.0.6-source.tar.bz2 3116968
+RMD160 f1701da1ec89a064e8ddc6550399a13fc0f632ff sbcl-1.0.6-source.tar.bz2 3116968
+SHA256 41b40e8ac3ae6dc27f02a76dcfe90efb4c250bafa49795c92fb8d85bed5308f0 sbcl-1.0.6-source.tar.bz2 3116968
+MD5 d49d28979f3f3700d90625772dff8445 sbcl-1.0.7-x86-64-linux-binary.tar.bz2 7679046
+RMD160 efb21072e91dab889e1bb4da5479beafedc2553f sbcl-1.0.7-x86-64-linux-binary.tar.bz2 7679046
+SHA256 2e8c1f5f8307c9175fd763e8343d74b04dd505ce3347d8cb65ad0588df8f5118 sbcl-1.0.7-x86-64-linux-binary.tar.bz2 7679046
+MD5 85c3336139401a7f2386f9d1a6763d7a sbcl-1.0.7-x86-linux-binary.tar.bz2 7966584
+RMD160 87f20afde7d3791cf6548c29a02117afa87b27c3 sbcl-1.0.7-x86-linux-binary.tar.bz2 7966584
+SHA256 a5037d4c88bec71517af0c67fe12d4d3305fbc76d4744ad331e034c41522a178 sbcl-1.0.7-x86-linux-binary.tar.bz2 7966584
diff --git a/dev-lisp/sbcl/sbcl-1.0.6-r1.ebuild b/dev-lisp/sbcl/sbcl-1.0.6-r1.ebuild
index a0047b57a507..8668bd952925 100644
--- a/dev-lisp/sbcl/sbcl-1.0.6-r1.ebuild
+++ b/dev-lisp/sbcl/sbcl-1.0.6-r1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2007 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lisp/sbcl/sbcl-1.0.6-r1.ebuild,v 1.2 2007/07/09 12:27:32 hkbst Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lisp/sbcl/sbcl-1.0.6-r1.ebuild,v 1.3 2007/07/11 13:20:27 hkbst Exp $
 
 inherit common-lisp-common-3 eutils flag-o-matic
 
@@ -82,6 +82,7 @@ src_unpack() {
 		for a in ${A}; do [[ $a == *binary* ]] && break; done
 	fi
 	unpack $a
+	ls -l
 	mv ${PN}* sbcl-binary || die
 	unpack ${P}-source.tar.bz2
 	pushd ${S}
diff --git a/dev-lisp/sbcl/sbcl-1.0.6-r2.ebuild b/dev-lisp/sbcl/sbcl-1.0.6-r2.ebuild
new file mode 100644
index 000000000000..02a438a3c759
--- /dev/null
+++ b/dev-lisp/sbcl/sbcl-1.0.6-r2.ebuild
@@ -0,0 +1,174 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-lisp/sbcl/sbcl-1.0.6-r2.ebuild,v 1.1 2007/07/11 13:20:27 hkbst Exp $
+
+inherit common-lisp-common-3 eutils flag-o-matic
+
+#same order as http://www.sbcl.org/platform-table.html
+BV_X86=1.0.7
+BV_AMD64=1.0.7
+BV_PPC=1.0
+BV_SPARC=0.9.17
+BV_ALPHA=0.9.12
+BV_MIPS=0.9.12
+BV_MIPSEL=0.9.12
+
+# BV_PPC_MACOS=0.9.11a
+
+DESCRIPTION="Steel Bank Common Lisp (SBCL) is an implementation of ANSI Common Lisp."
+HOMEPAGE="http://sbcl.sourceforge.net/"
+SRC_URI="mirror://sourceforge/sbcl/${P}-source.tar.bz2
+	x86? ( mirror://sourceforge/sbcl/${PN}-${BV_X86}-x86-linux-binary.tar.bz2 )
+	amd64? ( mirror://sourceforge/sbcl/${PN}-${BV_AMD64}-x86-64-linux-binary.tar.bz2 )
+	ppc? ( mirror://sourceforge/sbcl/${PN}-${BV_PPC}-powerpc-linux-binary.tar.bz2 )
+	sparc? ( mirror://sourceforge/sbcl/${PN}-${BV_SPARC}-sparc-linux-binary.tar.bz2 )
+	alpha? ( mirror://sourceforge/sbcl/${PN}-${BV_ALPHA}-alpha-linux-binary.tar.bz2 )
+	mips? ( !cobalt? ( mirror://sourceforge/sbcl/${PN}-${BV_MIPS}-mips-linux-binary.tar.bz2 ) )
+	mips? ( cobalt? ( mirror://sourceforge/sbcl/${PN}-${BV_MIPSEL}-mipsel-linux-binary.tar.bz2 ) )
+"
+
+LICENSE="MIT"
+SLOT="0"
+
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+
+IUSE="ldb source threads unicode doc"
+
+DEPEND="doc? ( sys-apps/texinfo )"
+
+PROVIDE="virtual/commonlisp"
+
+pkg_setup() {
+	if built_with_use sys-devel/gcc hardened && gcc-config -c | grep -qv vanilla; then
+		eerror "So-called \"hardened\" compiler features are incompatible with SBCL. You"
+		eerror "must use gcc-config to select a profile with non-hardened features"
+		eerror "(the \"vanilla\" profile) and \"source /etc/profile\" before continuing."
+		die
+	fi
+	if ! built_with_use sys-libs/glibc nptl && (use x86 || use amd64); then
+		eerror "Building SBCL without NPTL support on at least x86 and amd64"
+		eerror "architectures is not a supported configuration in Gentoo.  Please"
+		eerror "refer to Bug #119016 for more information."
+		die
+	fi
+	if use ppc && use ldb; then
+		ewarn "Building SBCL on PPC with LDB support is not a supported configuration"
+		ewarn "in Gentoo.	Please refer to Bug #121830 for more information."
+		ewarn "Continuing with LDB support disabled."
+	fi
+}
+
+enable_sbcl_feature() {
+	echo "(enable $1)" >> "${S}/customize-target-features.lisp"
+}
+
+disable_sbcl_feature() {
+	echo "(disable $1)" >> "${S}/customize-target-features.lisp"
+}
+
+sbcl_apply_features() {
+	cat > "${S}/customize-target-features.lisp" <<'EOF'
+(lambda (list)
+  (flet ((enable (x)
+		   (pushnew x list))
+		 (disable (x)
+		   (setf list (remove x list))))
+EOF
+	if use x86 || use amd64; then
+		use threads && enable_sbcl_feature ":sb-thread"
+	fi
+	if use ppc && use ldb; then
+		ewarn "Excluding LDB support for ppc."
+	else
+		use ldb && enable_sbcl_feature ":sb-ldb"
+	fi
+	disable_sbcl_feature ":sb-test"
+	! use unicode && disable_sbcl_feature ":sb-unicode"
+	cat >> "${S}/customize-target-features.lisp" <<'EOF'
+	)
+  list)
+EOF
+}
+
+src_unpack() {
+	unpack ${A}
+	mv sbcl-*-linux sbcl-binary
+
+	pushd "${S}"
+	epatch "${FILESDIR}/disable-tests-gentoo.patch"
+	use source && epatch "${FILESDIR}/vanilla-module-install-source-gentoo.patch"
+	popd
+	sed -i "s,/lib,/$(get_libdir),g" "${S}/install.sh"
+	sed -i "s,/usr/local/lib,/usr/$(get_libdir),g" \
+		"${S}/src/runtime/runtime.c" # #define SBCL_HOME ...
+
+	# applying customizations
+	sbcl_apply_features
+
+	find "${S}" -type f -name .cvsignore -print0 | xargs -0 rm -f
+	find "${S}" -depth -type d -name CVS -print0 | xargs -0 rm -rf
+	find "${S}" -type f -name \*.c -print0 | xargs -0 chmod 644
+}
+
+src_compile() {
+	local bindir="${WORKDIR}/sbcl-binary"
+
+	filter-ldflags -Wl,--as-needed --as-needed # see Bug #132992
+
+	PATH="${bindir}/src/runtime:${PATH}" SBCL_HOME="${bindir}/output" GNUMAKE=make \
+		./make.sh "sbcl
+			--sysinit /dev/null
+			--userinit /dev/null
+			--disable-debugger
+			--core ${bindir}/output/sbcl.core" \
+				|| die
+
+	if use doc; then
+		cd "${S}/doc/manual"
+		make info html || die "make info html failed"
+		cd "${S}/doc/internals"
+		make html || die "make html failed"
+	fi
+}
+
+src_install() {
+	unset SBCL_HOME
+	dodir /etc/
+	cat > "${D}/etc/sbclrc" <<EOF
+;;; The following is required if you want source location functions to
+;;; work in SLIME, for example.
+
+(setf (logical-pathname-translations "SYS")
+	'(("SYS:SRC;**;*.*.*" #p"/usr/$(get_libdir)/sbcl/src/**/*.*")
+	  ("SYS:CONTRIB;**;*.*.*" #p"/usr/$(get_libdir)/sbcl/**/*.*")))
+EOF
+	dodir /usr/share/man
+	dodir /usr/share/doc/${PF}
+	INSTALL_ROOT="${D}/usr" DOC_DIR="${D}/usr/share/doc/${PF}" sh install.sh || die "install.sh failed"
+
+	doman doc/sbcl-asdf-install.1
+
+	dodoc BUGS CREDITS INSTALL NEWS OPTIMIZATIONS PRINCIPLES README STYLE SUPPORT TLA TODO
+
+	if use doc; then
+		dohtml doc/html/*
+		doinfo "${S}/doc/manual/"*.info*
+		dohtml -r "${S}/doc/internals/sbcl-internals"
+	fi
+
+	if use source; then
+		# install the SBCL source
+		cp -pPR "${S}/src" "${D}/usr/$(get_libdir)/sbcl"
+		find "${D}/usr/$(get_libdir)/sbcl/src" -type f -name \*.fasl -print0 | xargs -0 rm -f
+	fi
+
+	impl-save-timestamp-hack sbcl
+}
+
+pkg_postinst() {
+	standard-impl-postinst sbcl
+}
+
+pkg_postrm() {
+	standard-impl-postrm sbcl /usr/bin/sbcl
+}