Migrate to distutils-r1.

(Portage version: 2.2.0_alpha162/cvs/Linux x86_64, signed Manifest commit with key 42B9401D)

2 files changed, 61 insertions, 3 deletions

diff --git a/dev-python/python-openid/ChangeLog b/dev-python/python-openid/ChangeLog
index a2615e43c286..b6c55f2936b1 100644
--- a/dev-python/python-openid/ChangeLog
+++ b/dev-python/python-openid/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/python-openid
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/python-openid/ChangeLog,v 1.18 2011/05/24 21:02:40 maekke Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/python-openid/ChangeLog,v 1.19 2013/02/12 13:15:19 mgorny Exp $
+
+*python-openid-2.2.5-r1 (12 Feb 2013)
+
+  12 Feb 2013; Michał Górny <mgorny@gentoo.org> +python-openid-2.2.5-r1.ebuild:
+  Migrate to distutils-r1.
 
   24 May 2011; Markus Meier <maekke@gentoo.org> python-openid-2.2.5.ebuild:
   x86 stable, bug #365537
@@ -100,4 +105,3 @@
   03 Feb 2007; Tiziano Müller <dev-zero@gentoo.org>
   python-openid-1.2.0.ebuild, +metadata.xml:
   Inital ebuild.
-
diff --git a/dev-python/python-openid/python-openid-2.2.5-r1.ebuild b/dev-python/python-openid/python-openid-2.2.5-r1.ebuild
new file mode 100644
index 000000000000..49e3b6b2165b
--- /dev/null
+++ b/dev-python/python-openid/python-openid-2.2.5-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/python-openid/python-openid-2.2.5-r1.ebuild,v 1.1 2013/02/12 13:15:19 mgorny Exp $
+
+EAPI=5
+
+PYTHON_REQ_USE='sqlite?'
+PYTHON_COMPAT=( python{2_5,2_6,2_7} )
+
+inherit distutils-r1
+
+DESCRIPTION="OpenID support for servers and consumers."
+HOMEPAGE="http://www.openidenabled.com/openid/libraries/python/ http://pypi.python.org/pypi/python-openid"
+# Downloaded from http://github.com/openid/python-openid/downloads
+SRC_URI="mirror://gentoo/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="examples mysql postgres sqlite"
+
+RDEPEND="mysql? ( >=dev-python/mysql-python-1.2.2[${PYTHON_USEDEP}] )
+	postgres? ( dev-python/psycopg[${PYTHON_USEDEP}] )"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/openid-python-openid-b666238"
+
+python_prepare_all() {
+	local PATCHES=(
+		# Patch to fix confusion with localhost/127.0.0.1
+		"${FILESDIR}/${PN}-2.0.0-gentoo-test_fetchers.diff"
+	)
+
+	# Disable broken tests from from examples/djopenid.
+	# Remove test that requires running db server.
+	sed -e "s/django_failures =.*/django_failures = 0/" \
+		-e '/storetest/d' \
+		-i admin/runtests || die "sed admin/runtests failed"
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	"${PYTHON}" admin/runtests || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}