Version bump

(Portage version: 2.2.8-r1/cvs/Linux i686, signed Manifest commit with key 0x3AFFCE974D34BD8C!)

2 files changed, 55 insertions, 2 deletions

diff --git a/dev-python/execnet/ChangeLog b/dev-python/execnet/ChangeLog
index 7987fca65030..b46d914fbe0d 100644
--- a/dev-python/execnet/ChangeLog
+++ b/dev-python/execnet/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/execnet
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/execnet/ChangeLog,v 1.17 2013/12/03 19:59:42 floppym Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/execnet/ChangeLog,v 1.18 2014/01/29 14:05:13 grozin Exp $
+
+*execnet-1.2.0 (29 Jan 2014)
+
+  29 Jan 2014; Andrey Grozin <grozin@gentoo.org> +execnet-1.2.0.ebuild:
+  Version bump
 
   03 Dec 2013; Mike Gilbert <floppym@gentoo.org> execnet-1.1-r1.ebuild:
   Revert last change and replace distutils-r1_python_test with distutils-
diff --git a/dev-python/execnet/execnet-1.2.0.ebuild b/dev-python/execnet/execnet-1.2.0.ebuild
new file mode 100644
index 000000000000..7bf80b650868
--- /dev/null
+++ b/dev-python/execnet/execnet-1.2.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/execnet/execnet-1.2.0.ebuild,v 1.1 2014/01/29 14:05:13 grozin Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7,3_2} pypy2_0 )
+
+inherit distutils-r1
+
+DESCRIPTION="Rapid multi-Python deployment"
+HOMEPAGE="http://codespeak.net/execnet/ http://pypi.python.org/pypi/execnet/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc"
+
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+RDEPEND=""
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+src_test() {
+	# Tests are a bit fragile to failures in parallel.
+	# XXX: take a closer look, it may be easy to fix.
+	local DISTUTILS_NO_PARALLEL_BUILD=1
+
+	distutils-r1_src_test
+}
+
+python_test() {
+	# Re-enable in order to properly test disabling it ;).
+	# https://bitbucket.org/hpk42/execnet/issue/10
+	unset PYTHONDONTWRITEBYTECODE
+
+	py.test || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/_build/html/. )
+
+	distutils-r1_python_install_all
+}