Version bump wrt bug #460934. Migrate to python-r1 thanks to Alphat-PC <AlphatPC@gmail.com> in bug #460486.

(Portage version: 2.1.11.55/cvs/Linux x86_64, signed Manifest commit with key 675D0D2C)

2 files changed, 74 insertions, 2 deletions

diff --git a/dev-python/qscintilla-python/ChangeLog b/dev-python/qscintilla-python/ChangeLog
index a0eefaaf0c21..b6209c0b53ad 100644
--- a/dev-python/qscintilla-python/ChangeLog
+++ b/dev-python/qscintilla-python/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-python/qscintilla-python
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/qscintilla-python/ChangeLog,v 1.95 2012/12/10 12:27:54 pesa Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/qscintilla-python/ChangeLog,v 1.96 2013/03/10 17:44:21 kensington Exp $
+
+*qscintilla-python-2.7.1 (10 Mar 2013)
+
+  10 Mar 2013; Michael Palimaka <kensington@gentoo.org>
+  +qscintilla-python-2.7.1.ebuild:
+  Version bump wrt bug #460934. Migrate to python-r1 thanks to Alphat-PC
+  <AlphatPC@gmail.com> in bug #460486.
 
 *qscintilla-python-2.7 (10 Dec 2012)
 
diff --git a/dev-python/qscintilla-python/qscintilla-python-2.7.1.ebuild b/dev-python/qscintilla-python/qscintilla-python-2.7.1.ebuild
new file mode 100644
index 000000000000..8868f9b9a900
--- /dev/null
+++ b/dev-python/qscintilla-python/qscintilla-python-2.7.1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/qscintilla-python/qscintilla-python-2.7.1.ebuild,v 1.1 2013/03/10 17:44:21 kensington Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_5,2_6,2_7,3_1,3_2,3_3} )
+
+inherit eutils multilib python-r1 toolchain-funcs
+
+MY_P=QScintilla-gpl-${PV}
+
+DESCRIPTION="Python bindings for Qscintilla"
+HOMEPAGE="http://www.riverbankcomputing.co.uk/software/qscintilla/intro"
+SRC_URI="mirror://sourceforge/pyqt/${MY_P}.tar.gz"
+
+LICENSE="|| ( GPL-2 GPL-3 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="debug"
+
+DEPEND="
+	${PYTHON_DEPS}
+	>=dev-python/sip-4.12:=[${PYTHON_USEDEP}]
+	>=dev-python/PyQt4-4.8[X,${PYTHON_USEDEP}]
+	dev-qt/qtcore:4
+	dev-qt/qtgui:4
+	~x11-libs/qscintilla-${PV}:=
+"
+RDEPEND="${DEPEND}"
+
+S=${WORKDIR}/${MY_P}/Python
+
+src_prepare() {
+	python_copy_sources
+}
+
+src_configure() {
+	configuration() {
+		local myconf=(
+			"${PYTHON}" configure-old.py
+			--apidir="${EPREFIX}"/usr/share/qt4/qsci
+			--destdir="$(python_get_sitedir)"/PyQt4
+			--sipdir="${EPREFIX}"/usr/share/sip
+			-n "${EPREFIX}"/usr/include/qt4
+			-o "${EPREFIX}"/usr/$(get_libdir)/qt4
+			-p 4
+			--no-timestamp
+			$(use debug && echo --debug)
+		)
+		echo "${myconf[@]}"
+		"${myconf[@]}" || die
+	}
+	python_parallel_foreach_impl run_in_build_dir configuration
+}
+
+src_compile() {
+	building() {
+		emake CC="$(tc-getCC)" CXX="$(tc-getCXX)" LINK="$(tc-getCXX)"
+	}
+	python_foreach_impl run_in_build_dir building
+}
+
+src_install() {
+	python_foreach_impl run_in_build_dir default
+}