dev-python/cvxopt: move to new python eclass

(Portage version: 2.2.0_alpha163/cvs/Linux x86_64, signed Manifest commit with key 8009D6F070EB7916)

4 files changed, 101 insertions, 12 deletions

diff --git a/dev-python/cvxopt/ChangeLog b/dev-python/cvxopt/ChangeLog
index 1e66bf67e964..6498e2df7ef5 100644
--- a/dev-python/cvxopt/ChangeLog
+++ b/dev-python/cvxopt/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/cvxopt
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/cvxopt/ChangeLog,v 1.12 2013/02/25 07:21:24 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/cvxopt/ChangeLog,v 1.13 2013/02/26 20:33:17 jlec Exp $
+
+*cvxopt-1.1.5-r2 (26 Feb 2013)
+
+  26 Feb 2013; Justin Lecher <jlec@gentoo.org> cvxopt-1.1.5.ebuild,
+  +cvxopt-1.1.5-r2.ebuild, metadata.xml:
+  move to new python eclass
 
   25 Feb 2013; Sébastien Fabbro <bicatali@gentoo.org> cvxopt-1.1.5-r1.ebuild:
   Previous was wrong commmit
diff --git a/dev-python/cvxopt/cvxopt-1.1.5-r2.ebuild b/dev-python/cvxopt/cvxopt-1.1.5-r2.ebuild
new file mode 100644
index 000000000000..560365a6717a
--- /dev/null
+++ b/dev-python/cvxopt/cvxopt-1.1.5-r2.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/cvxopt/cvxopt-1.1.5-r2.ebuild,v 1.1 2013/02/26 20:33:17 jlec Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit distutils-r1 toolchain-funcs
+
+DESCRIPTION="Python package for convex optimization"
+HOMEPAGE="http://abel.ee.ucla.edu/cvxopt"
+SRC_URI="http://abel.ee.ucla.edu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc +dsdp examples fftw +glpk gsl"
+
+RDEPEND="
+	virtual/blas
+	virtual/cblas
+	virtual/lapack
+	sci-libs/cholmod
+	sci-libs/umfpack
+	dsdp? ( sci-libs/dsdp )
+	fftw? ( sci-libs/fftw:3.0 )
+	glpk? ( sci-mathematics/glpk )
+	gsl? ( sci-libs/gsl )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( dev-python/sphinx )"
+
+S="${WORKDIR}/${P}/src"
+
+python_prepare_all(){
+	local PATCHES=( "${FILESDIR}"/${P}-setup.patch )
+	rm -rf src/C/SuiteSparse*/
+	rm -rf ../doc/build # 413905
+
+	distutils-r1_python_prepare_all
+
+	pkg_lib() {
+		local pylib=\'$($(tc-getPKG_CONFIG) --libs-only-l ${1} | sed \
+			-e 's/^-l//' \
+			-e "s/ -l/\',\'/g" \
+			-e 's/.,.pthread//g' \
+			-e "s:[[:space:]]::g")\'
+		sed -i -e "/_LIB = /s:\(.*\)'${1}'\(.*\):\1${pylib}\2:" setup.py || die
+	}
+
+	use_cvx() {
+		if use ${1}; then
+			sed -i \
+				-e "s/\(BUILD_${1^^} =\) 0/\1 1/" \
+				setup.py || die
+		fi
+	}
+
+	pkg_lib blas
+	pkg_lib lapack
+	use_cvx gsl
+	use_cvx fftw
+	use_cvx glpk
+	use_cvx dsdp
+}
+
+python_compile_all() {
+	use doc && emake -C "${WORKDIR}"/${P}/doc -B html
+}
+
+python_test() {
+	cd "${WORKDIR}"/${P}/examples/doc/chap8
+	"${PYTHON}" lp.py || die
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( "${WORKDIR}"/${P}/doc/build/html/. )
+	insinto /usr/share/doc/${PF}
+	use examples && doins -r "${WORKDIR}"/${P}/examples
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/cvxopt/cvxopt-1.1.5.ebuild b/dev-python/cvxopt/cvxopt-1.1.5.ebuild
index 5ba86d40f7e5..2353abc77a02 100644
--- a/dev-python/cvxopt/cvxopt-1.1.5.ebuild
+++ b/dev-python/cvxopt/cvxopt-1.1.5.ebuild
@@ -1,13 +1,13 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/cvxopt/cvxopt-1.1.5.ebuild,v 1.3 2012/05/04 15:12:12 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/cvxopt/cvxopt-1.1.5.ebuild,v 1.4 2013/02/26 20:33:17 jlec Exp $
 
 EAPI=4
 
 SUPPORT_PYTHON_ABIS=1
 RESTRICT_PYTHON_ABIS="2.4 2.5 *-jython 2.7-pypy-*"
 
-inherit distutils eutils
+inherit distutils eutils toolchain-funcs
 
 DESCRIPTION="Python package for convex optimization"
 HOMEPAGE="http://abel.ee.ucla.edu/cvxopt"
@@ -18,7 +18,8 @@ SLOT="0"
 KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
 IUSE="doc +dsdp examples fftw +glpk gsl"
 
-RDEPEND="virtual/blas
+RDEPEND="
+	virtual/blas
 	virtual/cblas
 	virtual/lapack
 	sci-libs/cholmod
@@ -39,7 +40,7 @@ src_prepare(){
 	rm -rf ../doc/build # 413905
 
 	pkg_lib() {
-		local pylib=\'$(pkg-config --libs-only-l ${1} | sed \
+		local pylib=\'$($(tc-getPKG_CONFIG) --libs-only-l ${1} | sed \
 			-e 's/^-l//' \
 			-e "s/ -l/\',\'/g" \
 			-e 's/.,.pthread//g' \
diff --git a/dev-python/cvxopt/metadata.xml b/dev-python/cvxopt/metadata.xml
index a58f8748b8f8..2e5db1fcde1d 100644
--- a/dev-python/cvxopt/metadata.xml
+++ b/dev-python/cvxopt/metadata.xml
@@ -1,17 +1,17 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<herd>sci-mathematics</herd>
-<longdescription lang='en'>
+  <herd>sci-mathematics</herd>
+  <longdescription lang="en">
   CVXOPT is a software for convex optimization based on
   the Python programming language. Its main purpose is to make the
   development of software for convex optimization applications
   straightforward.
 </longdescription>
-<use>
-  <flag name='glpk'>Use GNU Linear Programming Kit
+  <use>
+    <flag name="glpk">Use GNU Linear Programming Kit
   <pkg>sci-mathematics/glpk</pkg></flag>
-  <flag name='dsdp'>Use interior point library
+    <flag name="dsdp">Use interior point library
   <pkg>sci-libs/dsdp</pkg></flag>
-</use>
+  </use>
 </pkgmetadata>