Migrate to distutils-r1.

(Portage version: 2.2.0_alpha155/cvs/Linux x86_64, signed Manifest commit with key 42B9401D)

2 files changed, 56 insertions, 3 deletions

diff --git a/dev-python/execnet/ChangeLog b/dev-python/execnet/ChangeLog
index c481e1966aed..9091f791b973 100644
--- a/dev-python/execnet/ChangeLog
+++ b/dev-python/execnet/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/execnet
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/execnet/ChangeLog,v 1.13 2012/06/21 20:22:51 grozin Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/execnet/ChangeLog,v 1.14 2013/01/20 00:04:40 mgorny Exp $
+
+*execnet-1.1-r1 (20 Jan 2013)
+
+  20 Jan 2013; Michał Górny <mgorny@gentoo.org> +execnet-1.1-r1.ebuild:
+  Migrate to distutils-r1.
 
 *execnet-1.1 (21 Jun 2012)
 
@@ -71,4 +76,3 @@
   17 Jan 2010; Andrey Grozin <grozin@gentoo.org> +execnet-1.0.2.ebuild,
   +metadata.xml:
   Initial import
-
diff --git a/dev-python/execnet/execnet-1.1-r1.ebuild b/dev-python/execnet/execnet-1.1-r1.ebuild
new file mode 100644
index 000000000000..feef8c17c6b0
--- /dev/null
+++ b/dev-python/execnet/execnet-1.1-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/execnet/execnet-1.1-r1.ebuild,v 1.1 2013/01/20 00:04:40 mgorny Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_5,2_6,2_7} pypy{1_9,2_0} )
+
+inherit distutils-r1
+
+DESCRIPTION="Rapid multi-Python deployment"
+HOMEPAGE="http://codespeak.net/execnet/ http://pypi.python.org/pypi/execnet/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.zip"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+DEPEND="app-arch/unzip
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+RDEPEND=""
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+src_test() {
+	# Tests are a bit fragile to failures in parallel.
+	# XXX: take a closer look, it may be easy to fix.
+	local DISTUTILS_NO_PARALLEL_BUILD=1
+
+	distutils-r1_python_test
+}
+
+python_test() {
+	# Re-enable in order to properly test disabling it ;).
+	# https://bitbucket.org/hpk42/execnet/issue/10
+	unset PYTHONDONTWRITEBYTECODE
+
+	py.test || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/_build/html/. )
+
+	distutils-r1_python_install_all
+}