Version Bump

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key E9402A79B03529A2!)

2 files changed, 57 insertions, 1 deletions

diff --git a/dev-python/setuptools/ChangeLog b/dev-python/setuptools/ChangeLog
index 785d03c8e95f..5fdc398e2088 100644
--- a/dev-python/setuptools/ChangeLog
+++ b/dev-python/setuptools/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/setuptools
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/setuptools/ChangeLog,v 1.281 2015/06/02 05:13:38 jmorgan Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/setuptools/ChangeLog,v 1.282 2015/06/15 17:14:50 jlec Exp $
+
+*setuptools-17.1.1 (15 Jun 2015)
+
+  15 Jun 2015; Justin Lecher <jlec@gentoo.org> +setuptools-17.1.1.ebuild:
+  Version Bump
 
   02 Jun 2015; Jack Morgan <jmorgan@gentoo.org> setuptools-12.0.1.ebuild:
   sparc stable wrt bug #540290
diff --git a/dev-python/setuptools/setuptools-17.1.1.ebuild b/dev-python/setuptools/setuptools-17.1.1.ebuild
new file mode 100644
index 000000000000..d839dfbef5f0
--- /dev/null
+++ b/dev-python/setuptools/setuptools-17.1.1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/setuptools/setuptools-17.1.1.ebuild,v 1.1 2015/06/15 17:14:50 jlec Exp $
+
+EAPI="5"
+
+PYTHON_COMPAT=( python2_7 python3_{3,4} pypy pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Collection of extensions to Distutils"
+HOMEPAGE="http://pypi.python.org/pypi/setuptools"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="PSF-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="test"
+
+DEPEND="
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7 pypy)
+	)
+"
+
+# Force in-source build because build system modifies sources.
+DISTUTILS_IN_SOURCE_BUILD=1
+
+DOCS=( README.txt docs/{easy_install.txt,pkg_resources.txt,setuptools.txt} )
+
+python_prepare_all() {
+	# disable tests requiring a network connection
+	rm setuptools/tests/test_packageindex.py || die
+
+	# don't run integration tests
+	rm setuptools/tests/test_integration.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# test_easy_install raises a SandboxViolation due to ${HOME}/.pydistutils.cfg
+	# It tries to sandbox the test in a tempdir
+	HOME="${PWD}" py.test ${PN} || die "Tests failed under ${EPYTHON}"
+}
+
+python_install() {
+	export DISTRIBUTE_DISABLE_VERSIONED_EASY_INSTALL_SCRIPT=1
+	distutils-r1_python_install
+}