Tentative version bump. Major new version, so dropped keywords

(Portage version: 2.1.10.41/cvs/Linux x86_64)

3 files changed, 99 insertions, 2 deletions

diff --git a/dev-python/ipython/ChangeLog b/dev-python/ipython/ChangeLog
index eff6b51b71c5..a91a0a671c88 100644
--- a/dev-python/ipython/ChangeLog
+++ b/dev-python/ipython/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/ipython
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/ipython/ChangeLog,v 1.87 2011/07/17 11:52:36 xarthisius Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/ipython/ChangeLog,v 1.88 2012/01/08 22:07:39 bicatali Exp $
+
+*ipython-0.12 (08 Jan 2012)
+
+  08 Jan 2012; Sébastien Fabbro <bicatali@gentoo.org> +ipython-0.12.ebuild:
+  Tentative version bump. Major new version, so dropped keywords
 
   17 Jul 2011; Kacper Kowalik <xarthisius@gentoo.org> ipython-0.10.2.ebuild:
   ppc64 stable wrt #366667
diff --git a/dev-python/ipython/ipython-0.12.ebuild b/dev-python/ipython/ipython-0.12.ebuild
new file mode 100644
index 000000000000..d37e6bce6d78
--- /dev/null
+++ b/dev-python/ipython/ipython-0.12.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/ipython/ipython-0.12.ebuild,v 1.1 2012/01/08 22:07:39 bicatali Exp $
+
+EAPI=4
+
+# python eclass cruft
+PYTHON_USE_DEPEND="readline sqlite"
+PYTHON_MODNAME="IPython"
+SUPPORT_PYTHON_ABIS="1"
+RESTRICT_PYTHON_ABIS="2.[45]"
+
+inherit distutils elisp-common eutils
+
+DESCRIPTION="Advanced interactive shell for Python"
+HOMEPAGE="http://ipython.org/"
+SRC_URI="http://archive.ipython.org/release/${PV}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc emacs examples notebook +smp qt4 test wxwidgets"
+
+CDEPEND="dev-python/pexpect
+	emacs? ( app-emacs/python-mode virtual/emacs )
+	smp? ( dev-python/pyzmq )
+	wxwidgets? ( dev-python/wxpython )"
+RDEPEND="${CDEPEND}
+	notebook? ( www-servers/tornado
+			dev-python/pygments
+			dev-python/pyzmq )
+	qt4? ( || ( dev-python/PyQt4 dev-python/pyside )
+			dev-python/pygments
+			dev-python/pyzmq )"
+DEPEND="${CDEPEND}
+	test? ( dev-python/nose )"
+
+SITEFILE="62ipython-gentoo.el"
+
+src_prepare() {
+	sed -i \
+		-e "/docdirbase/s:ipython:${PF}:" \
+		setupbase.py || die "sed failed"
+	if ! use doc; then
+		sed -i \
+			-e 's/+ manual_files//' \
+			setupbase.py || die "sed failed"
+	fi
+	if ! use examples; then
+		sed -i \
+			-e 's/+ example_files//' \
+			setupbase.py || die "sed failed"
+	fi
+}
+
+src_compile() {
+	distutils_src_compile
+	use emacs && elisp-compile docs/emacs/ipython.el
+}
+
+src_test() {
+	testing() {
+		pushd build-${PYTHON_ABI} > /dev/null
+		PYTHONPATH=lib PATH="scripts-${PYTHON_ABI}:${PTHONPATH}" \
+			iptest"$([[ ${PYTHON_ABI} == 3.* ]] && echo 3)"
+		popd > /dev/null
+	}
+	python_execute_function testing
+}
+
+src_install() {
+	distutils_src_install
+	if use emacs; then
+		pushd docs/emacs > /dev/null
+		elisp-install ${PN} ${PN}.el*
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+		popd > /dev/null
+	fi
+}
+
+pkg_postinst() {
+	distutils_pkg_postinst
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	distutils_pkg_postrm
+	use emacs && elisp-site-regen
+}
diff --git a/dev-python/ipython/metadata.xml b/dev-python/ipython/metadata.xml
index d4b52ed7a3e6..b8e2b1057faf 100644
--- a/dev-python/ipython/metadata.xml
+++ b/dev-python/ipython/metadata.xml
@@ -40,4 +40,7 @@ Main features:
 * 他のPython言語プログラムを組み込むのが簡単。
 * pdbデバッガとprofilerへの統合アクセス。
 </longdescription>
+<use>
+  <flag name="notebook">Install requirements for the web notebook based on <pkg>www-servers/tornado</pkg></flag>
+</use>
 </pkgmetadata>