Move to distutils-r1

(Portage version: 2.2.01.22124-prefix/cvs/Linux x86_64, signed Manifest commit with key 0x13CB1360)

5 files changed, 65 insertions, 118 deletions

diff --git a/dev-python/pywavelets/ChangeLog b/dev-python/pywavelets/ChangeLog
index ef6605bd57f0..6f4a56349333 100644
--- a/dev-python/pywavelets/ChangeLog
+++ b/dev-python/pywavelets/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for dev-python/pywavelets
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pywavelets/ChangeLog,v 1.12 2013/01/16 19:55:14 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pywavelets/ChangeLog,v 1.13 2013/08/12 18:31:13 bicatali Exp $
+
+*pywavelets-0.2.2-r1 (12 Aug 2013)
+
+  12 Aug 2013; Sébastien Fabbro <bicatali@gentoo.org>
+  +pywavelets-0.2.2-r1.ebuild, -pywavelets-0.2.0.ebuild,
+  -pywavelets-0.2.2.ebuild, metadata.xml:
+  Move to distutils-r1
 
   16 Jan 2013; Justin Lecher <jlec@gentoo.org> pywavelets-0.2.2.ebuild,
   metadata.xml:
diff --git a/dev-python/pywavelets/metadata.xml b/dev-python/pywavelets/metadata.xml
index ffc0dd2090be..610e1b9f018f 100644
--- a/dev-python/pywavelets/metadata.xml
+++ b/dev-python/pywavelets/metadata.xml
@@ -1,16 +1,16 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-  <herd>sci-mathematics</herd>
-  <herd>python</herd>
-  <longdescription lang="en">
-PyWavelets is a Python wavelet transforms module that can perform:
+<herd>sci-mathematics</herd>
+<herd>python</herd>
+<longdescription lang="en">
+  PyWavelets is a Python wavelet transforms module that can perform:
   * Discrete Wavelet Transform (1D and 2D)
   * Inverse Discrete Wavelet Transform (1D and 2D)
   * Stationary Wavelet Transform
   * Wavelet Packets decomposition and reconstruction
 </longdescription>
-  <upstream>
-    <remote-id type="pypi">PyWavelets</remote-id>
-  </upstream>
+<upstream>
+  <remote-id type="pypi">PyWavelets</remote-id>
+</upstream>
 </pkgmetadata>
