dev-python/zsi: Move to distutils-r1.eclass

(Portage version: 2.2.0_alpha173/cvs/Linux x86_64, signed Manifest commit with key 8009D6F070EB7916)

1 files changed, 56 insertions, 0 deletions

diff --git a/dev-python/zsi/zsi-2.1_alpha1-r1.ebuild b/dev-python/zsi/zsi-2.1_alpha1-r1.ebuild
new file mode 100644
index 000000000000..0ff70c322ba4
--- /dev/null
+++ b/dev-python/zsi/zsi-2.1_alpha1-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/zsi/zsi-2.1_alpha1-r1.ebuild,v 1.1 2013/04/23 14:30:07 jlec Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit distutils-r1
+
+MY_PN="ZSI"
+MY_P="${MY_PN}-${PV/_alpha/-a}"
+
+DESCRIPTION="Web Services for Python"
+HOMEPAGE="http://pywebsvcs.sourceforge.net/zsi.html"
+SRC_URI="mirror://sourceforge/pywebsvcs/${MY_P}.tar.gz"
+
+LICENSE="BSD MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="doc examples twisted"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	twisted? (
+		dev-python/twisted
+		dev-python/twisted-web
+	)"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS="CHANGES README"
+
+python_prepare_all() {
+	if ! use twisted; then
+		sed -i \
+			-e "/version_info/d"\
+			-e "/ZSI.twisted/d"\
+			setup.py || die "sed failed"
+	fi
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if use doc; then
+		dohtml doc/*.{html,css,png}
+	fi
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins -r doc/examples/* samples/*
+	fi
+}