bump; add new dep for tests, tidy

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

2 files changed, 49 insertions, 1 deletions

diff --git a/dev-python/flask-mail/ChangeLog b/dev-python/flask-mail/ChangeLog
index 8c231c1ccc14..18f28fd33815 100644
--- a/dev-python/flask-mail/ChangeLog
+++ b/dev-python/flask-mail/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/flask-mail
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/flask-mail/ChangeLog,v 1.2 2014/06/14 07:13:30 idella4 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/flask-mail/ChangeLog,v 1.3 2014/09/30 07:16:56 idella4 Exp $
+
+*flask-mail-0.9.1 (30 Sep 2014)
+
+  30 Sep 2014; Ian Delaney <idella4@gentoo.org> +flask-mail-0.9.1.ebuild:
+  bump; add new dep for tests, tidy
 
   14 Jun 2014; Ian Delaney <idella4@gentoo.org> flask-mail-0.9.0.ebuild:
   add py3 pypy support, IUSE doc, doc build
diff --git a/dev-python/flask-mail/flask-mail-0.9.1.ebuild b/dev-python/flask-mail/flask-mail-0.9.1.ebuild
new file mode 100644
index 000000000000..7a74ce436262
--- /dev/null
+++ b/dev-python/flask-mail/flask-mail-0.9.1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/flask-mail/flask-mail-0.9.1.ebuild,v 1.1 2014/09/30 07:16:56 idella4 Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
+
+inherit distutils-r1
+
+MY_PN="Flask-Mail"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Flask extension for sending email"
+HOMEPAGE="http://pythonhosted.org/Flask-Mail/ https://pypi.python.org/pypi/Flask-Mail"
+SRC_URI="mirror://pypi/${MY_P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/blinker[${PYTHON_USEDEP}]"
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( ${RDEPEND}
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/speaklater[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7 pypy) )"
+
+S="${WORKDIR}/${MY_P}"
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	nosetests || die "Testing failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}