dev-python/pandas: Version Bump, #498856

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

3 files changed, 132 insertions, 9 deletions

diff --git a/dev-python/pandas/ChangeLog b/dev-python/pandas/ChangeLog
index bf2cb99ea365..70b81e668506 100644
--- a/dev-python/pandas/ChangeLog
+++ b/dev-python/pandas/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/pandas
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pandas/ChangeLog,v 1.20 2013/10/27 08:05:32 mgorny Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pandas/ChangeLog,v 1.21 2014/01/22 07:59:04 jlec Exp $
+
+*pandas-0.13.0 (22 Jan 2014)
+
+  22 Jan 2014; Justin Lecher <jlec@gentoo.org> +pandas-0.13.0.ebuild,
+  metadata.xml:
+  Version Bump, #498856
 
   27 Oct 2013; Michał Górny <mgorny@gentoo.org> pandas-0.12.0.ebuild:
   Remove redundant python_export_best (done by the eclass).
diff --git a/dev-python/pandas/metadata.xml b/dev-python/pandas/metadata.xml
index 4e4c66c9b6c0..5426ee89028c 100644
--- a/dev-python/pandas/metadata.xml
+++ b/dev-python/pandas/metadata.xml
@@ -1,17 +1,17 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<herd>sci</herd>
-<longdescription lang="en">
+  <herd>sci</herd>
+  <longdescription lang="en">
   Pandas is a Python package providing fast, flexible, and expressive
   data structures designed to make working with "relational" or
   "labeled" data both easy and intuitive. It aims to be the
   fundamental high-level building block for doing practical, real
   world data analysis in Python. 
 </longdescription>
-<use>
-  <flag name="excel">Pull a few Python packages for Microsoft Excel i/o</flag>
-  <flag name="html">Enable HTML i/o via <pkg>dev-python/beautifulsoup</pkg></flag>
-  <flag name="R">Enable support for R via <pkg>dev-python/rpy</pkg></flag>
-</use>
+  <use>
+    <flag name="excel">Pull a few Python packages for Microsoft Excel i/o</flag>
+    <flag name="html">Enable HTML i/o via <pkg>dev-python/beautifulsoup</pkg></flag>
+    <flag name="R">Enable support for R via <pkg>dev-python/rpy</pkg></flag>
+  </use>
 </pkgmetadata>
diff --git a/dev-python/pandas/pandas-0.13.0.ebuild b/dev-python/pandas/pandas-0.13.0.ebuild
new file mode 100644
index 000000000000..072f3ad98542
--- /dev/null
+++ b/dev-python/pandas/pandas-0.13.0.ebuild
@@ -0,0 +1,117 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pandas/pandas-0.13.0.ebuild,v 1.1 2014/01/22 07:59:04 jlec Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} )
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Powerful data structures for data analysis and statistics"
+HOMEPAGE="http://pandas.sourceforge.net/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples excel html test R"
+
+REQUIRED_USE="
+	excel? ( !python_targets_python3_2 )
+	doc? ( !python_targets_python3_2 )
+	R? ( !python_targets_python3_2 )
+"
+
+CDEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]"
+DEPEND="${CDEPEND}
+	doc? (
+		dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		>=dev-python/openpyxl-1.6.1[${PYTHON_USEDEP}]
+		dev-python/pytables[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/rpy[$(python_gen_usedep 'python2_7')]
+		sci-libs/scipy[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/xlrd[$(python_gen_usedep 'python2*')]
+		dev-python/xlwt[$(python_gen_usedep 'python2*')]
+		sci-libs/scikits_timeseries[$(python_gen_usedep 'python2*')]
+		x11-misc/xclip )
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+# dev-python/statsmodels invokes a circular dep
+#  hence rm from doc? ( ), again
+RDEPEND="${CDEPEND}
+	dev-python/numexpr[${PYTHON_USEDEP}]
+	dev-python/bottleneck[${PYTHON_USEDEP}]
+	dev-python/matplotlib[${PYTHON_USEDEP}]
+	dev-python/pytables[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]
+	excel? (
+		>=dev-python/openpyxl-1.6.1[${PYTHON_USEDEP}]
+		dev-python/xlrd[$(python_gen_usedep 'python2*')]
+		dev-python/xlwt[$(python_gen_usedep 'python2*')]
+	)
+	html? (
+		dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+		|| ( dev-python/lxml[${PYTHON_USEDEP}]
+			 dev-python/html5lib[${PYTHON_USEDEP}] )
+	)
+	R? ( dev-python/rpy[$(python_gen_usedep 'python2_7')] )"
+
+python_prepare_all() {
+	if use doc; then
+		# Prevent un-needed download during build
+		sed -e 's:^intersphinx_mapping:#intersphinx_mapping:' \
+			-e "s:^    'statsmodels:#    'statsmodels:" \
+			-e "s:^    'python:#    'python:" \
+			-e "s:^}:#}:" \
+			-i doc/source/conf.py || die
+	fi
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# To build docs the need be located in $BUILD_DIR,
+	# else PYTHONPATH points to unusable modules.
+	if use doc; then
+		cd "${BUILD_DIR}"/lib || die
+		cp -ar "${S}"/doc . && cd doc || die
+		LANG=C PYTHONPATH=. "${EPYTHON}" make.py html || die
+	fi
+}
+
+python_test() {
+	# test can't survive py2.6, alternately patch to skip under unittest2
+	if [[ ${EPYTHON} == "python2.6" ]]; then
+		rm $(find "${BUILD_DIR}" -name test_array.py) || die
+	fi
+	cd "${BUILD_DIR}"/lib || die
+	PYTHONPATH=. MPLCONFIGDIR=. HOME=. \
+		VIRTUALX_COMMAND="nosetests --verbosity=3 pandas" \
+		virtualmake || die
+}
+
+python_install_all() {
+	if use doc; then
+		cd  "${BUILD_DIR}"/lib || die
+		dohtml -r doc/build/html/*
+		einfo "An initial build of docs is absent of references to statsmodels"
+		einfo "due to circular dependency. To have them included, emerge"
+		einfo "statsmodels next and re-emerge pandas with USE doc"
+	fi
+
+	if use examples; then
+		# example python modules not to be compressed
+		docompress -x /usr/share/doc/${PF}/examples
+		insinto /usr/share/doc/${PF}
+		doins -r "${S}"/examples
+	fi
+	distutils-r1_python_install_all
+}