diff --git a/dev-python/pywavelets/pywavelets-0.2.0.ebuild b/dev-python/pywavelets/pywavelets-0.2.0.ebuild
deleted file mode 100644
index b04a818f0235..000000000000
--- a/dev-python/pywavelets/pywavelets-0.2.0.ebuild
+++ /dev/null
@@ -1,54 +0,0 @@
-# Copyright 1999-2012 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pywavelets/pywavelets-0.2.0.ebuild,v 1.6 2012/08/02 17:57:17 bicatali Exp $
-
-EAPI=4
-PYTHON_DEPEND="2"
-SUPPORT_PYTHON_ABIS="1"
-RESTRICT_PYTHON_ABIS="3.* *-jython 2.7-pypy-*"
-
-inherit distutils
-
-MY_PN="${PN/pyw/PyW}"
-MY_P="${MY_PN}-${PV}"
-
-DESCRIPTION="Python module for discrete, stationary, and packet wavelet transforms."
-HOMEPAGE="http://www.pybytes.com/pywavelets/ http://pypi.python.org/pypi/PyWavelets"
-SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.bz2"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
-IUSE="doc examples test"
-
-DEPEND="dev-python/cython
-	test? ( dev-python/numpy )"
-RDEPEND="dev-python/numpy"
-
-S="${WORKDIR}/${MY_P}"
-
-DOCS="CHANGES.txt THANKS.txt"
-PYTHON_MODNAME="pywt"
-
-src_prepare() {
-	distutils_src_prepare
-	# https://bitbucket.org/nigma/pywt/changeset/784802d4118c
-	sed -e "167s/__new__/__cinit__/" -i src/_pywt.pyx
-}
-
-src_test() {
-	testing() {
-		PYTHONPATH="$(ls -d build-${PYTHON_ABI}/lib.*)" \
-			"$(PYTHON)" tests/test_perfect_reconstruction.py
-	}
-	python_execute_function testing
-}
-
-src_install () {
-	distutils_src_install
-	use doc && dohtml -r doc/build/html/*
-	if use examples; then
-		insinto /usr/share/doc/${PF}/examples
-		doins demo/* || die "doins failed"
-	fi
-}
diff --git a/dev-python/pywavelets/pywavelets-0.2.2-r1.ebuild b/dev-python/pywavelets/pywavelets-0.2.2-r1.ebuild
new file mode 100644
index 000000000000..bf0763255d29
--- /dev/null
+++ b/dev-python/pywavelets/pywavelets-0.2.2-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pywavelets/pywavelets-0.2.2-r1.ebuild,v 1.1 2013/08/12 18:31:13 bicatali Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit distutils-r1
+
+MY_PN="${PN/pyw/PyW}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Python module for discrete, stationary, and packet wavelet transforms"
+HOMEPAGE="http://www.pybytes.com/pywavelets"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.zip"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples test"
+
+DEPEND="
+	app-arch/unzip
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? ( dev-python/numpy[${PYTHON_USEDEP}] )
+	doc? ( dev-python/sphinx )"
+RDEPEND="dev-python/numpy[${PYTHON_USEDEP}]"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS=(CHANGES.txt THANKS.txt)
+
+python_test() {
+	PYTHONPATH="${BUILD_DIR}/lib" \
+		${EPYTHON} tests/test_perfect_reconstruction.py || die
+}
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	use doc && dohtml -r doc/build/html/*
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins demo/*
+	fi
+}
diff --git a/dev-python/pywavelets/pywavelets-0.2.2.ebuild b/dev-python/pywavelets/pywavelets-0.2.2.ebuild
deleted file mode 100644
index e99bba84aca3..000000000000
--- a/dev-python/pywavelets/pywavelets-0.2.2.ebuild
+++ /dev/null
@@ -1,56 +0,0 @@
-# Copyright 1999-2013 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pywavelets/pywavelets-0.2.2.ebuild,v 1.5 2013/01/16 19:55:14 jlec Exp $
-
-EAPI=4
-
-PYTHON_DEPEND="2"
-SUPPORT_PYTHON_ABIS="1"
-RESTRICT_PYTHON_ABIS="2.5 3.* *-jython 2.7-pypy-*"
-
-inherit distutils
-
-MY_PN="${PN/pyw/PyW}"
-MY_P="${MY_PN}-${PV}"
-
-DESCRIPTION="Python module for discrete, stationary, and packet wavelet transforms."
-HOMEPAGE="http://www.pybytes.com/pywavelets/ http://pypi.python.org/pypi/PyWavelets"
-SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.zip"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
-IUSE="doc examples test"
-
-DEPEND="app-arch/unzip
-	dev-python/cython
-	test? ( dev-python/numpy )
-	doc? ( dev-python/sphinx )"
-RDEPEND="dev-python/numpy"
-
-S="${WORKDIR}/${MY_P}"
-
-DOCS="CHANGES.txt THANKS.txt"
-PYTHON_MODNAME="pywt"
-
-src_test() {
-	testing() {
-		PYTHONPATH="$(ls -d build-${PYTHON_ABI}/lib.*)" \
-			"$(PYTHON)" tests/test_perfect_reconstruction.py
-	}
-	python_execute_function testing
-}
-
-src_compile() {
-	distutils_src_compile
-	use doc && emake -C doc html
-}
-
-src_install () {
-	distutils_src_install
-	use doc && dohtml -r doc/build/html/*
-	if use examples; then
-		insinto /usr/share/doc/${PF}/examples
-		doins demo/* || die "doins failed"
-	fi
-}