dev-python/subunit-0.0.18 added for pbr, which will be added for keystoneclient which will be added for heatclient and on

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 0x2471eb3e40ac5ac3)

2 files changed, 64 insertions, 1 deletions

diff --git a/dev-python/subunit/ChangeLog b/dev-python/subunit/ChangeLog
index b83f43e41386..4c8efe33324d 100644
--- a/dev-python/subunit/ChangeLog
+++ b/dev-python/subunit/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/subunit
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/subunit/ChangeLog,v 1.38 2014/03/19 23:07:21 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/subunit/ChangeLog,v 1.39 2014/03/27 21:47:34 prometheanfire Exp $
+
+*subunit-0.0.18 (27 Mar 2014)
+
+  27 Mar 2014; Matthew Thode <prometheanfire@gentoo.org> +subunit-0.0.18.ebuild:
+  dev-python/subunit-0.0.18 added for pbr, which will be added for
+  keystoneclient which will be added for heatclient and on
 
   19 Mar 2014; Sébastien Fabbro <bicatali@gentoo.org> subunit-0.0.9.ebuild:
   Keyword ~amd64-linux ~x86-linux
diff --git a/dev-python/subunit/subunit-0.0.18.ebuild b/dev-python/subunit/subunit-0.0.18.ebuild
new file mode 100644
index 000000000000..c129c98d4939
--- /dev/null
+++ b/dev-python/subunit/subunit-0.0.18.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/subunit/subunit-0.0.18.ebuild,v 1.1 2014/03/27 21:47:34 prometheanfire Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} pypy2_0 )
+
+inherit distutils-r1 eutils
+
+DESCRIPTION="A streaming protocol for test results"
+HOMEPAGE="https://launchpad.net/subunit http://pypi.python.org/pypi/python-subunit"
+SRC_URI="http://launchpad.net/${PN}/trunk/${PV}/+download/${P}.tar.gz"
+
+LICENSE="Apache-2.0 BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~x86 ~x86-fbsd"
+#need to keyword the following in =dev-python/extras-0.0.3 then readd the keywords here
+#ia64 s390 sh sparc amd64-fbsd
+IUSE="static-libs"
+
+RDEPEND=">=dev-python/testtools-0.9.34[${PYTHON_USEDEP}]
+	dev-python/extras[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-lang/perl
+	dev-libs/check
+	dev-util/cppunit
+	virtual/pkgconfig"
+
+src_configure() {
+	econf --enable-shared $(use_enable static-libs static)
+	distutils-r1_src_configure
+}
+
+src_compile() {
+	emake
+	distutils-r1_src_compile
+}
+
+python_test() {
+	local -x PATH="${PWD}/shell/share:${PATH}"
+	local -x PYTHONPATH=python
+	"${PYTHON}" -m testtools.run all_tests.test_suite || die "Testing failed with ${EPYTHON}"
+}
+
+src_install() {
+	local targets=(
+		install-include_subunitHEADERS
+		install-pcdataDATA
+		install-exec-local
+		install-libLTLIBRARIES
+	)
+	emake DESTDIR="${D}" "${targets[@]}"
+	prune_libtool_files
+	distutils-r1_src_install
+}