Bump, drop minor arches due to enum34 keywords missing, drop pypy because keywords missing, drop py34 target because setup.py too confused about life

(Portage version: 2.2.15/cvs/Linux x86_64, unsigned Manifest commit)

2 files changed, 55 insertions, 2 deletions

diff --git a/dev-python/cryptography/ChangeLog b/dev-python/cryptography/ChangeLog
index e41bea69ab5b..0d4c053cf738 100644
--- a/dev-python/cryptography/ChangeLog
+++ b/dev-python/cryptography/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/cryptography
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/cryptography/ChangeLog,v 1.29 2014/12/24 07:27:30 maekke Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/cryptography/ChangeLog,v 1.30 2015/01/13 03:21:41 patrick Exp $
+
+*cryptography-0.7.1 (13 Jan 2015)
+
+  13 Jan 2015; Patrick Lauer <patrick@gentoo.org> +cryptography-0.7.1.ebuild:
+  Bump, drop minor arches due to enum34 keywords missing, drop pypy because
+  keywords missing, drop py34 target because setup.py too confused about life
 
   24 Dec 2014; Markus Meier <maekke@gentoo.org> cryptography-0.6.1.ebuild:
   arm stable, bug #530294
diff --git a/dev-python/cryptography/cryptography-0.7.1.ebuild b/dev-python/cryptography/cryptography-0.7.1.ebuild
new file mode 100644
index 000000000000..661c4e00f188
--- /dev/null
+++ b/dev-python/cryptography/cryptography-0.7.1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/cryptography/cryptography-0.7.1.ebuild,v 1.1 2015/01/13 03:21:41 patrick Exp $
+
+EAPI=5
+
+# drop pypy so that keywording on not-x86 doesn't get in the way
+# temporarily drop py3.4 until someone stabs setup.py into submission
+PYTHON_COMPAT=( python{2_7,3_3} )
+
+inherit distutils-r1
+
+DESCRIPTION="Library providing cryptographic recipes and primitives"
+HOMEPAGE="https://github.com/pyca/cryptography/ https://pypi.python.org/pypi/cryptography/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~mips ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris"
+IUSE="test"
+
+RDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-libs/openssl:0
+	>=dev-python/six-1.4.1[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '>=dev-python/cffi-0.8:=[${PYTHON_USEDEP}]' 'python*')
+	$(python_gen_cond_dep 'dev-python/enum34[${PYTHON_USEDEP}]' python{2_7,3_3} )
+	dev-python/pyasn1[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	test? (
+		~dev-python/cryptography-vectors-${PV}[${PYTHON_USEDEP}]
+		dev-python/iso8601[${PYTHON_USEDEP}]
+		dev-python/pretend[${PYTHON_USEDEP}]
+		dev-python/pyasn1[${PYTHON_USEDEP}]
+		>=dev-python/pytest-2.4.2[${PYTHON_USEDEP}]
+	)
+"
+
+DOCS=( AUTHORS.rst CONTRIBUTING.rst README.rst )
+
+# Restricted until cffi fixes its compile on import issues
+RESTRICT="test"
+
+python_test() {
+	py.test -v || die "Tests fail with ${EPYTHON}"
+}